basis/math/primes/primes.factor

   1 ! Copyright (C) 2007-2009 Samuel Tardieu.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: combinators kernel math math.functions math.miller-rabin
   4 math.order math.primes.erato math.ranges sequences ;
   5 IN: math.primes
   6
   7 <PRIVATE
   8
   9 : look-in-bitmap ( n -- ? ) >index 4999999 sieve nth ;
  10
  11 : really-prime? ( n -- ? )
  12     dup 5000000 < [ look-in-bitmap ] [ miller-rabin ] if ; foldable
  13
  14 PRIVATE>
  15
  16 : prime? ( n -- ? )
  17     {
  18         { [ dup 2 < ] [ drop f ] }
  19         { [ dup even? ] [ 2 = ] }
  20         [ really-prime? ]
  21     } cond ; foldable
  22
  23 : next-prime ( n -- p )
  24     next-odd [ dup really-prime? ] [ 2 + ] until ; foldable
  25
  26 : primes-between ( low high -- seq )
  27     [ dup 3 max dup even? [ 1 + ] when ] dip
  28     2 <range> [ prime? ] filter
  29     swap 3 < [ 2 prefix ] when ;
  30
  31 : primes-upto ( n -- seq ) 2 swap primes-between ;
  32
  33 : coprime? ( a b -- ? ) gcd nip 1 = ; foldable