basis/math/primes/primes.factor

   1 ! Copyright (C) 2007-2009 Samuel Tardieu.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: combinators kernel math math.functions
   4 math.primes.miller-rabin math.order math.primes.erato
   5 math.ranges sequences ;
   6 IN: math.primes
   7
   8 <PRIVATE
   9
  10 : look-in-bitmap ( n -- ? ) >index 4999999 sieve nth ;
  11
  12 : really-prime? ( n -- ? )
  13     dup 5000000 < [ look-in-bitmap ] [ miller-rabin ] if ; foldable
  14
  15 PRIVATE>
  16
  17 : prime? ( n -- ? )
  18     {
  19         { [ dup 2 < ] [ drop f ] }
  20         { [ dup even? ] [ 2 = ] }
  21         [ really-prime? ]
  22     } cond ; foldable
  23
  24 : next-prime ( n -- p )
  25     next-odd [ dup really-prime? ] [ 2 + ] until ; foldable
  26
  27 : primes-between ( low high -- seq )
  28     [ dup 3 max dup even? [ 1 + ] when ] dip
  29     2 <range> [ prime? ] filter
  30     swap 3 < [ 2 prefix ] when ;
  31
  32 : primes-upto ( n -- seq ) 2 swap primes-between ;
  33
  34 : coprime? ( a b -- ? ) gcd nip 1 = ; foldable