basis/math/statistics/statistics.factor

   1 ! Copyright (C) 2008 Doug Coleman, Michael Judge.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: assocs combinators generalizations kernel locals math
   4 math.functions math.order math.vectors sequences
   5 sequences.private sorting fry arrays grouping sets
   6 splitting.monotonic ;
   7 IN: math.statistics
   8
   9 : power-mean ( seq p -- x )
  10     [ '[ _ ^ ] map-sum ] [ [ length / ] [ recip ^ ] bi* ] 2bi ; inline
  11
  12 ! Delta in degrees-of-freedom
  13 : mean-ddof ( seq ddof -- x )
  14     [ [ sum ] [ length ] bi ] dip -
  15     dup zero? [ 2drop 0 ] [ / ] if ; inline
  16
  17 : mean ( seq -- x )
  18     0 mean-ddof ; inline
  19
  20 : unbiased-mean ( seq -- x )
  21     1 mean-ddof ; inline
  22
  23 : sum-of-squares ( seq -- x )
  24     [ sq ] map-sum ; inline
  25
  26 : sum-of-squared-errors ( seq -- x )
  27     [ mean ] keep [ - sq ] with map-sum ; inline
  28
  29 : sum-of-absolute-errors ( seq -- x )
  30     [ mean ] keep [ - ] with map-sum ; inline
  31
  32 : quadratic-mean ( seq -- x ) ! root-mean-square
  33     [ sum-of-squares ] [ length ] bi / sqrt ; inline
  34
  35 : geometric-mean ( seq -- x )
  36     [ length ] [ product ] bi nth-root ; inline
  37
  38 : harmonic-mean ( seq -- x )
  39     [ recip ] map-sum recip ; inline
  40
  41 : contraharmonic-mean ( seq -- x )
  42     [ sum-of-squares ] [ sum ] bi / ; inline
  43
  44 <PRIVATE
  45
  46 : trim-points ( p seq -- from to seq  )
  47     [ length [ * >integer ] keep over - ] keep ;
  48
  49 PRIVATE>
  50
  51 : trimmed-mean ( seq p -- x )
  52     swap natural-sort trim-points <slice> mean ;
  53
  54 : winsorized-mean ( seq p -- x )
  55     swap natural-sort trim-points
  56     [ <slice> ]
  57     [ nip dupd nth <array> ]
  58     [ [ 1 - ] dip nth <array> ] 3tri
  59     surround mean ;
  60
  61 <PRIVATE
  62
  63 :: ((kth-object)) ( seq k nth-quot exchange-quot quot: ( x y -- ? ) -- elt )
  64     #! Wirth's method, Algorithm's + Data structues = Programs p. 84
  65     k seq bounds-check 2drop
  66     0 :> i!
  67     0 :> j!
  68     0 :> l!
  69     0 :> x!
  70     seq length 1 - :> m!
  71     [ l m < ]
  72     [
  73         k seq nth x!
  74         l i!
  75         m j!
  76         [ i j <= ]
  77         [
  78             [ i seq nth-quot call x quot call ] [ i 1 + i! ] while
  79             [ x j seq nth-quot call quot call ] [ j 1 - j! ] while
  80             i j <= [
  81                 i j seq exchange-quot call
  82                 i 1 + i!
  83                 j 1 - j!
  84             ] when
  85         ] do while
  86
  87         j k < [ i l! ] when
  88         k i < [ j m! ] when
  89     ] while
  90     k seq nth ; inline
  91
  92 : (kth-object) ( seq k nth-quot exchange-quot quot: ( x y -- ? ) -- elt )
  93     #! The algorithm modifiers seq, so we clone it
  94     [ clone ] 4dip ((kth-object)) ; inline
  95
  96 : kth-object-unsafe ( seq k quot: ( x y -- ? ) -- elt )
  97     [ [ nth-unsafe ] [ exchange-unsafe ] ] dip (kth-object) ; inline
  98
  99 : kth-objects-unsafe ( seq kths quot: ( x y -- ? ) -- elts )
 100     [ clone ] 2dip
 101     '[ [ nth-unsafe ] [ exchange-unsafe ]  _ ((kth-object)) ] with map ; inline
 102
 103 PRIVATE>
 104
 105 : kth-object ( seq k quot: ( x y -- ? ) -- elt )
 106     [ [ nth ] [ exchange ] ] dip (kth-object) ; inline
 107
 108 : kth-objects ( seq kths quot: ( x y -- ? ) -- elts )
 109     [ clone ] 2dip
 110     '[ [ nth ] [ exchange ]  _ ((kth-object)) ] with map ; inline
 111
 112 : kth-smallests ( seq kths -- elts ) [ < ] kth-objects-unsafe ;
 113
 114 : kth-smallest ( seq k -- elt ) [ < ] kth-object-unsafe ;
 115
 116 : kth-largests ( seq kths -- elts ) [ > ] kth-objects-unsafe ;
 117
 118 : kth-largest ( seq k -- elt ) [ > ] kth-object-unsafe ;
 119
 120 : count-relative ( seq k -- lt eq gt )
 121     [ 0 0 0 ] 2dip '[
 122         _ <=> {
 123             { +lt+ [ [ 1 + ] 2dip ] }
 124             { +gt+ [ 1 + ] }
 125             { +eq+ [ [ 1 + ] dip ] }
 126         } case
 127     ] each ;
 128
 129 : minmax-relative ( seq k -- lt eq gt lt-max gt-min )
 130     [ 0 0 0 -1/0. 1/0. ] 2dip '[
 131         dup _ <=> {
 132             { +lt+ [ [ 1 + ] 5 ndip '[ _ max ] dip ] }
 133             { +gt+ [ [ 1 + ] 3dip min ] }
 134             { +eq+ [ [ 1 + ] 4dip drop ] }
 135         } case
 136     ] each ;
 137
 138 : lower-median-index ( seq -- n )
 139     [ midpoint@ ]
 140     [ length odd? [ 1 - ] unless ] bi ;
 141
 142 : lower-median ( seq -- elt )
 143     [ ] [ lower-median-index ] bi kth-smallest ;
 144
 145 : upper-median ( seq -- elt )
 146     dup midpoint@ kth-smallest ;
 147
 148 : medians ( seq -- lower upper )
 149     [ ]
 150     [ [ lower-median-index ] [ midpoint@ ] bi 2array ]
 151     bi kth-smallests first2 ;
 152
 153 : median ( seq -- x )
 154     dup length odd? [ lower-median ] [ medians + 2 / ] if ;
 155
 156 ! quantile can be any n-tile. quartile is n = 4, percentile is n = 100
 157 ! a,b,c,d parameters, N - number of samples, q is quantile (1/2 for median, 1/4 for 1st quartile)
 158 ! http://mathworld.wolfram.com/Quantile.html
 159 ! a + (N + b) q - 1
 160 ! could subtract 1 from a
 161
 162 : quantile-x ( a b N q -- x )
 163     [ + ] dip * + 1 - ; inline
 164
 165 ! 2+1/4 frac is 1/4
 166 : frac ( x -- x' )
 167     >fraction [ /mod nip ] keep / ; inline
 168
 169 :: quantile-indices ( seq qs a b c d -- seq )
 170     qs [ [ a b seq length ] dip quantile-x ] map ;
 171
 172 :: qabcd ( y-floor y-ceiling x c d -- qabcd )
 173     y-floor y-ceiling y-floor - c d x frac * + * + ;
 174
 175 :: quantile-abcd ( seq qs a b c d -- quantile )
 176     seq qs a b c d quantile-indices :> indices
 177     indices [ [ floor ] [ ceiling ] bi 2array ] map
 178     concat :> index-pairs
 179
 180     seq index-pairs kth-smallests
 181     2 group indices [ [ first2 ] dip c d qabcd ] 2map ;
 182
 183 : quantile1 ( seq qs -- seq' )
 184     0 0 1 0 quantile-abcd ;
 185
 186 : quantile3 ( seq qs -- seq' )
 187     1/2 0 0 0 quantile-abcd ;
 188
 189 : quantile4 ( seq qs -- seq' )
 190     0 0 0 1 quantile-abcd ;
 191
 192 : quantile5 ( seq qs -- seq' )
 193     1/2 0 0 1 quantile-abcd ;
 194
 195 : quantile6 ( seq qs -- seq' )
 196     0 1 0 1 quantile-abcd ;
 197
 198 : quantile7 ( seq qs -- seq' )
 199     1 -1 0 1 quantile-abcd ;
 200
 201 : quantile8 ( seq qs -- seq' )
 202     1/3 1/3 0 1 quantile-abcd ;
 203
 204 : quantile9 ( seq qs -- seq' )
 205     3/8 1/4 0 1 quantile-abcd ;
 206
 207 : quartile ( seq -- seq' )
 208     { 1/4 1/2 3/4 } quantile5 ;
 209
 210 <PRIVATE
 211
 212 : (sequence>assoc) ( seq map-quot insert-quot assoc -- assoc )
 213     [ swap curry compose each ] keep ; inline
 214
 215 : (sequence-index>assoc) ( seq map-quot insert-quot assoc -- assoc )
 216     [ swap curry compose each-index ] keep ; inline
 217
 218 PRIVATE>
 219
 220 : sequence>assoc! ( assoc seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) -- assoc )
 221     4 nrot (sequence>assoc) ; inline
 222
 223 : sequence>assoc ( seq map-quot insert-quot exemplar -- assoc )
 224     clone (sequence>assoc) ; inline
 225
 226 : sequence-index>assoc ( seq map-quot insert-quot exemplar -- assoc )
 227     clone (sequence-index>assoc) ; inline
 228
 229 : sequence-index>hashtable ( seq map-quot insert-quot -- hashtable )
 230     H{ } sequence-index>assoc ; inline
 231
 232 : sequence>hashtable ( seq map-quot insert-quot -- hashtable )
 233     H{ } sequence>assoc ; inline
 234
 235 : histogram! ( hashtable seq -- hashtable )
 236     [ ] [ inc-at ] sequence>assoc! ;
 237
 238 : histogram-by ( seq quot: ( x -- bin ) -- hashtable )
 239     [ inc-at ] sequence>hashtable ; inline
 240
 241 : histogram ( seq -- hashtable )
 242     [ ] histogram-by ;
 243
 244 : sorted-histogram ( seq -- alist )
 245     histogram sort-values ;
 246
 247 : normalized-histogram ( seq -- alist )
 248     [ histogram ] [ length ] bi '[ _ / ] assoc-map ;
 249
 250 : collect-index-by ( seq quot -- hashtable )
 251     [ swap ] prepose [ push-at ] sequence-index>hashtable ; inline
 252
 253 : collect-by ( seq quot -- hashtable )
 254     [ dup ] prepose [ push-at ] sequence>hashtable ; inline
 255
 256 : equal-probabilities ( n -- array )
 257     dup recip <array> ; inline
 258
 259 : mode ( seq -- x )
 260     histogram >alist
 261     [ ] [ [ [ second ] bi@ > ] most ] map-reduce first ;
 262
 263 : minmax ( seq -- min max )
 264     [ first dup ] keep [ [ min ] [ max ] bi-curry bi* ] each ;
 265
 266 : range ( seq -- x )
 267     minmax swap - ;
 268
 269 : var-ddof ( seq n -- x )
 270     2dup [ length ] dip - 0 <= [
 271         2drop 0
 272     ] [
 273         [ [ sum-of-squared-errors ] [ length ] bi ] dip - /
 274     ] if ; inline
 275
 276 : population-var ( seq -- x ) 0 var-ddof ; inline
 277
 278 : sample-var ( seq -- x ) 1 var-ddof ; inline
 279
 280 : std-ddof ( seq n -- x )
 281     var-ddof sqrt ; inline
 282
 283 : population-std ( seq -- x ) 0 std-ddof ; inline
 284
 285 : sample-std ( seq -- x ) 1 std-ddof ; inline
 286
 287 ALIAS: std sample-std
 288
 289 : signal-to-noise ( seq -- x ) [ mean ] [ population-std ] bi / ;
 290
 291 : mean-dev ( seq -- x ) dup mean v-n vabs mean ;
 292
 293 : median-dev ( seq -- x ) dup median v-n vabs mean ;
 294
 295 : ste-ddof ( seq n -- x ) '[ _ std-ddof ] [ length ] bi sqrt / ;
 296
 297 : population-ste ( seq -- x ) 0 ste-ddof ;
 298
 299 : sample-ste ( seq -- x ) 1 ste-ddof ;
 300
 301 : ((r)) ( mean(x) mean(y) {x} {y} -- (r) )
 302     ! finds sigma((xi-mean(x))(yi-mean(y))
 303     0 [ [ [ pick ] dip swap - ] bi@ * + ] 2reduce 2nip ;
 304
 305 : (r) ( mean(x) mean(y) {x} {y} sx sy -- r )
 306     * recip [ [ ((r)) ] keep length 1 - / ] dip * ;
 307
 308 : [r] ( {{x,y}...} -- mean(x) mean(y) {x} {y} sx sy )
 309     first2 [ [ [ mean ] bi@ ] 2keep ] 2keep [ population-std ] bi@ ;
 310
 311 : r ( {{x,y}...} -- r )
 312     [r] (r) ;
 313
 314 : r^2 ( {{x,y}...} -- r )
 315     r sq ;
 316
 317 : least-squares ( {{x,y}...} -- alpha beta )
 318     [r] { [ 2dup ] [ ] [ ] [ ] [ ] } spread
 319     ! stack is mean(x) mean(y) mean(x) mean(y) {x} {y} sx sy
 320     [ (r) ] 2keep ! stack is mean(x) mean(y) r sx sy
 321     swap / * ! stack is mean(x) mean(y) beta
 322     [ swapd * - ] keep ;
 323
 324 : cov-ddof ( {x} {y} ddof -- cov )
 325     [ [ dup mean v-n ] bi@ v* ] dip mean-ddof ;
 326
 327 : population-cov ( {x} {y} -- cov ) 0 cov-ddof ; inline
 328
 329 : sample-cov ( {x} {y} -- cov ) 1 cov-ddof ; inline
 330
 331 : corr-ddof ( {x} {y} n -- corr )
 332     [ [ population-cov ] ] dip
 333     '[ [ _ var-ddof ] bi@ * sqrt ] 2bi / ;
 334
 335 : population-corr ( {x} {y} -- corr ) 0 corr-ddof ; inline
 336
 337 : sample-corr ( {x} {y} -- corr ) 1 corr-ddof ; inline
 338
 339 : cum-map ( seq identity quot -- seq' )
 340     swapd [ dup ] compose map nip ; inline
 341
 342 : cum-sum ( seq -- seq' )
 343     0 [ + ] cum-map ;
 344
 345 : cum-sum0 ( seq -- seq' )
 346     0 [ + ] accumulate nip ;
 347
 348 : cum-product ( seq -- seq' )
 349     1 [ * ] cum-map ;
 350
 351 : cum-count ( seq quot -- seq' )
 352     [ 0 ] dip
 353     '[ _ call [ 1 + ] when ] cum-map ; inline
 354
 355 : cum-min ( seq -- seq' )
 356     dup ?first [ min ] cum-map ;
 357
 358 : cum-max ( seq -- seq' )
 359     dup ?first [ max ] cum-map ;
 360
 361 : entropy ( probabilities -- n )
 362     dup sum '[ _ / dup log * ] map-sum neg ;
 363
 364 : maximum-entropy ( probabilities -- n )
 365     length log ;
 366
 367 : normalized-entropy ( probabilities -- n )
 368     [ entropy ] [ maximum-entropy ] bi / ;
 369
 370 : binary-entropy ( p -- h )
 371     [ dup log * ] [ 1 swap - dup log * ] bi + neg 2 log / ;
 372
 373 : standardize ( u -- v )
 374     [ dup mean v-n ] [ sample-std ] bi
 375     dup zero? [ drop ] [ v/n ] if ;
 376
 377 : standardize-2d ( u -- v )
 378     flip dup [ [ mean ] [ sample-std ] bi 2array ] map
 379     [ [ first v-n ] 2map ] keep [ second v/n ] 2map flip ;
 380
 381 : differences ( u -- v )
 382     [ 1 tail-slice ] keep [ - ] 2map ;
 383
 384 : rescale ( u -- v )
 385     dup minmax over - [ v-n ] [ v/n ] bi* ;
 386
 387 : rank-values ( seq -- seq' )
 388     [
 389         [ ] [ length iota ] bi zip sort-keys
 390         [ [ first ] bi@ = ] monotonic-split
 391         [ values ] map [ 0 [ length + ] accumulate nip ] [ ] bi zip
 392     ] [ length f <array> ] bi
 393     [ '[ first2 [ _ set-nth ] with each ] each ] keep ;
 394
 395 : z-score ( seq -- n )
 396     dup [ mean ] [ sample-std ] bi '[ _ - _ / ] map ;