basis/math/statistics/statistics.factor

   1 ! Copyright (C) 2008 Doug Coleman, Michael Judge.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: assocs combinators generalizations kernel locals math
   4 math.functions math.order math.vectors sequences
   5 sequences.private sorting fry ;
   6 IN: math.statistics
   7
   8 : mean ( seq -- x )
   9     [ sum ] [ length ] bi / ;
  10
  11 : geometric-mean ( seq -- x )
  12     [ length ] [ product ] bi nth-root ;
  13
  14 : harmonic-mean ( seq -- x )
  15     [ recip ] map-sum recip ;
  16
  17 :: kth-object ( seq k quot: ( x y -- ? ) -- elt )
  18     #! Wirth's method, Algorithm's + Data structues = Programs p. 84
  19     #! The algorithm modifiers seq, so we clone it
  20     seq clone :> seq
  21     0 :> i!
  22     0 :> j!
  23     0 :> l!
  24     0 :> x!
  25     seq length 1 - :> m!
  26     [ l m < ]
  27     [
  28         k seq nth x!
  29         l i!
  30         m j!
  31         [ i j <= ]
  32         [
  33             [ i seq nth-unsafe x quot call ] [ i 1 + i! ] while
  34             [ x j seq nth-unsafe quot call ] [ j 1 - j! ] while
  35             i j <= [
  36                 i j seq exchange-unsafe
  37                 i 1 + i!
  38                 j 1 - j!
  39             ] when
  40         ] do while
  41
  42         j k < [ i l! ] when
  43         k i < [ j m! ] when
  44     ] while
  45     k seq nth ; inline
  46
  47 : kth-smallest ( seq k -- elt ) [ < ] kth-object ;
  48
  49 : kth-largest ( seq k -- elt ) [ > ] kth-object ;
  50
  51 : count-relative ( seq k -- lt eq gt )
  52     [ 0 0 0 ] 2dip '[
  53         _ <=> {
  54             { +lt+ [ [ 1 + ] 2dip ] }
  55             { +gt+ [ 1 + ] }
  56             { +eq+ [ [ 1 + ] dip ] }
  57         } case
  58     ] each ;
  59
  60 : minmax-relative ( seq k -- lt eq gt lt-max gt-min )
  61     [ 0 0 0 -1/0. 1/0. ] 2dip '[
  62         dup _ <=> {
  63             { +lt+ [ [ 1 + ] 5 ndip '[ _ max ] dip ] }
  64             { +gt+ [ [ 1 + ] 3dip min ] }
  65             { +eq+ [ [ 1 + ] 4dip drop ] }
  66         } case
  67     ] each ;
  68
  69 : lower-median ( seq -- elt )
  70     [ ] [ ] [ length odd? ] tri
  71     [ midpoint@ ] [ midpoint@ 1 - ] if kth-smallest ;
  72
  73 : upper-median ( seq -- elt )
  74     dup midpoint@ kth-smallest ;
  75
  76 : medians ( seq -- lower upper )
  77     [ lower-median ] [ upper-median ] bi ;
  78
  79 : median ( seq -- x )
  80     [ ] [ length odd? ] bi [ lower-median ] [ medians + 2 / ] if ;
  81
  82 <PRIVATE
  83
  84 : (sequence>assoc) ( seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) assoc -- assoc )
  85     [ swap curry compose each ] keep ; inline
  86
  87 PRIVATE>
  88
  89 : sequence>assoc! ( assoc seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) -- assoc )
  90     4 nrot (sequence>assoc) ; inline
  91
  92 : sequence>assoc ( seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) exemplar -- assoc )
  93     clone (sequence>assoc) ; inline
  94
  95 : sequence>hashtable ( seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) -- hashtable )
  96     H{ } sequence>assoc ; inline
  97
  98 : histogram! ( hashtable seq -- hashtable )
  99     [ ] [ inc-at ] sequence>assoc! ;
 100
 101 : histogram-by ( seq quot: ( x -- bin ) -- hashtable )
 102     [ inc-at ] sequence>hashtable ; inline
 103
 104 : histogram ( seq -- hashtable )
 105     [ ] histogram-by ;
 106
 107 : sorted-histogram ( seq -- alist )
 108     histogram sort-values ;
 109
 110 : collect-pairs ( seq quot: ( x -- v k ) -- hashtable )
 111     [ push-at ] sequence>hashtable ; inline
 112
 113 : collect-by ( seq quot: ( x -- x' ) -- hashtable )
 114     [ dup ] prepose collect-pairs ; inline
 115
 116 : mode ( seq -- x )
 117     histogram >alist
 118     [ ] [ [ [ second ] bi@ > ] most ] map-reduce first ;
 119
 120 ERROR: empty-sequence ;
 121
 122 : minmax ( seq -- min max )
 123     [
 124         empty-sequence
 125     ] [
 126         [ first dup ] keep [ [ min ] [ max ] bi-curry bi* ] each
 127     ] if-empty ;
 128
 129 : range ( seq -- x )
 130     minmax swap - ;
 131
 132 : sample-var ( seq -- x )
 133     #! normalize by N-1
 134     dup length 1 <= [
 135         drop 0
 136     ] [
 137         [ [ mean ] keep [ - sq ] with map-sum ]
 138         [ length 1 - ] bi /
 139     ] if ;
 140
 141 : var ( seq -- x )
 142     dup length 1 <= [
 143         drop 0
 144     ] [
 145         [ [ mean ] keep [ - sq ] with map-sum ]
 146         [ length ] bi /
 147     ] if ;
 148
 149 : std ( seq -- x ) var sqrt ;
 150
 151 : ste ( seq -- x ) [ std ] [ length ] bi sqrt / ;
 152
 153 : ((r)) ( mean(x) mean(y) {x} {y} -- (r) )
 154     ! finds sigma((xi-mean(x))(yi-mean(y))
 155     0 [ [ [ pick ] dip swap - ] bi@ * + ] 2reduce 2nip ;
 156
 157 : (r) ( mean(x) mean(y) {x} {y} sx sy -- r )
 158     * recip [ [ ((r)) ] keep length 1 - / ] dip * ;
 159
 160 : [r] ( {{x,y}...} -- mean(x) mean(y) {x} {y} sx sy )
 161     first2 [ [ [ mean ] bi@ ] 2keep ] 2keep [ std ] bi@ ;
 162
 163 : r ( {{x,y}...} -- r )
 164     [r] (r) ;
 165
 166 : r^2 ( {{x,y}...} -- r )
 167     r sq ;
 168
 169 : least-squares ( {{x,y}...} -- alpha beta )
 170     [r] { [ 2dup ] [ ] [ ] [ ] [ ] } spread
 171     ! stack is mean(x) mean(y) mean(x) mean(y) {x} {y} sx sy
 172     [ (r) ] 2keep ! stack is mean(x) mean(y) r sx sy
 173     swap / * ! stack is mean(x) mean(y) beta
 174     [ swapd * - ] keep ;
 175
 176 : cov ( {x} {y} -- cov )
 177     [ dup mean v-n ] bi@ v* mean ;
 178
 179 : corr ( {x} {y} -- corr )
 180      [ cov ] [ [ var ] bi@ * sqrt ] 2bi / ;
 181
 182 : cum-sum ( seq -- seq' )
 183     0 swap [ + dup ] map nip ;
 184
 185 : cum-product ( seq -- seq' )
 186     1 swap [ * dup ] map nip ;
 187
 188 : cum-min ( seq -- seq' )
 189     [ ?first ] keep [ min dup ] map nip ;
 190
 191 : cum-max ( seq -- seq' )
 192     [ ?first ] keep [ max dup ] map nip ;