basis/math/complex/complex.factor

   1 ! Copyright (C) 2006, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel kernel.private math math.private
   4 math.libm math.functions arrays math.functions.private sequences
   5 parser ;
   6 IN: math.complex.private
   7
   8 M: real real-part ;
   9 M: real imaginary-part drop 0 ;
  10 M: complex real-part real>> ;
  11 M: complex imaginary-part imaginary>> ;
  12 M: complex absq >rect [ sq ] bi@ + ;
  13 M: complex hashcode* nip >rect [ hashcode ] bi@ bitxor ;
  14 : componentwise ( x y quot -- a b ) [ [ >rect ] bi@ ] dip bi-curry@ bi* ; inline
  15 : complex= ( x y quot -- ? ) componentwise and ; inline
  16 M: complex equal? over complex? [ [ = ] complex= ] [ 2drop f ] if ;
  17 M: complex number= [ number= ] complex= ;
  18 : complex-op ( x y quot -- z ) componentwise (rect>) ; inline
  19 M: complex + [ + ] complex-op ;
  20 M: complex - [ - ] complex-op ;
  21 : *re ( x y -- xr*yr xi*yi ) [ >rect ] bi@ [ * ] bi-curry@ bi* ; inline
  22 : *im ( x y -- xi*yr xr*yi ) swap [ >rect ] bi@ swap [ * ] bi-curry@ bi* ; inline
  23 M: complex * [ *re - ] [ *im + ] 2bi (rect>) ;
  24 : (complex/) ( x y -- r i m ) [ [ *re + ] [ *im - ] 2bi ] keep absq ; inline
  25 : complex/ ( x y quot -- z ) [ (complex/) ] dip curry bi@ (rect>) ; inline
  26 M: complex / [ / ] complex/ ;
  27 M: complex /f [ /f ] complex/ ;
  28 M: complex /i [ /i ] complex/ ;
  29 M: complex abs absq >float fsqrt ;
  30 M: complex sqrt >polar [ fsqrt ] [ 2.0 / ] bi* polar> ;
  31
  32 IN: syntax
  33
  34 : C{ \ } [ first2 rect> ] parse-literal ; parsing
  35
  36 USE: prettyprint.custom
  37
  38 M: complex pprint* pprint-object ;
  39 M: complex pprint-delims drop \ C{ \ } ;
  40 M: complex >pprint-sequence >rect 2array ;