basis/math/statistics/statistics.factor

   1 ! Copyright (C) 2008 Doug Coleman, Michael Judge.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: assocs combinators generalizations kernel locals math
   4 math.functions math.order math.vectors sequences
   5 sequences.private sorting fry arrays grouping sets ;
   6 IN: math.statistics
   7
   8 : power-mean ( seq p -- x )
   9     [ '[ _ ^ ] map-sum ] [ [ length / ] [ recip ^ ] bi* ] 2bi ; inline
  10
  11 : mean ( seq -- x )
  12     [ sum ] [ length ] bi / ; inline
  13
  14 : sum-of-squares ( seq -- x )
  15     [ sq ] map-sum ; inline
  16
  17 : sum-of-squared-errors ( seq -- x )
  18     [ mean ] keep [ - sq ] with map-sum ; inline
  19
  20 : sum-of-absolute-errors ( seq -- x )
  21     [ mean ] keep [ - ] with map-sum ; inline
  22
  23 : quadratic-mean ( seq -- x ) ! root-mean-square
  24     [ sum-of-squares ] [ length ] bi / sqrt ; inline
  25
  26 : geometric-mean ( seq -- x )
  27     [ length ] [ product ] bi nth-root ; inline
  28
  29 : harmonic-mean ( seq -- x )
  30     [ recip ] map-sum recip ; inline
  31
  32 : contraharmonic-mean ( seq -- x )
  33     [ sum-of-squares ] [ sum ] bi / ; inline
  34
  35 <PRIVATE
  36
  37 :: ((kth-object)) ( seq k nth-quot exchange-quot quot: ( x y -- ? ) -- elt )
  38     #! Wirth's method, Algorithm's + Data structues = Programs p. 84
  39     k seq bounds-check 2drop
  40     0 :> i!
  41     0 :> j!
  42     0 :> l!
  43     0 :> x!
  44     seq length 1 - :> m!
  45     [ l m < ]
  46     [
  47         k seq nth x!
  48         l i!
  49         m j!
  50         [ i j <= ]
  51         [
  52             [ i seq nth-quot call x quot call ] [ i 1 + i! ] while
  53             [ x j seq nth-quot call quot call ] [ j 1 - j! ] while
  54             i j <= [
  55                 i j seq exchange-quot call
  56                 i 1 + i!
  57                 j 1 - j!
  58             ] when
  59         ] do while
  60
  61         j k < [ i l! ] when
  62         k i < [ j m! ] when
  63     ] while
  64     k seq nth ; inline
  65
  66 : (kth-object) ( seq k nth-quot exchange-quot quot: ( x y -- ? ) -- elt )
  67     #! The algorithm modifiers seq, so we clone it
  68     [ clone ] 4dip ((kth-object)) ; inline
  69
  70 : kth-object-unsafe ( seq k quot: ( x y -- ? ) -- elt )
  71     [ [ nth-unsafe ] [ exchange-unsafe ] ] dip (kth-object) ; inline
  72
  73 : kth-objects-unsafe ( seq kths quot: ( x y -- ? ) -- elts )
  74     [ clone ] 2dip
  75     '[ [ nth-unsafe ] [ exchange-unsafe ]  _ ((kth-object)) ] with map ; inline
  76
  77 PRIVATE>
  78
  79 : kth-object ( seq k quot: ( x y -- ? ) -- elt )
  80     [ [ nth ] [ exchange ] ] dip (kth-object) ; inline
  81
  82 : kth-objects ( seq kths quot: ( x y -- ? ) -- elts )
  83     [ clone ] 2dip
  84     '[ [ nth ] [ exchange ]  _ ((kth-object)) ] with map ; inline
  85
  86 : kth-smallests ( seq kths -- elts ) [ < ] kth-objects-unsafe ;
  87
  88 : kth-smallest ( seq k -- elt ) [ < ] kth-object-unsafe ;
  89
  90 : kth-largests ( seq kths -- elts ) [ > ] kth-objects-unsafe ;
  91
  92 : kth-largest ( seq k -- elt ) [ > ] kth-object-unsafe ;
  93
  94 : count-relative ( seq k -- lt eq gt )
  95     [ 0 0 0 ] 2dip '[
  96         _ <=> {
  97             { +lt+ [ [ 1 + ] 2dip ] }
  98             { +gt+ [ 1 + ] }
  99             { +eq+ [ [ 1 + ] dip ] }
 100         } case
 101     ] each ;
 102
 103 : minmax-relative ( seq k -- lt eq gt lt-max gt-min )
 104     [ 0 0 0 -1/0. 1/0. ] 2dip '[
 105         dup _ <=> {
 106             { +lt+ [ [ 1 + ] 5 ndip '[ _ max ] dip ] }
 107             { +gt+ [ [ 1 + ] 3dip min ] }
 108             { +eq+ [ [ 1 + ] 4dip drop ] }
 109         } case
 110     ] each ;
 111
 112 : lower-median-index ( seq -- n )
 113     [ midpoint@ ]
 114     [ length odd? [ 1 - ] unless ] bi ;
 115
 116 : lower-median ( seq -- elt )
 117     [ ] [ lower-median-index ] bi kth-smallest ;
 118
 119 : upper-median ( seq -- elt )
 120     dup midpoint@ kth-smallest ;
 121
 122 : medians ( seq -- lower upper )
 123     [ ]
 124     [ [ lower-median-index ] [ midpoint@ ] bi 2array ]
 125     bi kth-smallests first2 ;
 126
 127 : median ( seq -- x )
 128     dup length odd?
 129     [ lower-median ] [ medians + 2 / ] if ;
 130
 131 ! quantile can be any n-tile. quartile is n = 4, percentile is n = 100
 132 ! a,b,c,d parameters, N - number of samples, q is quantile (1/2 for median, 1/4 for 1st quartile)
 133 ! http://mathworld.wolfram.com/Quantile.html
 134 ! a + (N + b) q - 1
 135 ! could subtract 1 from a
 136
 137 : quantile-x ( a b N q -- x )
 138     [ + ] dip * + 1 - ; inline
 139
 140 ! 2+1/4 frac is 1/4
 141 : frac ( x -- x' )
 142     >fraction [ /mod nip ] keep / ; inline
 143
 144 :: quantile-indices ( seq qs a b c d -- seq )
 145     qs [ [ a b seq length ] dip quantile-x ] map ;
 146
 147 :: qabcd ( y-floor y-ceiling x c d -- qabcd )
 148     y-floor y-ceiling y-floor - c d x frac * + * + ;
 149
 150 :: quantile-abcd ( seq qs a b c d -- quantile )
 151     seq qs a b c d quantile-indices :> indices
 152     indices [ [ floor ] [ ceiling ] bi 2array ] map
 153     concat :> index-pairs
 154
 155     seq index-pairs kth-smallests
 156     2 group indices [ [ first2 ] dip c d qabcd ] 2map ;
 157
 158 : quantile1 ( seq qs -- seq' )
 159     0 0 1 0 quantile-abcd ;
 160
 161 : quantile3 ( seq qs -- seq' )
 162     1/2 0 0 0 quantile-abcd ;
 163
 164 : quantile4 ( seq qs -- seq' )
 165     0 0 0 1 quantile-abcd ;
 166
 167 : quantile5 ( seq qs -- seq' )
 168     1/2 0 0 1 quantile-abcd ;
 169
 170 : quantile6 ( seq qs -- seq' )
 171     0 1 0 1 quantile-abcd ;
 172
 173 : quantile7 ( seq qs -- seq' )
 174     1 -1 0 1 quantile-abcd ;
 175
 176 : quantile8 ( seq qs -- seq' )
 177     1/3 1/3 0 1 quantile-abcd ;
 178
 179 : quantile9 ( seq qs -- seq' )
 180     3/8 1/4 0 1 quantile-abcd ;
 181
 182 : quartile ( seq -- seq' )
 183     { 1/4 1/2 3/4 } quantile5 ;
 184
 185 <PRIVATE
 186
 187 : (sequence>assoc) ( seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) assoc -- assoc )
 188     [ swap curry compose each ] keep ; inline
 189
 190 PRIVATE>
 191
 192 : sequence>assoc! ( assoc seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) -- assoc )
 193     4 nrot (sequence>assoc) ; inline
 194
 195 : sequence>assoc ( seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) exemplar -- assoc )
 196     clone (sequence>assoc) ; inline
 197
 198 : sequence>hashtable ( seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) -- hashtable )
 199     H{ } sequence>assoc ; inline
 200
 201 : histogram! ( hashtable seq -- hashtable )
 202     [ ] [ inc-at ] sequence>assoc! ;
 203
 204 : histogram-by ( seq quot: ( x -- bin ) -- hashtable )
 205     [ inc-at ] sequence>hashtable ; inline
 206
 207 : histogram ( seq -- hashtable )
 208     [ ] histogram-by ;
 209
 210 : sorted-histogram ( seq -- alist )
 211     histogram sort-values ;
 212
 213 : collect-pairs ( seq quot: ( x -- v k ) -- hashtable )
 214     [ push-at ] sequence>hashtable ; inline
 215
 216 : collect-by ( seq quot: ( x -- x' ) -- hashtable )
 217     [ dup ] prepose collect-pairs ; inline
 218
 219 : mode ( seq -- x )
 220     histogram >alist
 221     [ ] [ [ [ second ] bi@ > ] most ] map-reduce first ;
 222
 223 ERROR: empty-sequence ;
 224
 225 : minmax ( seq -- min max )
 226     [
 227         empty-sequence
 228     ] [
 229         [ first dup ] keep [ [ min ] [ max ] bi-curry bi* ] each
 230     ] if-empty ;
 231
 232 : range ( seq -- x )
 233     minmax swap - ;
 234
 235 : sample-var ( seq -- x )
 236     #! normalize by N-1; unbiased
 237     dup length 1 <= [
 238         drop 0
 239     ] [
 240         [ sum-of-squared-errors ] [ length 1 - ] bi /
 241     ] if ;
 242
 243 : full-var ( seq -- x )
 244     dup length 1 <= [
 245         drop 0
 246     ] [
 247         [ sum-of-squared-errors ] [ length ] bi /
 248     ] if ;
 249
 250 ALIAS: var sample-var
 251
 252 : sample-std ( seq -- x ) sample-var sqrt ;
 253
 254 : full-std ( seq -- x ) full-var sqrt ;
 255
 256 ALIAS: std sample-std
 257
 258 : mean-dev ( seq -- x ) dup mean v-n vabs mean ;
 259
 260 : median-dev ( seq -- x ) dup median v-n vabs mean ;
 261
 262 : sample-ste ( seq -- x ) [ sample-std ] [ length ] bi sqrt / ;
 263
 264 : full-ste ( seq -- x ) [ full-std ] [ length ] bi sqrt / ;
 265
 266 ALIAS: ste sample-ste
 267
 268 : ((r)) ( mean(x) mean(y) {x} {y} -- (r) )
 269     ! finds sigma((xi-mean(x))(yi-mean(y))
 270     0 [ [ [ pick ] dip swap - ] bi@ * + ] 2reduce 2nip ;
 271
 272 : (r) ( mean(x) mean(y) {x} {y} sx sy -- r )
 273     * recip [ [ ((r)) ] keep length 1 - / ] dip * ;
 274
 275 : [r] ( {{x,y}...} -- mean(x) mean(y) {x} {y} sx sy )
 276     first2 [ [ [ mean ] bi@ ] 2keep ] 2keep [ std ] bi@ ;
 277
 278 : r ( {{x,y}...} -- r )
 279     [r] (r) ;
 280
 281 : r^2 ( {{x,y}...} -- r )
 282     r sq ;
 283
 284 : least-squares ( {{x,y}...} -- alpha beta )
 285     [r] { [ 2dup ] [ ] [ ] [ ] [ ] } spread
 286     ! stack is mean(x) mean(y) mean(x) mean(y) {x} {y} sx sy
 287     [ (r) ] 2keep ! stack is mean(x) mean(y) r sx sy
 288     swap / * ! stack is mean(x) mean(y) beta
 289     [ swapd * - ] keep ;
 290
 291 : cov ( {x} {y} -- cov )
 292     [ dup mean v-n ] bi@ v* mean ;
 293
 294 : sample-corr ( {x} {y} -- corr )
 295      [ cov ] [ [ sample-var ] bi@ * sqrt ] 2bi / ;
 296
 297 : full-corr ( {x} {y} -- corr )
 298      [ cov ] [ [ full-var ] bi@ * sqrt ] 2bi / ;
 299
 300 ALIAS: corr sample-corr
 301
 302 : cum-sum ( seq -- seq' )
 303     0 swap [ + dup ] map nip ;
 304
 305 : cum-product ( seq -- seq' )
 306     1 swap [ * dup ] map nip ;
 307
 308 : cum-min ( seq -- seq' )
 309     [ ?first ] keep [ min dup ] map nip ;
 310
 311 : cum-max ( seq -- seq' )
 312     [ ?first ] keep [ max dup ] map nip ;
 313
 314 : entropy ( seq -- n )
 315     dup members [ [ = ] curry count ] with map
 316     dup sum v/n dup [ log ] map v* sum neg ;
 317
 318 : binary-entropy ( p -- h )
 319     [ dup log * ] [ 1 swap - dup log * ] bi + neg 2 log / ;
 320
 321 : standardize ( u -- v )
 322     [ dup mean v-n ] [ std ] bi v/n ;
 323
 324 : differences ( u -- v )
 325     [ 1 tail-slice ] keep [ - ] 2map ;
 326
 327 : rescale ( u -- v )
 328     dup minmax over - [ v-n ] [ v/n ] bi* ;