basis/math/primes/primes.factor

   1 ! Copyright (C) 2007-2009 Samuel Tardieu.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: combinators combinators.short-circuit fry kernel math
   4 math.bitwise math.functions math.order math.primes.erato
   5 math.primes.erato.private math.primes.miller-rabin math.ranges
   6 literals random sequences sets vectors ;
   7 IN: math.primes
   8
   9 <PRIVATE
  10
  11 : look-in-bitmap ( n -- ? ) $[ 8999999 sieve ] marked-unsafe? ; inline
  12
  13 : (prime?) ( n -- ? )
  14     dup 8999999 <= [ look-in-bitmap ] [ miller-rabin ] if ;
  15
  16 ! In order not to reallocate large vectors, we compute the upper bound
  17 ! of the number of primes in a given interval. We use a double inequality given
  18 ! by Pierre Dusart in http://www.ams.org/mathscinet-getitem?mr=99d:11133
  19 ! for x > 598. Under this limit, we know that there are at most 108 primes.
  20 : upper-pi ( x -- y )
  21     dup log [ / ] [ 1.2762 swap / 1 + ] bi * ceiling ;
  22
  23 : lower-pi ( x -- y )
  24     dup log [ / ] [ 0.992 swap / 1 + ] bi * floor ;
  25
  26 : <primes-vector> ( low high -- vector )
  27     swap [ [ upper-pi ] [ lower-pi ] bi* - >integer
  28     108 max 10000 min <vector> ] keep
  29     3 < [ [ 2 swap push ] keep ] when ;
  30
  31 : simple? ( n -- ? ) { [ even? ] [ 3 mod 0 = ] [ 5 mod 0 = ] } 1|| ;
  32
  33 PRIVATE>
  34
  35 : prime? ( n -- ? )
  36     {
  37         { [ dup 7 < ] [ { 2 3 5 } member? ] }
  38         { [ dup simple? ] [ drop f ] }
  39         [ (prime?) ]
  40     } cond ; foldable
  41
  42 : next-prime ( n -- p )
  43     dup 2 < [
  44         drop 2
  45     ] [
  46         next-odd [ dup prime? ] [ 2 + ] until
  47     ] if ; foldable
  48
  49 <PRIVATE
  50
  51 : (primes-between) ( low high -- seq )
  52     [ [ 3 max dup even? [ 1 + ] when ] dip 2 <range> ]
  53     [ <primes-vector> ] 2bi
  54     [ '[ [ prime? ] _ push-if ] each ] keep clone ;
  55
  56 PRIVATE>
  57
  58 : primes-between ( low high -- seq )
  59     [ ceiling >integer ] [ floor >integer ] bi*
  60     {
  61         { [ 2dup > ] [ 2drop V{ } clone ] }
  62         { [ dup 2 = ] [ 2drop V{ 2 } clone ] }
  63         { [ dup 2 < ] [ 2drop V{ } clone ] }
  64         [ (primes-between) ]
  65     } cond ;
  66
  67 : primes-upto ( n -- seq ) 2 swap primes-between ;
  68
  69 : coprime? ( a b -- ? ) gcd nip 1 = ; foldable
  70
  71 : random-prime ( numbits -- p )
  72     [ ] [ 2^ ] [ random-bits* next-prime ] tri
  73     2dup < [ 2drop random-prime ] [ 2nip ] if ;
  74
  75 : estimated-primes ( m -- n )
  76     dup log / ; foldable
  77
  78 ERROR: no-relative-prime n ;
  79
  80 <PRIVATE
  81
  82 : (find-relative-prime) ( n guess -- p )
  83     over 1 <= [ over no-relative-prime ] when
  84     dup 1 <= [ drop 3 ] when
  85     [ 2dup coprime? ] [ 2 + ] until nip ;
  86
  87 PRIVATE>
  88
  89 : find-relative-prime* ( n guess -- p )
  90     #! find a prime relative to n with initial guess
  91     >odd (find-relative-prime) ;
  92
  93 : find-relative-prime ( n -- p )
  94     dup random find-relative-prime* ;
  95
  96 ERROR: too-few-primes n numbits ;
  97
  98 : unique-primes ( n numbits -- seq )
  99     2dup 2^ estimated-primes > [ too-few-primes ] when
 100     2dup [ random-prime ] curry replicate
 101     dup all-unique? [ 2nip ] [ drop unique-primes ] if ;