basis/math/statistics/statistics.factor

   1 ! Copyright (C) 2008 Doug Coleman, Michael Judge.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: arrays combinators kernel math math.functions
   4 math.order sequences sorting locals sequences.private
   5 assocs fry ;
   6 IN: math.statistics
   7
   8 : mean ( seq -- x )
   9     [ sum ] [ length ] bi / ;
  10
  11 : geometric-mean ( seq -- x )
  12     [ length ] [ product ] bi nth-root ;
  13
  14 : harmonic-mean ( seq -- x )
  15     [ recip ] map-sum recip ;
  16
  17 :: kth-smallest ( seq k -- elt )
  18     #! Wirth's method, Algorithm's + Data structues = Programs p. 84
  19     #! The algorithm modifiers seq, so we clone it
  20     seq clone :> seq
  21     0 :> i!
  22     0 :> j!
  23     0 :> l!
  24     0 :> x!
  25     seq length 1 - :> m!
  26     [ l m < ]
  27     [
  28         k seq nth x!
  29         l i!
  30         m j!
  31         [ i j <= ]
  32         [
  33             [ i seq nth-unsafe x < ] [ i 1 + i! ] while
  34             [ x j seq nth-unsafe < ] [ j 1 - j! ] while
  35             i j <= [
  36                 i j seq exchange-unsafe
  37                 i 1 + i!
  38                 j 1 - j!
  39             ] when
  40         ] do while
  41
  42         j k < [ i l! ] when
  43         k i < [ j m! ] when
  44     ] while
  45     k seq nth ; inline
  46
  47 : lower-median ( seq -- elt )
  48     [ ] [ ] [ length odd? ] tri
  49     [ midpoint@ ] [ midpoint@ 1 - ] if kth-smallest ;
  50
  51 : upper-median ( seq -- elt )
  52     dup midpoint@ kth-smallest ;
  53
  54 : medians ( seq -- lower upper )
  55     [ lower-median ] [ upper-median ] bi ;
  56
  57 : median ( seq -- x )
  58     [ ] [ length odd? ] bi [ lower-median ] [ medians + 2 / ] if ;
  59
  60 <PRIVATE
  61
  62 : (sequence>assoc) ( seq quot assoc -- assoc )
  63     [ swap curry each ] keep ; inline
  64
  65 PRIVATE>
  66
  67 : sequence>assoc! ( assoc seq quot: ( obj assoc -- ) -- assoc )
  68     rot (sequence>assoc) ; inline
  69
  70 : sequence>assoc ( seq quot: ( obj assoc -- ) exemplar -- assoc )
  71     clone (sequence>assoc) ; inline
  72
  73 : sequence>hashtable ( seq quot: ( obj hashtable -- ) -- hashtable )
  74     H{ } sequence>assoc ; inline
  75
  76 : histogram! ( hashtable seq -- hashtable )
  77     [ inc-at ] sequence>assoc! ;
  78
  79 : histogram ( seq -- hashtable )
  80     [ inc-at ] sequence>hashtable ;
  81
  82 : sorted-histogram ( seq -- alist )
  83     histogram >alist sort-values ;
  84
  85 : collect-values ( seq quot: ( obj hashtable -- ) -- hash )
  86     '[ [ dup @ ] dip push-at ] sequence>hashtable ; inline
  87
  88 : mode ( seq -- x )
  89     histogram >alist
  90     [ ] [ [ [ second ] bi@ > ] 2keep ? ] map-reduce first ;
  91
  92 ERROR: empty-sequence ;
  93
  94 : minmax ( seq -- min max )
  95     [
  96         empty-sequence
  97     ] [
  98         [ first dup ] keep [ [ min ] [ max ] bi-curry bi* ] each
  99     ] if-empty ;
 100
 101 : range ( seq -- x )
 102     minmax swap - ;
 103
 104 : var ( seq -- x )
 105     #! normalize by N-1
 106     dup length 1 <= [
 107         drop 0
 108     ] [
 109         [ [ mean ] keep [ - sq ] with map-sum ]
 110         [ length 1 - ] bi /
 111     ] if ;
 112
 113 : std ( seq -- x ) var sqrt ;
 114
 115 : ste ( seq -- x ) [ std ] [ length ] bi sqrt / ;
 116
 117 : ((r)) ( mean(x) mean(y) {x} {y} -- (r) )
 118     ! finds sigma((xi-mean(x))(yi-mean(y))
 119     0 [ [ [ pick ] dip swap - ] bi@ * + ] 2reduce 2nip ;
 120
 121 : (r) ( mean(x) mean(y) {x} {y} sx sy -- r )
 122     * recip [ [ ((r)) ] keep length 1 - / ] dip * ;
 123
 124 : [r] ( {{x,y}...} -- mean(x) mean(y) {x} {y} sx sy )
 125     first2 [ [ [ mean ] bi@ ] 2keep ] 2keep [ std ] bi@ ;
 126
 127 : r ( {{x,y}...} -- r )
 128     [r] (r) ;
 129
 130 : r^2 ( {{x,y}...} -- r )
 131     r sq ;
 132
 133 : least-squares ( {{x,y}...} -- alpha beta )
 134     [r] { [ 2dup ] [ ] [ ] [ ] [ ] } spread
 135     ! stack is mean(x) mean(y) mean(x) mean(y) {x} {y} sx sy
 136     [ (r) ] 2keep ! stack is mean(x) mean(y) r sx sy
 137     swap / * ! stack is mean(x) mean(y) beta
 138     [ swapd * - ] keep ;