basis/math/bitwise/bitwise.factor

   1 ! Copyright (C) 2007, 2008 Slava Pestov, Doug Coleman.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: arrays kernel math sequences accessors math.bits
   4 sequences.private words namespaces macros hints
   5 combinators fry io.binary combinators.smart ;
   6 IN: math.bitwise
   7
   8 ! utilities
   9 : clear-bit ( x n -- y ) 2^ bitnot bitand ; inline
  10 : set-bit ( x n -- y ) 2^ bitor ; inline
  11 : bit-clear? ( x n -- ? ) 2^ bitand 0 = ; inline
  12 : unmask ( x n -- ? ) bitnot bitand ; inline
  13 : unmask? ( x n -- ? ) unmask 0 > ; inline
  14 : mask ( x n -- ? ) bitand ; inline
  15 : mask? ( x n -- ? ) mask 0 > ; inline
  16 : wrap ( m n -- m' ) 1 - bitand ; inline
  17 : bits ( m n -- m' ) 2^ wrap ; inline
  18 : mask-bit ( m n -- m' ) 2^ mask ; inline
  19 : on-bits ( n -- m ) 2^ 1 - ; inline
  20 : toggle-bit ( m n -- m' ) 2^ bitxor ; inline
  21
  22 : shift-mod ( n s w -- n )
  23     [ shift ] dip 2^ wrap ; inline
  24
  25 : bitroll ( x s w -- y )
  26     [ wrap ] keep
  27     [ shift-mod ] [ [ - ] keep shift-mod ] 3bi bitor ; inline
  28
  29 : bitroll-32 ( n s -- n' ) 32 bitroll ; inline
  30
  31 : bitroll-64 ( n s -- n' ) 64 bitroll ; inline
  32
  33 ! 32-bit arithmetic
  34 : w+ ( int int -- int ) + 32 bits ; inline
  35 : w- ( int int -- int ) - 32 bits ; inline
  36 : w* ( int int -- int ) * 32 bits ; inline
  37
  38 ! 64-bit arithmetic
  39 : W+ ( int int -- int ) + 64 bits ; inline
  40 : W- ( int int -- int ) - 64 bits ; inline
  41 : W* ( int int -- int ) * 64 bits ; inline
  42
  43 ! flags
  44 MACRO: flags ( values -- )
  45     [ 0 ] [ [ ?execute bitor ] curry compose ] reduce ;
  46
  47 ! bitfield
  48 <PRIVATE
  49
  50 GENERIC: (bitfield-quot) ( spec -- quot )
  51
  52 M: integer (bitfield-quot) ( spec -- quot )
  53     [ swapd shift bitor ] curry ;
  54
  55 M: pair (bitfield-quot) ( spec -- quot )
  56     first2 over word? [ [ swapd execute ] dip ] [ ] ?
  57     [ shift bitor ] append 2curry ;
  58
  59 PRIVATE>
  60
  61 MACRO: bitfield ( bitspec -- )
  62     [ 0 ] [ (bitfield-quot) compose ] reduce ;
  63
  64 ! bit-count
  65 <PRIVATE
  66
  67 DEFER: byte-bit-count
  68
  69 <<
  70
  71 \ byte-bit-count
  72 256 iota [
  73     8 <bits> 0 [ [ 1 + ] when ] reduce
  74 ] B{ } map-as '[ HEX: ff bitand _ nth-unsafe ]
  75 (( byte -- table )) define-declared
  76
  77 \ byte-bit-count make-inline
  78
  79 >>
  80
  81 GENERIC: (bit-count) ( x -- n )
  82
  83 M: fixnum (bit-count)
  84     [
  85         {
  86             [           byte-bit-count ]
  87             [ -8  shift byte-bit-count ]
  88             [ -16 shift byte-bit-count ]
  89             [ -24 shift byte-bit-count ]
  90         } cleave
  91     ] sum-outputs ;
  92
  93 M: bignum (bit-count)
  94     dup 0 = [ drop 0 ] [
  95         [ byte-bit-count ] [ -8 shift (bit-count) ] bi +
  96     ] if ;
  97
  98 PRIVATE>
  99
 100 : bit-count ( x -- n )
 101     dup 0 < [ bitnot ] when (bit-count) ; inline
 102
 103 ! Signed byte array to integer conversion
 104 : signed-le> ( bytes -- x )
 105     [ le> ] [ length 8 * 1 - on-bits ] bi
 106     2dup > [ bitnot bitor ] [ drop ] if ;
 107
 108 : signed-be> ( bytes -- x )
 109     <reversed> signed-le> ;
 110
 111 : >signed ( x n -- y )
 112     2dup neg 1 + shift 1 = [ 2^ - ] [ drop ] if ;
 113
 114 : >odd ( n -- int ) 0 set-bit ; foldable
 115
 116 : >even ( n -- int ) 0 clear-bit ; foldable
 117
 118 : next-even ( m -- n ) >even 2 + ; foldable
 119
 120 : next-odd ( m -- n ) dup even? [ 1 + ] [ 2 + ] if ; foldable