basis/math/statistics/statistics.factor

   1 ! Copyright (C) 2008 Doug Coleman, Michael Judge, Loryn Jenkins.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: assocs combinators generalizations kernel locals math
   4 math.functions math.order math.vectors math.ranges sequences
   5 sequences.private sorting fry arrays grouping sets
   6 splitting.monotonic ;
   7 IN: math.statistics
   8
   9 : power-mean ( seq p -- x )
  10     [ '[ _ ^ ] map-sum ] [ [ length / ] [ recip ^ ] bi* ] 2bi ; inline
  11
  12 ! Delta in degrees-of-freedom
  13 : mean-ddof ( seq ddof -- x )
  14     [ [ sum ] [ length ] bi ] dip -
  15     [ drop 0 ] [ / ] if-zero ; inline
  16
  17 : mean ( seq -- x )
  18     0 mean-ddof ; inline
  19
  20 : unbiased-mean ( seq -- x )
  21     1 mean-ddof ; inline
  22
  23 : sum-of-squares ( seq -- x )
  24     [ sq ] map-sum ; inline
  25
  26 : sum-of-squared-errors ( seq -- x )
  27     [ mean ] keep [ - sq ] with map-sum ; inline
  28
  29 : sum-of-absolute-errors ( seq -- x )
  30     [ mean ] keep [ - ] with map-sum ; inline
  31
  32 : quadratic-mean ( seq -- x ) ! root-mean-square
  33     [ sum-of-squares ] [ length ] bi / sqrt ; inline
  34
  35 : geometric-mean ( seq -- x )
  36     [ [ log ] map-sum ] [ length ] bi /f e^ ; inline
  37
  38 : harmonic-mean ( seq -- x )
  39     [ recip ] map-sum recip ; inline
  40
  41 : contraharmonic-mean ( seq -- x )
  42     [ sum-of-squares ] [ sum ] bi / ; inline
  43
  44 <PRIVATE
  45
  46 : trim-points ( p seq -- from to seq  )
  47     [ length [ * >integer ] keep over - ] keep ;
  48
  49 PRIVATE>
  50
  51 : trimmed-mean ( seq p -- x )
  52     swap natural-sort trim-points <slice> mean ;
  53
  54 : winsorized-mean ( seq p -- x )
  55     swap natural-sort trim-points
  56     [ <slice> ]
  57     [ nip dupd nth <array> ]
  58     [ [ 1 - ] dip nth <array> ] 3tri
  59     surround mean ;
  60
  61 <PRIVATE
  62
  63 :: ((kth-object)) ( seq k nth-quot exchange-quot quot: ( x y -- ? ) -- elt )
  64     ! Wirth's method, Algorithm's + Data structues = Programs p. 84
  65     k seq bounds-check 2drop
  66     0 :> i!
  67     0 :> j!
  68     0 :> l!
  69     0 :> x!
  70     seq length 1 - :> m!
  71     [ l m < ]
  72     [
  73         k seq nth-unsafe x!
  74         l i!
  75         m j!
  76         [ i j <= ]
  77         [
  78             [ i seq nth-quot call x quot call ] [ i 1 + i! ] while
  79             [ x j seq nth-quot call quot call ] [ j 1 - j! ] while
  80             i j <= [
  81                 i j seq exchange-quot call
  82                 i 1 + i!
  83                 j 1 - j!
  84             ] when
  85         ] do while
  86
  87         j k < [ i l! ] when
  88         k i < [ j m! ] when
  89     ] while
  90     k seq nth-unsafe ; inline
  91
  92 : (kth-object) ( seq k nth-quot exchange-quot quot: ( x y -- ? ) -- elt )
  93     ! The algorithm modifiers seq, so we clone it
  94     [ >array ] 4dip ((kth-object)) ; inline
  95
  96 : kth-object-unsafe ( seq k quot: ( x y -- ? ) -- elt )
  97     [ [ nth-unsafe ] [ exchange-unsafe ] ] dip (kth-object) ; inline
  98
  99 : kth-objects-unsafe ( seq kths quot: ( x y -- ? ) -- elts )
 100     '[ _ kth-object-unsafe ] with map ; inline
 101
 102 PRIVATE>
 103
 104 : kth-object ( seq k quot: ( x y -- ? ) -- elt )
 105     [ [ nth ] [ exchange ] ] dip (kth-object) ; inline
 106
 107 : kth-objects ( seq kths quot: ( x y -- ? ) -- elts )
 108     '[ _ kth-object ] with map ; inline
 109
 110 : kth-smallests ( seq kths -- elts ) [ < ] kth-objects-unsafe ;
 111
 112 : kth-smallest ( seq k -- elt ) [ < ] kth-object-unsafe ;
 113
 114 : kth-largests ( seq kths -- elts ) [ > ] kth-objects-unsafe ;
 115
 116 : kth-largest ( seq k -- elt ) [ > ] kth-object-unsafe ;
 117
 118 : count-relative ( seq k -- lt eq gt )
 119     [ 0 0 0 ] 2dip '[
 120         _ <=> {
 121             { +lt+ [ [ 1 + ] 2dip ] }
 122             { +gt+ [ 1 + ] }
 123             { +eq+ [ [ 1 + ] dip ] }
 124         } case
 125     ] each ;
 126
 127 : minmax-relative ( seq k -- lt eq gt lt-max gt-min )
 128     [ 0 0 0 -1/0. 1/0. ] 2dip '[
 129         dup _ <=> {
 130             { +lt+ [ [ 1 + ] 5 ndip '[ _ max ] dip ] }
 131             { +gt+ [ [ 1 + ] 3dip min ] }
 132             { +eq+ [ [ 1 + ] 4dip drop ] }
 133         } case
 134     ] each ;
 135
 136 : lower-median-index ( seq -- n )
 137     [ midpoint@ ]
 138     [ length odd? [ 1 - ] unless ] bi ;
 139
 140 : lower-median ( seq -- elt )
 141     [ ] [ lower-median-index ] bi kth-smallest ;
 142
 143 : upper-median ( seq -- elt )
 144     dup midpoint@ kth-smallest ;
 145
 146 : medians ( seq -- lower upper )
 147     [ ]
 148     [ [ lower-median-index ] [ midpoint@ ] bi 2array ]
 149     bi kth-smallests first2 ;
 150
 151 : median ( seq -- x )
 152     dup length odd? [ lower-median ] [ medians + 2 / ] if ;
 153
 154 ! quantile can be any n-tile. quartile is n = 4, percentile is n = 100
 155 ! a,b,c,d parameters, N - number of samples, q is quantile (1/2 for median, 1/4 for 1st quartile)
 156 ! http://mathworld.wolfram.com/Quantile.html
 157 ! a + (N + b) q - 1
 158 ! could subtract 1 from a
 159
 160 : quantile-x ( a b N q -- x )
 161     [ + ] dip * + 1 - ; inline
 162
 163 ! 2+1/4 frac is 1/4
 164 : frac ( x -- x' )
 165     >fraction [ /mod nip ] keep / ; inline
 166
 167 :: quantile-indices ( seq qs a b -- seq )
 168     qs [ [ a b seq length ] dip quantile-x ] map ;
 169
 170 :: qabcd ( y-floor y-ceiling x c d -- qabcd )
 171     y-floor y-ceiling y-floor - c d x frac * + * + ;
 172
 173 :: quantile-abcd ( seq qs a b c d -- quantile )
 174     seq qs a b quantile-indices :> indices
 175     indices [ [ floor 0 max ] [ ceiling seq length 1 - min ] bi 2array ] map
 176     concat :> index-pairs
 177
 178     seq index-pairs kth-smallests
 179     2 group indices [ [ first2 ] dip c d qabcd ] 2map ;
 180
 181 : quantile1 ( seq qs -- seq' )
 182     0 0 1 0 quantile-abcd ;
 183
 184 : quantile3 ( seq qs -- seq' )
 185     1/2 0 0 0 quantile-abcd ;
 186
 187 : quantile4 ( seq qs -- seq' )
 188     0 0 0 1 quantile-abcd ;
 189
 190 : quantile5 ( seq qs -- seq' )
 191     1/2 0 0 1 quantile-abcd ;
 192
 193 : quantile6 ( seq qs -- seq' )
 194     0 1 0 1 quantile-abcd ;
 195
 196 : quantile7 ( seq qs -- seq' )
 197     1 -1 0 1 quantile-abcd ;
 198
 199 : quantile8 ( seq qs -- seq' )
 200     1/3 1/3 0 1 quantile-abcd ;
 201
 202 : quantile9 ( seq qs -- seq' )
 203     3/8 1/4 0 1 quantile-abcd ;
 204
 205 : quartile ( seq -- seq' )
 206     { 1/4 1/2 3/4 } quantile5 ;
 207
 208 : trimean ( seq -- x )
 209     quartile first3 [ 2 * ] dip + + 4 / ;
 210
 211 <PRIVATE
 212
 213 : (sequence>assoc) ( seq map-quot insert-quot assoc -- assoc )
 214     [ swap curry compose each ] keep ; inline
 215
 216 : (sequence-index>assoc) ( seq map-quot insert-quot assoc -- assoc )
 217     [ swap curry compose each-index ] keep ; inline
 218
 219 PRIVATE>
 220
 221 : sequence>assoc! ( assoc seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) -- assoc )
 222     4 nrot (sequence>assoc) ; inline
 223
 224 : sequence>assoc ( seq map-quot insert-quot exemplar -- assoc )
 225     clone (sequence>assoc) ; inline
 226
 227 : sequence-index>assoc ( seq map-quot insert-quot exemplar -- assoc )
 228     clone (sequence-index>assoc) ; inline
 229
 230 : sequence-index>hashtable ( seq map-quot insert-quot -- hashtable )
 231     H{ } sequence-index>assoc ; inline
 232
 233 : sequence>hashtable ( seq map-quot insert-quot -- hashtable )
 234     H{ } sequence>assoc ; inline
 235
 236 : histogram! ( hashtable seq -- hashtable )
 237     [ ] [ inc-at ] sequence>assoc! ;
 238
 239 : histogram-by ( seq quot: ( x -- bin ) -- hashtable )
 240     [ inc-at ] sequence>hashtable ; inline
 241
 242 : histogram ( seq -- hashtable )
 243     [ ] histogram-by ;
 244
 245 : sorted-histogram ( seq -- alist )
 246     histogram sort-values ;
 247
 248 : normalized-histogram ( seq -- alist )
 249     [ histogram ] [ length ] bi '[ _ / ] assoc-map ;
 250
 251 : collect-index-by ( ... seq quot: ( ... obj -- ... key ) -- ... hashtable )
 252     [ dip swap ] curry [ push-at ] sequence-index>hashtable ; inline
 253
 254 : collect-by ( ... seq quot: ( ... obj -- ... key ) -- ... hashtable )
 255     [ keep swap ] curry [ push-at ] sequence>hashtable ; inline
 256
 257 : equal-probabilities ( n -- array )
 258     dup recip <array> ; inline
 259
 260 : mode ( seq -- x )
 261     histogram >alist [ second ] supremum-by first ;
 262
 263 : minmax ( seq -- min max )
 264     [ first dup ] keep [ [ min ] [ max ] bi-curry bi* ] each ;
 265
 266 : range ( seq -- x )
 267     minmax swap - ;
 268
 269 : var-ddof ( seq n -- x )
 270     2dup [ length ] dip - 0 <= [
 271         2drop 0
 272     ] [
 273         [ [ sum-of-squared-errors ] [ length ] bi ] dip - /
 274     ] if ; inline
 275
 276 : population-var ( seq -- x ) 0 var-ddof ; inline
 277
 278 : sample-var ( seq -- x ) 1 var-ddof ; inline
 279
 280 : std-ddof ( seq n -- x )
 281     var-ddof sqrt ; inline
 282
 283 : population-std ( seq -- x ) 0 std-ddof ; inline
 284
 285 : sample-std ( seq -- x ) 1 std-ddof ; inline
 286
 287 ALIAS: std sample-std
 288
 289 : signal-to-noise ( seq -- x ) [ mean ] [ population-std ] bi / ;
 290
 291 : demean ( seq -- seq' ) dup mean v-n ;
 292
 293 : mean-dev ( seq -- x ) demean vabs mean ;
 294
 295 : demedian ( seq -- seq' ) dup median v-n ;
 296
 297 : median-dev ( seq -- x ) demedian vabs mean ;
 298
 299 : ste-ddof ( seq n -- x ) '[ _ std-ddof ] [ length ] bi sqrt / ;
 300
 301 : population-ste ( seq -- x ) 0 ste-ddof ;
 302
 303 : sample-ste ( seq -- x ) 1 ste-ddof ;
 304
 305 : ((r)) ( x-mean y-mean x-seq y-seq -- (r) )
 306     ! finds sigma((xi-mean(x))(yi-mean(y))
 307     0 [ [ [ pick ] dip swap - ] bi@ * + ] 2reduce 2nip ;
 308
 309 : (r) ( x-mean y-mean x-seq y-seq x-std y-std -- r )
 310     * recip [ [ ((r)) ] keep length 1 - / ] dip * ;
 311
 312 : [r] ( xy-pairs -- x-mean y-mean x-seq y-seq x-std y-std )
 313     first2 [ [ [ mean ] bi@ ] 2keep ] 2keep [ population-std ] bi@ ;
 314
 315 : r ( xy-pairs -- r )
 316     [r] (r) ;
 317
 318 : r^2 ( xy-pairs -- r )
 319     r sq ;
 320
 321 : least-squares ( xy-pairs -- alpha beta )
 322     [r] { [ 2dup ] [ ] [ ] [ ] [ ] } spread
 323     ! stack is x-mean y-mean x-mean y-mean x-seq y-seq x-std y-std
 324     [ (r) ] 2keep ! stack is mean(x) mean(y) r sx sy
 325     swap / * ! stack is mean(x) mean(y) beta
 326     [ swapd * - ] keep ;
 327
 328 : cov-ddof ( x-seq y-seq ddof -- cov )
 329     [ [ demean ] bi@ v* ] dip mean-ddof ;
 330
 331 : population-cov ( x-seq y-seq -- cov ) 0 cov-ddof ; inline
 332
 333 : sample-cov ( x-seq y-seq -- cov ) 1 cov-ddof ; inline
 334
 335 : corr-ddof ( x-seq y-seq n -- corr )
 336     [ [ population-cov ] ] dip
 337     '[ [ _ var-ddof ] bi@ * sqrt ] 2bi / ;
 338
 339 : population-corr ( x-seq y-seq -- corr ) 0 corr-ddof ; inline
 340
 341 : sample-corr ( x-seq y-seq -- corr ) 1 corr-ddof ; inline
 342
 343 : cum-map ( seq identity quot: ( prev elt -- next ) -- seq' )
 344     swapd [ dup ] compose map nip ; inline
 345
 346 : cum-sum ( seq -- seq' )
 347     0 [ + ] cum-map ;
 348
 349 : cum-sum0 ( seq -- seq' )
 350     0 [ + ] accumulate nip ;
 351
 352 : cum-product ( seq -- seq' )
 353     1 [ * ] cum-map ;
 354
 355 : cum-mean ( seq -- seq' )
 356     0 swap [ [ + dup ] dip 1 + / ] map-index nip ;
 357
 358 : cum-count ( seq quot -- seq' )
 359     [ 0 ] dip '[ _ call [ 1 + ] when ] cum-map ; inline
 360
 361 : cum-min ( seq -- seq' )
 362     dup ?first [ min ] cum-map ;
 363
 364 : cum-max ( seq -- seq' )
 365     dup ?first [ max ] cum-map ;
 366
 367 : entropy ( probabilities -- n )
 368     dup sum '[ _ / dup log * ] map-sum neg ;
 369
 370 : maximum-entropy ( probabilities -- n )
 371     length log ;
 372
 373 : normalized-entropy ( probabilities -- n )
 374     [ entropy ] [ maximum-entropy ] bi / ;
 375
 376 : binary-entropy ( p -- h )
 377     [ dup log * ] [ 1 swap - dup log * ] bi + neg 2 log / ;
 378
 379 : standardize ( u -- v )
 380     [ demean ] [ sample-std ] bi [ v/n ] unless-zero ;
 381
 382 : standardize-2d ( u -- v )
 383     flip [ standardize ] map flip ;
 384
 385 : differences ( u -- v )
 386     [ rest-slice ] keep v- ;
 387
 388 : rescale ( u -- v )
 389     dup minmax over - [ v-n ] [ v/n ] bi* ;
 390
 391 : rankings ( histogram -- assoc )
 392     sort-keys 0 swap [ rot [ + ] keep swapd ] H{ } assoc-map-as nip ;
 393
 394 : rank-values ( seq -- seq' )
 395     dup histogram rankings '[ _ at ] map ;
 396
 397 : z-score ( seq -- n )
 398     [ demean ] [ sample-std ] bi v/n ;