basis/math/statistics/statistics.factor

   1 ! Copyright (C) 2008 Doug Coleman, Michael Judge.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: assocs combinators generalizations kernel locals math
   4 math.functions math.order sequences sequences.private sorting ;
   5 IN: math.statistics
   6
   7 : mean ( seq -- x )
   8     [ sum ] [ length ] bi / ;
   9
  10 : geometric-mean ( seq -- x )
  11     [ length ] [ product ] bi nth-root ;
  12
  13 : harmonic-mean ( seq -- x )
  14     [ recip ] map-sum recip ;
  15
  16 :: kth-smallest ( seq k -- elt )
  17     #! Wirth's method, Algorithm's + Data structues = Programs p. 84
  18     #! The algorithm modifiers seq, so we clone it
  19     seq clone :> seq
  20     0 :> i!
  21     0 :> j!
  22     0 :> l!
  23     0 :> x!
  24     seq length 1 - :> m!
  25     [ l m < ]
  26     [
  27         k seq nth x!
  28         l i!
  29         m j!
  30         [ i j <= ]
  31         [
  32             [ i seq nth-unsafe x < ] [ i 1 + i! ] while
  33             [ x j seq nth-unsafe < ] [ j 1 - j! ] while
  34             i j <= [
  35                 i j seq exchange-unsafe
  36                 i 1 + i!
  37                 j 1 - j!
  38             ] when
  39         ] do while
  40
  41         j k < [ i l! ] when
  42         k i < [ j m! ] when
  43     ] while
  44     k seq nth ; inline
  45
  46 : lower-median ( seq -- elt )
  47     [ ] [ ] [ length odd? ] tri
  48     [ midpoint@ ] [ midpoint@ 1 - ] if kth-smallest ;
  49
  50 : upper-median ( seq -- elt )
  51     dup midpoint@ kth-smallest ;
  52
  53 : medians ( seq -- lower upper )
  54     [ lower-median ] [ upper-median ] bi ;
  55
  56 : median ( seq -- x )
  57     [ ] [ length odd? ] bi [ lower-median ] [ medians + 2 / ] if ;
  58
  59 <PRIVATE
  60
  61 : (sequence>assoc) ( seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) assoc -- assoc )
  62     [ swap curry compose each ] keep ; inline
  63
  64 PRIVATE>
  65
  66 : sequence>assoc! ( assoc seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) -- assoc )
  67     4 nrot (sequence>assoc) ; inline
  68
  69 : sequence>assoc ( seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) exemplar -- assoc )
  70     clone (sequence>assoc) ; inline
  71
  72 : sequence>hashtable ( seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) -- hashtable )
  73     H{ } sequence>assoc ; inline
  74
  75 : histogram! ( hashtable seq -- hashtable )
  76     [ ] [ inc-at ] sequence>assoc! ;
  77
  78 : histogram-by ( seq quot: ( x -- bin ) -- hashtable )
  79     [ inc-at ] sequence>hashtable ; inline
  80
  81 : histogram ( seq -- hashtable )
  82     [ ] histogram-by ;
  83
  84 : sorted-histogram ( seq -- alist )
  85     histogram sort-values ;
  86
  87 : collect-pairs ( seq quot: ( x -- v k ) -- hashtable )
  88     [ push-at ] sequence>hashtable ; inline
  89
  90 : collect-by ( seq quot: ( x -- x' ) -- hashtable )
  91     [ dup ] prepose collect-pairs ; inline
  92
  93 : mode ( seq -- x )
  94     histogram >alist
  95     [ ] [ [ [ second ] bi@ > ] most ] map-reduce first ;
  96
  97 ERROR: empty-sequence ;
  98
  99 : minmax ( seq -- min max )
 100     [
 101         empty-sequence
 102     ] [
 103         [ first dup ] keep [ [ min ] [ max ] bi-curry bi* ] each
 104     ] if-empty ;
 105
 106 : range ( seq -- x )
 107     minmax swap - ;
 108
 109 : var ( seq -- x )
 110     #! normalize by N-1
 111     dup length 1 <= [
 112         drop 0
 113     ] [
 114         [ [ mean ] keep [ - sq ] with map-sum ]
 115         [ length 1 - ] bi /
 116     ] if ;
 117
 118 : std ( seq -- x ) var sqrt ;
 119
 120 : ste ( seq -- x ) [ std ] [ length ] bi sqrt / ;
 121
 122 : ((r)) ( mean(x) mean(y) {x} {y} -- (r) )
 123     ! finds sigma((xi-mean(x))(yi-mean(y))
 124     0 [ [ [ pick ] dip swap - ] bi@ * + ] 2reduce 2nip ;
 125
 126 : (r) ( mean(x) mean(y) {x} {y} sx sy -- r )
 127     * recip [ [ ((r)) ] keep length 1 - / ] dip * ;
 128
 129 : [r] ( {{x,y}...} -- mean(x) mean(y) {x} {y} sx sy )
 130     first2 [ [ [ mean ] bi@ ] 2keep ] 2keep [ std ] bi@ ;
 131
 132 : r ( {{x,y}...} -- r )
 133     [r] (r) ;
 134
 135 : r^2 ( {{x,y}...} -- r )
 136     r sq ;
 137
 138 : least-squares ( {{x,y}...} -- alpha beta )
 139     [r] { [ 2dup ] [ ] [ ] [ ] [ ] } spread
 140     ! stack is mean(x) mean(y) mean(x) mean(y) {x} {y} sx sy
 141     [ (r) ] 2keep ! stack is mean(x) mean(y) r sx sy
 142     swap / * ! stack is mean(x) mean(y) beta
 143     [ swapd * - ] keep ;