basis/math/bitwise/bitwise.factor

   1 ! Copyright (C) 2007, 2008 Slava Pestov, Doug Coleman.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: alien alien.c-types alien.data arrays assocs byte-arrays
   4 combinators combinators.short-circuit fry kernel kernel.private
   5 layouts macros math math.bits sequences sequences.private
   6 specialized-arrays words ;
   7 SPECIALIZED-ARRAY: uchar
   8 IN: math.bitwise
   9
  10 ! utilities
  11 : clear-bit ( x n -- y ) 2^ bitnot bitand ; inline
  12 : set-bit ( x n -- y ) 2^ bitor ; inline
  13 : unmask ( x n -- y ) bitnot bitand ; inline
  14 : unmask? ( x n -- ? ) unmask zero? not ; inline
  15 : mask ( x n -- y ) bitand ; inline
  16 : mask? ( x n -- ? ) [ mask ] [ = ] bi ; inline
  17 : wrap ( m n -- m' ) 1 - bitand ; inline
  18 : on-bits ( m -- n ) dup 0 <= [ drop 0 ] [ 2^ 1 - ] if ; inline
  19 : bits ( m n -- m' ) on-bits mask ; inline
  20 : mask-bit ( m n -- m' ) 2^ mask ; inline
  21 : toggle-bit ( m n -- m' ) 2^ bitxor ; inline
  22 : >signed ( x n -- y )
  23     [ bits ] keep 2dup 1 - bit? [ 2^ - ] [ drop ] if ; inline
  24 : >odd ( m -- n ) 0 set-bit ; foldable
  25 : >even ( m -- n ) 0 clear-bit ; foldable
  26 : next-even ( m -- n ) >even 2 + ; foldable
  27 : next-odd ( m -- n ) dup even? [ 1 + ] [ 2 + ] if ; foldable
  28 : shift-mod ( m s w -- n ) [ shift ] dip 2^ wrap ; inline
  29
  30 ERROR: bit-range-error x high low ;
  31 : bit-range ( x high low -- y )
  32     2dup { [ nip 0 < ] [ < ] } 2|| [ bit-range-error ] when
  33     [ nip neg shift ] [ - 1 + ] 2bi bits ; inline
  34
  35 : bitroll ( x s w -- y )
  36     [ wrap ] keep
  37     [ shift-mod ] [ [ - ] keep shift-mod ] 3bi bitor ; inline
  38
  39 : bitroll-32 ( m s -- n ) 32 bitroll ; inline
  40
  41 : bitroll-64 ( m s -- n ) 64 bitroll ; inline
  42
  43 ! 32-bit arithmetic
  44 : w+ ( x y -- z ) + 32 bits ; inline
  45 : w- ( x y -- z ) - 32 bits ; inline
  46 : w* ( x y -- z ) * 32 bits ; inline
  47
  48 ! 64-bit arithmetic
  49 : W+ ( x y -- z ) + 64 bits ; inline
  50 : W- ( x y -- z ) - 64 bits ; inline
  51 : W* ( x y -- z ) * 64 bits ; inline
  52
  53 : symbols>flags ( symbols assoc -- flag-bits )
  54     '[ _ at ] map 0 [ bitor ] reduce ;
  55
  56 ! bitfield
  57 <PRIVATE
  58
  59 GENERIC: (bitfield-quot) ( spec -- quot )
  60
  61 M: integer (bitfield-quot) ( spec -- quot )
  62     '[ _ shift ] ;
  63
  64 M: pair (bitfield-quot) ( spec -- quot )
  65     first2-unsafe over word? [
  66         '[ _ execute _ shift ]
  67     ] [
  68         '[ _ _ shift ]
  69     ] if ;
  70
  71 : (bitfield) ( bitspec -- quot )
  72     [ [ 0 ] ] [
  73         [ (bitfield-quot) ] [ '[ @ _ dip bitor ] ] map-reduce
  74     ] if-empty ;
  75
  76 PRIVATE>
  77
  78 MACRO: bitfield ( bitspec -- quot ) (bitfield) ;
  79
  80 MACRO: bitfield* ( bitspec -- quot ) reverse (bitfield) ;
  81
  82 ! bit-count
  83 <PRIVATE
  84
  85 DEFER: byte-bit-count
  86
  87 <<
  88
  89 \ byte-bit-count
  90 256 <iota> [
  91     8 <bits> 0 [ [ 1 + ] when ] reduce
  92 ] B{ } map-as '[ 0xff bitand _ nth-unsafe ]
  93 ( byte -- table ) define-declared
  94
  95 \ byte-bit-count make-inline
  96
  97 >>
  98
  99 GENERIC: (bit-count) ( x -- n )
 100
 101 : fixnum-bit-count ( x -- n )
 102     { fixnum } declare
 103     {
 104         [ byte-bit-count ]
 105         [ -8 shift byte-bit-count + ]
 106         [ -16 shift byte-bit-count + ]
 107         [ -24 shift byte-bit-count + ]
 108         [
 109             cell 8 = [
 110                 {
 111                     [ -32 shift byte-bit-count + ]
 112                     [ -40 shift byte-bit-count + ]
 113                     [ -48 shift byte-bit-count + ]
 114                     [ -56 shift byte-bit-count + ]
 115                 } cleave >fixnum
 116             ] [ drop ] if
 117         ]
 118     } cleave ;
 119
 120 M: fixnum (bit-count)
 121     fixnum-bit-count { fixnum } declare ; inline
 122
 123 M: bignum (bit-count)
 124     [ 0 ] [
 125         [ byte-bit-count ] [ -8 shift (bit-count) ] bi +
 126     ] if-zero ;
 127
 128 : byte-array-bit-count ( byte-array -- n )
 129     [ byte-bit-count ] map-sum ; inline
 130
 131 PRIVATE>
 132
 133 GENERIC: bit-count ( obj -- n )
 134
 135 M: integer bit-count
 136     dup 0 < [ non-negative-integer-expected ] when (bit-count) ; inline
 137
 138 M: byte-array bit-count
 139     byte-array-bit-count ;
 140
 141 M: object bit-count
 142     binary-object uchar <c-direct-array> byte-array-bit-count ;
 143
 144 : bit-length ( x -- n )
 145     dup 0 < [ non-negative-integer-expected ] [
 146         dup 1 > [ log2 1 + ] when
 147     ] if ;
 148
 149 : even-parity? ( obj -- ? ) bit-count even? ;
 150
 151 : odd-parity? ( obj -- ? ) bit-count odd? ;