basis/math/bitwise/bitwise.factor

   1 ! Copyright (C) 2007, 2008 Slava Pestov, Doug Coleman.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: arrays assocs kernel math sequences accessors
   4 math.bits sequences.private words namespaces macros
   5 hints combinators fry io.binary combinators.smart ;
   6 IN: math.bitwise
   7
   8 ! utilities
   9 : clear-bit ( x n -- y ) 2^ bitnot bitand ; inline
  10 : set-bit ( x n -- y ) 2^ bitor ; inline
  11 : bit-clear? ( x n -- ? ) 2^ bitand 0 = ; inline
  12 : unmask ( x n -- ? ) bitnot bitand ; inline
  13 : unmask? ( x n -- ? ) unmask 0 > ; inline
  14 : mask ( x n -- ? ) bitand ; inline
  15 : mask? ( x n -- ? ) mask 0 > ; inline
  16 : wrap ( m n -- m' ) 1 - bitand ; inline
  17 : bits ( m n -- m' ) 2^ wrap ; inline
  18 : mask-bit ( m n -- m' ) 2^ mask ; inline
  19 : on-bits ( n -- m ) 2^ 1 - ; inline
  20 : toggle-bit ( m n -- m' ) 2^ bitxor ; inline
  21
  22 : shift-mod ( n s w -- n )
  23     [ shift ] dip 2^ wrap ; inline
  24
  25 : bitroll ( x s w -- y )
  26     [ wrap ] keep
  27     [ shift-mod ] [ [ - ] keep shift-mod ] 3bi bitor ; inline
  28
  29 : bitroll-32 ( n s -- n' ) 32 bitroll ; inline
  30
  31 : bitroll-64 ( n s -- n' ) 64 bitroll ; inline
  32
  33 ! 32-bit arithmetic
  34 : w+ ( int int -- int ) + 32 bits ; inline
  35 : w- ( int int -- int ) - 32 bits ; inline
  36 : w* ( int int -- int ) * 32 bits ; inline
  37
  38 ! 64-bit arithmetic
  39 : W+ ( int int -- int ) + 64 bits ; inline
  40 : W- ( int int -- int ) - 64 bits ; inline
  41 : W* ( int int -- int ) * 64 bits ; inline
  42
  43 ! flags
  44 MACRO: flags ( values -- )
  45     [ 0 ] [ [ ?execute bitor ] curry compose ] reduce ;
  46
  47 : symbols>flags ( symbols assoc -- flag-bits )
  48     [ at ] curry map
  49     0 [ bitor ] reduce ;
  50
  51 ! bitfield
  52 <PRIVATE
  53
  54 GENERIC: (bitfield-quot) ( spec -- quot )
  55
  56 M: integer (bitfield-quot) ( spec -- quot )
  57     [ swapd shift bitor ] curry ;
  58
  59 M: pair (bitfield-quot) ( spec -- quot )
  60     first2 over word? [ [ swapd execute ] dip ] [ ] ?
  61     [ shift bitor ] append 2curry ;
  62
  63 PRIVATE>
  64
  65 MACRO: bitfield ( bitspec -- )
  66     [ 0 ] [ (bitfield-quot) compose ] reduce ;
  67
  68 ! bit-count
  69 <PRIVATE
  70
  71 DEFER: byte-bit-count
  72
  73 <<
  74
  75 \ byte-bit-count
  76 256 iota [
  77     8 <bits> 0 [ [ 1 + ] when ] reduce
  78 ] B{ } map-as '[ HEX: ff bitand _ nth-unsafe ]
  79 (( byte -- table )) define-declared
  80
  81 \ byte-bit-count make-inline
  82
  83 >>
  84
  85 GENERIC: (bit-count) ( x -- n )
  86
  87 M: fixnum (bit-count)
  88     [
  89         {
  90             [           byte-bit-count ]
  91             [ -8  shift byte-bit-count ]
  92             [ -16 shift byte-bit-count ]
  93             [ -24 shift byte-bit-count ]
  94         } cleave
  95     ] sum-outputs ;
  96
  97 M: bignum (bit-count)
  98     dup 0 = [ drop 0 ] [
  99         [ byte-bit-count ] [ -8 shift (bit-count) ] bi +
 100     ] if ;
 101
 102 PRIVATE>
 103
 104 : bit-count ( x -- n )
 105     dup 0 < [ bitnot ] when (bit-count) ; inline
 106
 107 ! Signed byte array to integer conversion
 108 : signed-le> ( bytes -- x )
 109     [ le> ] [ length 8 * 1 - on-bits ] bi
 110     2dup > [ bitnot bitor ] [ drop ] if ;
 111
 112 : signed-be> ( bytes -- x )
 113     <reversed> signed-le> ;
 114
 115 : >signed ( x n -- y )
 116     2dup neg 1 + shift 1 = [ 2^ - ] [ drop ] if ;
 117
 118 : >odd ( n -- int ) 0 set-bit ; foldable
 119
 120 : >even ( n -- int ) 0 clear-bit ; foldable
 121
 122 : next-even ( m -- n ) >even 2 + ; foldable
 123
 124 : next-odd ( m -- n ) dup even? [ 1 + ] [ 2 + ] if ; foldable