basis/math/statistics/statistics.factor

   1 ! Copyright (C) 2008 Doug Coleman, Michael Judge.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: assocs combinators generalizations kernel locals math
   4 math.functions math.order math.vectors sequences
   5 sequences.private sorting fry arrays grouping sets ;
   6 IN: math.statistics
   7
   8 : power-mean ( seq p -- x )
   9     [ '[ _ ^ ] map-sum ] [ [ length / ] [ recip ^ ] bi* ] 2bi ;
  10
  11 : mean ( seq -- x )
  12     [ sum ] [ length ] bi / ;
  13
  14 : quadratic-mean ( seq -- x ) ! root-mean-square
  15     [ [ sq ] map-sum ] [ length ] bi / sqrt ;
  16
  17 : geometric-mean ( seq -- x )
  18     [ length ] [ product ] bi nth-root ;
  19
  20 : harmonic-mean ( seq -- x )
  21     [ recip ] map-sum recip ;
  22
  23 : contraharmonic-mean ( seq -- x )
  24     [ [ sq ] map-sum ] [ sum ] bi / ;
  25
  26 <PRIVATE
  27
  28 :: ((kth-object)) ( seq k nth-quot exchange-quot quot: ( x y -- ? ) -- elt )
  29     #! Wirth's method, Algorithm's + Data structues = Programs p. 84
  30     #! The algorithm modifiers seq, so we clone it
  31     k seq bounds-check 2drop
  32     0 :> i!
  33     0 :> j!
  34     0 :> l!
  35     0 :> x!
  36     seq length 1 - :> m!
  37     [ l m < ]
  38     [
  39         k seq nth x!
  40         l i!
  41         m j!
  42         [ i j <= ]
  43         [
  44             [ i seq nth-quot call x quot call ] [ i 1 + i! ] while
  45             [ x j seq nth-quot call quot call ] [ j 1 - j! ] while
  46             i j <= [
  47                 i j seq exchange-quot call
  48                 i 1 + i!
  49                 j 1 - j!
  50             ] when
  51         ] do while
  52
  53         j k < [ i l! ] when
  54         k i < [ j m! ] when
  55     ] while
  56     k seq nth ; inline
  57
  58 : (kth-object) ( seq k nth-quot exchange-quot quot: ( x y -- ? ) -- elt )
  59     [ clone ] 4dip ((kth-object)) ; inline
  60
  61 : kth-object-unsafe ( seq k quot: ( x y -- ? ) -- elt )
  62     [ [ nth-unsafe ] [ exchange-unsafe ] ] dip (kth-object) ; inline
  63
  64 : kth-objects-unsafe ( seq kths quot: ( x y -- ? ) -- elts )
  65     [ clone ] 2dip
  66     '[ [ nth-unsafe ] [ exchange-unsafe ]  _ ((kth-object)) ] with map ; inline
  67
  68 PRIVATE>
  69
  70 : kth-object ( seq k quot: ( x y -- ? ) -- elt )
  71     [ [ nth ] [ exchange ] ] dip (kth-object) ; inline
  72
  73 : kth-objects ( seq kths quot: ( x y -- ? ) -- elts )
  74     [ clone ] 2dip
  75     '[ [ nth ] [ exchange ]  _ ((kth-object)) ] with map ; inline
  76
  77 : kth-smallests ( seq kths -- elts ) [ < ] kth-objects-unsafe ;
  78
  79 : kth-smallest ( seq k -- elt ) [ < ] kth-object-unsafe ;
  80
  81 : kth-largests ( seq kths -- elts ) [ > ] kth-objects-unsafe ;
  82
  83 : kth-largest ( seq k -- elt ) [ > ] kth-object-unsafe ;
  84
  85 : count-relative ( seq k -- lt eq gt )
  86     [ 0 0 0 ] 2dip '[
  87         _ <=> {
  88             { +lt+ [ [ 1 + ] 2dip ] }
  89             { +gt+ [ 1 + ] }
  90             { +eq+ [ [ 1 + ] dip ] }
  91         } case
  92     ] each ;
  93
  94 : minmax-relative ( seq k -- lt eq gt lt-max gt-min )
  95     [ 0 0 0 -1/0. 1/0. ] 2dip '[
  96         dup _ <=> {
  97             { +lt+ [ [ 1 + ] 5 ndip '[ _ max ] dip ] }
  98             { +gt+ [ [ 1 + ] 3dip min ] }
  99             { +eq+ [ [ 1 + ] 4dip drop ] }
 100         } case
 101     ] each ;
 102
 103 : lower-median-index ( seq -- n )
 104     [ midpoint@ ]
 105     [ length odd? [ 1 - ] unless ] bi ;
 106
 107 : lower-median ( seq -- elt )
 108     [ ] [ lower-median-index ] bi kth-smallest ;
 109
 110 : upper-median ( seq -- elt )
 111     dup midpoint@ kth-smallest ;
 112
 113 : medians ( seq -- lower upper )
 114     [ ]
 115     [ [ lower-median-index ] [ midpoint@ ] bi 2array ]
 116     bi kth-smallests first2 ;
 117
 118 : median ( seq -- x )
 119     dup length odd?
 120     [ lower-median ] [ medians + 2 / ] if ;
 121
 122 ! quantile can be any n-tile. quartile is n = 4, percentile is n = 100
 123 ! a,b,c,d parameters, N - number of samples, q is quantile (1/2 for median, 1/4 for 1st quartile)
 124 ! http://mathworld.wolfram.com/Quantile.html
 125 ! a + (N + b) q - 1
 126 ! could subtract 1 from a
 127
 128 : quantile-x ( a b N q -- x )
 129     [ + ] dip * + 1 - ; inline
 130
 131 ! 2+1/4 frac is 1/4
 132 : frac ( x -- x' )
 133     >fraction [ /mod nip ] keep / ; inline
 134
 135 :: quantile-indices ( seq qs a b c d -- seq )
 136     qs [ [ a b seq length ] dip quantile-x ] map ;
 137
 138 :: qabcd ( y-floor y-ceiling x c d -- qabcd )
 139     y-floor y-ceiling y-floor - c d x frac * + * + ;
 140
 141 :: quantile-abcd ( seq qs a b c d -- quantile )
 142     seq qs a b c d quantile-indices :> indices
 143     indices [ [ floor ] [ ceiling ] bi 2array ] map
 144     concat :> index-pairs
 145
 146     seq index-pairs kth-smallests
 147     2 group indices [ [ first2 ] dip c d qabcd ] 2map ;
 148
 149 : quantile1 ( seq qs -- seq' )
 150     0 0 1 0 quantile-abcd ;
 151
 152 : quantile3 ( seq qs -- seq' )
 153     1/2 0 0 0 quantile-abcd ;
 154
 155 : quantile4 ( seq qs -- seq' )
 156     0 0 0 1 quantile-abcd ;
 157
 158 : quantile5 ( seq qs -- seq' )
 159     1/2 0 0 1 quantile-abcd ;
 160
 161 : quantile6 ( seq qs -- seq' )
 162     0 1 0 1 quantile-abcd ;
 163
 164 : quantile7 ( seq qs -- seq' )
 165     1 -1 0 1 quantile-abcd ;
 166
 167 : quantile8 ( seq qs -- seq' )
 168     1/3 1/3 0 1 quantile-abcd ;
 169
 170 : quantile9 ( seq qs -- seq' )
 171     3/8 1/4 0 1 quantile-abcd ;
 172
 173 : quartile ( seq -- seq' )
 174     { 1/4 1/2 3/4 } quantile5 ;
 175
 176 <PRIVATE
 177
 178 : (sequence>assoc) ( seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) assoc -- assoc )
 179     [ swap curry compose each ] keep ; inline
 180
 181 PRIVATE>
 182
 183 : sequence>assoc! ( assoc seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) -- assoc )
 184     4 nrot (sequence>assoc) ; inline
 185
 186 : sequence>assoc ( seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) exemplar -- assoc )
 187     clone (sequence>assoc) ; inline
 188
 189 : sequence>hashtable ( seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) -- hashtable )
 190     H{ } sequence>assoc ; inline
 191
 192 : histogram! ( hashtable seq -- hashtable )
 193     [ ] [ inc-at ] sequence>assoc! ;
 194
 195 : histogram-by ( seq quot: ( x -- bin ) -- hashtable )
 196     [ inc-at ] sequence>hashtable ; inline
 197
 198 : histogram ( seq -- hashtable )
 199     [ ] histogram-by ;
 200
 201 : sorted-histogram ( seq -- alist )
 202     histogram sort-values ;
 203
 204 : collect-pairs ( seq quot: ( x -- v k ) -- hashtable )
 205     [ push-at ] sequence>hashtable ; inline
 206
 207 : collect-by ( seq quot: ( x -- x' ) -- hashtable )
 208     [ dup ] prepose collect-pairs ; inline
 209
 210 : mode ( seq -- x )
 211     histogram >alist
 212     [ ] [ [ [ second ] bi@ > ] most ] map-reduce first ;
 213
 214 ERROR: empty-sequence ;
 215
 216 : minmax ( seq -- min max )
 217     [
 218         empty-sequence
 219     ] [
 220         [ first dup ] keep [ [ min ] [ max ] bi-curry bi* ] each
 221     ] if-empty ;
 222
 223 : range ( seq -- x )
 224     minmax swap - ;
 225
 226 : sample-var ( seq -- x )
 227     #! normalize by N-1
 228     dup length 1 <= [
 229         drop 0
 230     ] [
 231         [ [ mean ] keep [ - sq ] with map-sum ]
 232         [ length 1 - ] bi /
 233     ] if ;
 234
 235 : full-var ( seq -- x )
 236     dup length 1 <= [
 237         drop 0
 238     ] [
 239         [ [ mean ] keep [ - sq ] with map-sum ]
 240         [ length ] bi /
 241     ] if ;
 242
 243 ALIAS: var sample-var
 244
 245 : sample-std ( seq -- x ) sample-var sqrt ;
 246
 247 : full-std ( seq -- x ) full-var sqrt ;
 248
 249 ALIAS: std sample-std
 250
 251 : mean-dev ( seq -- x ) dup mean v-n vabs mean ;
 252
 253 : median-dev ( seq -- x ) dup median v-n vabs mean ;
 254
 255 : sample-ste ( seq -- x ) [ sample-std ] [ length ] bi sqrt / ;
 256
 257 : full-ste ( seq -- x ) [ full-std ] [ length ] bi sqrt / ;
 258
 259 ALIAS: ste sample-ste
 260
 261 : ((r)) ( mean(x) mean(y) {x} {y} -- (r) )
 262     ! finds sigma((xi-mean(x))(yi-mean(y))
 263     0 [ [ [ pick ] dip swap - ] bi@ * + ] 2reduce 2nip ;
 264
 265 : (r) ( mean(x) mean(y) {x} {y} sx sy -- r )
 266     * recip [ [ ((r)) ] keep length 1 - / ] dip * ;
 267
 268 : [r] ( {{x,y}...} -- mean(x) mean(y) {x} {y} sx sy )
 269     first2 [ [ [ mean ] bi@ ] 2keep ] 2keep [ std ] bi@ ;
 270
 271 : r ( {{x,y}...} -- r )
 272     [r] (r) ;
 273
 274 : r^2 ( {{x,y}...} -- r )
 275     r sq ;
 276
 277 : least-squares ( {{x,y}...} -- alpha beta )
 278     [r] { [ 2dup ] [ ] [ ] [ ] [ ] } spread
 279     ! stack is mean(x) mean(y) mean(x) mean(y) {x} {y} sx sy
 280     [ (r) ] 2keep ! stack is mean(x) mean(y) r sx sy
 281     swap / * ! stack is mean(x) mean(y) beta
 282     [ swapd * - ] keep ;
 283
 284 : cov ( {x} {y} -- cov )
 285     [ dup mean v-n ] bi@ v* mean ;
 286
 287 : sample-corr ( {x} {y} -- corr )
 288      [ cov ] [ [ sample-var ] bi@ * sqrt ] 2bi / ;
 289
 290 : full-corr ( {x} {y} -- corr )
 291      [ cov ] [ [ full-var ] bi@ * sqrt ] 2bi / ;
 292
 293 ALIAS: corr sample-corr
 294
 295 : cum-sum ( seq -- seq' )
 296     0 swap [ + dup ] map nip ;
 297
 298 : cum-product ( seq -- seq' )
 299     1 swap [ * dup ] map nip ;
 300
 301 : cum-min ( seq -- seq' )
 302     [ ?first ] keep [ min dup ] map nip ;
 303
 304 : cum-max ( seq -- seq' )
 305     [ ?first ] keep [ max dup ] map nip ;
 306
 307 : entropy ( seq -- n )
 308     dup members [ [ = ] curry count ] with map
 309     dup sum v/n dup [ log ] map v* sum neg ;
 310
 311 : binary-entropy ( p -- h )
 312     [ dup log * ] [ 1 swap - dup log * ] bi + neg 2 log / ;
 313
 314 : standardize ( u -- v )
 315     [ dup mean v-n ] [ std ] bi v/n ;
 316
 317 : differences ( u -- v )
 318     [ 1 tail-slice ] keep [ - ] 2map ;
 319
 320 : rescale ( u -- v )
 321     dup minmax over - [ v-n ] [ v/n ] bi* ;