basis/math/functions/functions.factor

   1 ! Copyright (C) 2004, 2008 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: math kernel math.constants math.private math.bits
   4 math.libm combinators math.order sequences ;
   5 IN: math.functions
   6
   7 : >fraction ( a/b -- a b )
   8     [ numerator ] [ denominator ] bi ; inline
   9
  10 : rect> ( x y -- z )
  11     dup 0 = [ drop ] [ complex boa ] if ; inline
  12
  13 GENERIC: sqrt ( x -- y ) foldable
  14
  15 M: real sqrt
  16     >float dup 0.0 < [ neg fsqrt 0.0 swap rect> ] [ fsqrt ] if ;
  17
  18 : factor-2s ( n -- r s )
  19     #! factor an integer into 2^r * s
  20     dup 0 = [ 1 ] [
  21         0 swap [ dup even? ] [ [ 1 + ] [ 2/ ] bi* ] while
  22     ] if ; inline
  23
  24 <PRIVATE
  25
  26 GENERIC# ^n 1 ( z w -- z^w ) foldable
  27
  28 : (^n) ( z w -- z^w )
  29     make-bits 1 [ [ dupd * ] when [ sq ] dip ] reduce nip ; inline
  30
  31 M: integer ^n
  32     [ factor-2s ] dip [ (^n) ] keep rot * shift ;
  33
  34 M: ratio ^n
  35     [ >fraction ] dip [ ^n ] curry bi@ / ;
  36
  37 M: float ^n (^n) ;
  38
  39 M: complex ^n (^n) ;
  40
  41 : integer^ ( x y -- z )
  42     dup 0 > [ ^n ] [ neg ^n recip ] if ; inline
  43
  44 PRIVATE>
  45
  46 : >rect ( z -- x y )
  47     [ real-part ] [ imaginary-part ] bi ; inline
  48
  49 : >float-rect ( z -- x y )
  50     >rect [ >float ] bi@ ; inline
  51
  52 : >polar ( z -- abs arg )
  53     >float-rect [ [ sq ] bi@ + fsqrt ] [ swap fatan2 ] 2bi ; inline
  54
  55 : cis ( arg -- z ) dup fcos swap fsin rect> ; inline
  56
  57 : polar> ( abs arg -- z ) cis * ; inline
  58
  59 <PRIVATE
  60
  61 : ^mag ( w abs arg -- magnitude )
  62     [ >float-rect swap ] [ swap fpow ] [ rot * fexp /f ] tri* ; inline
  63
  64 : ^theta ( w abs arg -- theta )
  65     [ >float-rect ] [ flog * swap ] [ * + ] tri* ; inline
  66
  67 : ^complex ( x y -- z )
  68     swap >polar [ ^mag ] [ ^theta ] 3bi polar> ; inline
  69
  70 : real^? ( x y -- ? )
  71     2dup [ real? ] both? [ drop 0 >= ] [ 2drop f ] if ; inline
  72
  73 : 0^ ( x -- z )
  74     dup zero? [ drop 0/0. ] [ 0 < 1/0. 0 ? ] if ; inline
  75
  76 : (^mod) ( n x y -- z )
  77     make-bits 1 [
  78         [ dupd * pick mod ] when [ sq over mod ] dip
  79     ] reduce 2nip ; inline
  80
  81 : (gcd) ( b a x y -- a d )
  82     over zero? [
  83         2nip
  84     ] [
  85         swap [ /mod [ over * swapd - ] dip ] keep (gcd)
  86     ] if ;
  87
  88 PRIVATE>
  89
  90 : ^ ( x y -- z )
  91     {
  92         { [ over 0 = ] [ nip 0^ ] }
  93         { [ dup integer? ] [ integer^ ] }
  94         { [ 2dup real^? ] [ fpow ] }
  95         [ ^complex ]
  96     } cond ; inline
  97
  98 : gcd ( x y -- a d )
  99     [ 0 1 ] 2dip (gcd) dup 0 < [ neg ] when ; foldable
 100
 101 : lcm ( a b -- c )
 102     [ * ] 2keep gcd nip /i ; foldable
 103
 104 : divisor? ( m n -- ? )
 105     mod 0 = ;
 106
 107 : mod-inv ( x n -- y )
 108     [ nip ] [ gcd 1 = ] 2bi
 109     [ dup 0 < [ + ] [ nip ] if ]
 110     [ "Non-trivial divisor found" throw ] if ; foldable
 111
 112 : ^mod ( x y n -- z )
 113     over 0 < [
 114         [ [ neg ] dip ^mod ] keep mod-inv
 115     ] [
 116         -rot (^mod)
 117     ] if ; foldable
 118
 119 GENERIC: absq ( x -- y ) foldable
 120
 121 M: real absq sq ;
 122
 123 : ~abs ( x y epsilon -- ? )
 124     [ - abs ] dip < ;
 125
 126 : ~rel ( x y epsilon -- ? )
 127     [ [ - abs ] 2keep [ abs ] bi@ + ] dip * < ;
 128
 129 : ~ ( x y epsilon -- ? )
 130     {
 131         { [ 2over [ fp-nan? ] either? ] [ 3drop f ] }
 132         { [ dup zero? ] [ drop number= ] }
 133         { [ dup 0 < ] [ ~rel ] }
 134         [ ~abs ]
 135     } cond ;
 136
 137 : conjugate ( z -- z* ) >rect neg rect> ; inline
 138
 139 : arg ( z -- arg ) >float-rect swap fatan2 ; inline
 140
 141 : [-1,1]? ( x -- ? )
 142     dup complex? [ drop f ] [ abs 1 <= ] if ; inline
 143
 144 : >=1? ( x -- ? )
 145     dup complex? [ drop f ] [ 1 >= ] if ; inline
 146
 147 GENERIC: exp ( x -- y )
 148
 149 M: real exp fexp ;
 150
 151 M: complex exp >rect swap fexp swap polar> ;
 152
 153 GENERIC: log ( x -- y )
 154
 155 M: real log dup 0.0 >= [ flog ] [ 0.0 rect> log ] if ;
 156
 157 M: complex log >polar swap flog swap rect> ;
 158
 159 GENERIC: cos ( x -- y ) foldable
 160
 161 M: complex cos
 162     >float-rect
 163     [ [ fcos ] [ fcosh ] bi* * ]
 164     [ [ fsin neg ] [ fsinh ] bi* * ] 2bi rect> ;
 165
 166 M: real cos fcos ;
 167
 168 : sec ( x -- y ) cos recip ; inline
 169
 170 GENERIC: cosh ( x -- y ) foldable
 171
 172 M: complex cosh
 173     >float-rect
 174     [ [ fcosh ] [ fcos ] bi* * ]
 175     [ [ fsinh ] [ fsin ] bi* * ] 2bi rect> ;
 176
 177 M: real cosh fcosh ;
 178
 179 : sech ( x -- y ) cosh recip ; inline
 180
 181 GENERIC: sin ( x -- y ) foldable
 182
 183 M: complex sin
 184     >float-rect
 185     [ [ fsin ] [ fcosh ] bi* * ]
 186     [ [ fcos ] [ fsinh ] bi* * ] 2bi rect> ;
 187
 188 M: real sin fsin ;
 189
 190 : cosec ( x -- y ) sin recip ; inline
 191
 192 GENERIC: sinh ( x -- y ) foldable
 193
 194 M: complex sinh
 195     >float-rect
 196     [ [ fsinh ] [ fcos ] bi* * ]
 197     [ [ fcosh ] [ fsin ] bi* * ] 2bi rect> ;
 198
 199 M: real sinh fsinh ;
 200
 201 : cosech ( x -- y ) sinh recip ; inline
 202
 203 GENERIC: tan ( x -- y ) foldable
 204
 205 M: complex tan [ sin ] [ cos ] bi / ;
 206
 207 M: real tan ftan ;
 208
 209 GENERIC: tanh ( x -- y ) foldable
 210
 211 M: complex tanh [ sinh ] [ cosh ] bi / ;
 212
 213 M: real tanh ftanh ;
 214
 215 : cot ( x -- y ) tan recip ; inline
 216
 217 : coth ( x -- y ) tanh recip ; inline
 218
 219 : acosh ( x -- y )
 220     dup sq 1 - sqrt + log ; inline
 221
 222 : asech ( x -- y ) recip acosh ; inline
 223
 224 : asinh ( x -- y )
 225     dup sq 1 + sqrt + log ; inline
 226
 227 : acosech ( x -- y ) recip asinh ; inline
 228
 229 : atanh ( x -- y )
 230     [ 1 + ] [ 1 - neg ] bi / log 2 / ; inline
 231
 232 : acoth ( x -- y ) recip atanh ; inline
 233
 234 : i* ( x -- y ) >rect neg swap rect> ;
 235
 236 : -i* ( x -- y ) >rect swap neg rect> ;
 237
 238 : asin ( x -- y )
 239     dup [-1,1]? [ fasin ] [ i* asinh -i* ] if ; inline
 240
 241 : acos ( x -- y )
 242     dup [-1,1]? [ facos ] [ asin pi 2 / swap - ] if ;
 243     inline
 244
 245 GENERIC: atan ( x -- y ) foldable
 246
 247 M: complex atan i* atanh i* ;
 248
 249 M: real atan fatan ;
 250
 251 : asec ( x -- y ) recip acos ; inline
 252
 253 : acosec ( x -- y ) recip asin ; inline
 254
 255 : acot ( x -- y ) recip atan ; inline
 256
 257 : truncate ( x -- y ) dup 1 mod - ; inline
 258
 259 : round ( x -- y ) dup sgn 2 / + truncate ; inline
 260
 261 : floor ( x -- y )
 262     dup 1 mod dup zero?
 263     [ drop ] [ dup 0 < [ - 1 - ] [ - ] if ] if ; foldable
 264
 265 : ceiling ( x -- y ) neg floor neg ; foldable
 266
 267 : floor-to ( x step -- y )
 268     dup zero? [ drop ] [ [ / floor ] [ * ] bi ] if ;
 269
 270 : lerp ( a b t -- a_t ) [ over - ] dip * + ; inline
 271