basis/math/statistics/statistics.factor

   1 ! Copyright (C) 2008 Doug Coleman, Michael Judge.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: assocs combinators generalizations kernel locals math
   4 math.functions math.order math.vectors sequences
   5 sequences.private sorting fry arrays grouping sets ;
   6 IN: math.statistics
   7
   8 : mean ( seq -- x )
   9     [ sum ] [ length ] bi / ;
  10
  11 : geometric-mean ( seq -- x )
  12     [ length ] [ product ] bi nth-root ;
  13
  14 : harmonic-mean ( seq -- x )
  15     [ recip ] map-sum recip ;
  16
  17 <PRIVATE
  18
  19 :: ((kth-object)) ( seq k nth-quot exchange-quot quot: ( x y -- ? ) -- elt )
  20     #! Wirth's method, Algorithm's + Data structues = Programs p. 84
  21     #! The algorithm modifiers seq, so we clone it
  22     k seq bounds-check 2drop
  23     0 :> i!
  24     0 :> j!
  25     0 :> l!
  26     0 :> x!
  27     seq length 1 - :> m!
  28     [ l m < ]
  29     [
  30         k seq nth x!
  31         l i!
  32         m j!
  33         [ i j <= ]
  34         [
  35             [ i seq nth-quot call x quot call ] [ i 1 + i! ] while
  36             [ x j seq nth-quot call quot call ] [ j 1 - j! ] while
  37             i j <= [
  38                 i j seq exchange-quot call
  39                 i 1 + i!
  40                 j 1 - j!
  41             ] when
  42         ] do while
  43
  44         j k < [ i l! ] when
  45         k i < [ j m! ] when
  46     ] while
  47     k seq nth ; inline
  48
  49 : (kth-object) ( seq k nth-quot exchange-quot quot: ( x y -- ? ) -- elt )
  50     [ clone ] 4dip ((kth-object)) ; inline
  51
  52 : kth-object-unsafe ( seq k quot: ( x y -- ? ) -- elt )
  53     [ [ nth-unsafe ] [ exchange-unsafe ] ] dip (kth-object) ; inline
  54
  55 : kth-objects-unsafe ( seq kths quot: ( x y -- ? ) -- elts )
  56     [ clone ] 2dip
  57     '[ [ nth-unsafe ] [ exchange-unsafe ]  _ ((kth-object)) ] with map ; inline
  58
  59 PRIVATE>
  60
  61 : kth-object ( seq k quot: ( x y -- ? ) -- elt )
  62     [ [ nth ] [ exchange ] ] dip (kth-object) ; inline
  63
  64 : kth-objects ( seq kths quot: ( x y -- ? ) -- elts )
  65     [ clone ] 2dip
  66     '[ [ nth ] [ exchange ]  _ ((kth-object)) ] with map ; inline
  67
  68 : kth-smallests ( seq kths -- elts ) [ < ] kth-objects-unsafe ;
  69
  70 : kth-smallest ( seq k -- elt ) [ < ] kth-object-unsafe ;
  71
  72 : kth-largests ( seq kths -- elts ) [ > ] kth-objects-unsafe ;
  73
  74 : kth-largest ( seq k -- elt ) [ > ] kth-object-unsafe ;
  75
  76 : count-relative ( seq k -- lt eq gt )
  77     [ 0 0 0 ] 2dip '[
  78         _ <=> {
  79             { +lt+ [ [ 1 + ] 2dip ] }
  80             { +gt+ [ 1 + ] }
  81             { +eq+ [ [ 1 + ] dip ] }
  82         } case
  83     ] each ;
  84
  85 : minmax-relative ( seq k -- lt eq gt lt-max gt-min )
  86     [ 0 0 0 -1/0. 1/0. ] 2dip '[
  87         dup _ <=> {
  88             { +lt+ [ [ 1 + ] 5 ndip '[ _ max ] dip ] }
  89             { +gt+ [ [ 1 + ] 3dip min ] }
  90             { +eq+ [ [ 1 + ] 4dip drop ] }
  91         } case
  92     ] each ;
  93
  94 : lower-median-index ( seq -- n )
  95     [ midpoint@ ]
  96     [ length odd? [ 1 - ] unless ] bi ;
  97
  98 : lower-median ( seq -- elt )
  99     [ ] [ lower-median-index ] bi kth-smallest ;
 100
 101 : upper-median ( seq -- elt )
 102     dup midpoint@ kth-smallest ;
 103
 104 : medians ( seq -- lower upper )
 105     [ ]
 106     [ [ lower-median-index ] [ midpoint@ ] bi 2array ]
 107     bi kth-smallests first2 ;
 108
 109 : median ( seq -- x )
 110     dup length odd?
 111     [ lower-median ] [ medians + 2 / ] if ;
 112
 113 ! quantile can be any n-tile. quartile is n = 4, percentile is n = 100
 114 ! a,b,c,d parameters, N - number of samples, q is quantile (1/2 for median, 1/4 for 1st quartile)
 115 ! http://mathworld.wolfram.com/Quantile.html
 116 ! a + (N + b) q - 1
 117 ! could subtract 1 from a
 118
 119 : quantile-x ( a b N q -- x )
 120     [ + ] dip * + 1 - ; inline
 121
 122 ! 2+1/4 frac is 1/4
 123 : frac ( x -- x' )
 124     >fraction [ /mod nip ] keep / ; inline
 125
 126 :: quantile-indices ( seq qs a b c d -- seq )
 127     qs [ [ a b seq length ] dip quantile-x ] map ;
 128
 129 :: qabcd ( y-floor y-ceiling x c d -- qabcd )
 130     y-floor y-ceiling y-floor - c d x frac * + * + ;
 131
 132 :: quantile-abcd ( seq qs a b c d -- quantile )
 133     seq qs a b c d quantile-indices :> indices
 134     indices [ [ floor ] [ ceiling ] bi 2array ] map
 135     concat :> index-pairs
 136
 137     seq index-pairs kth-smallests
 138     2 group indices [ [ first2 ] dip c d qabcd ] 2map ;
 139
 140 : quantile1 ( seq qs -- seq' )
 141     0 0 1 0 quantile-abcd ;
 142
 143 : quantile3 ( seq qs -- seq' )
 144     1/2 0 0 0 quantile-abcd ;
 145
 146 : quantile4 ( seq qs -- seq' )
 147     0 0 0 1 quantile-abcd ;
 148
 149 : quantile5 ( seq qs -- seq' )
 150     1/2 0 0 1 quantile-abcd ;
 151
 152 : quantile6 ( seq qs -- seq' )
 153     0 1 0 1 quantile-abcd ;
 154
 155 : quantile7 ( seq qs -- seq' )
 156     1 -1 0 1 quantile-abcd ;
 157
 158 : quantile8 ( seq qs -- seq' )
 159     1/3 1/3 0 1 quantile-abcd ;
 160
 161 : quantile9 ( seq qs -- seq' )
 162     3/8 1/4 0 1 quantile-abcd ;
 163
 164 : quartile ( seq -- seq' )
 165     { 1/4 1/2 3/4 } quantile5 ;
 166
 167 <PRIVATE
 168
 169 : (sequence>assoc) ( seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) assoc -- assoc )
 170     [ swap curry compose each ] keep ; inline
 171
 172 PRIVATE>
 173
 174 : sequence>assoc! ( assoc seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) -- assoc )
 175     4 nrot (sequence>assoc) ; inline
 176
 177 : sequence>assoc ( seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) exemplar -- assoc )
 178     clone (sequence>assoc) ; inline
 179
 180 : sequence>hashtable ( seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) -- hashtable )
 181     H{ } sequence>assoc ; inline
 182
 183 : histogram! ( hashtable seq -- hashtable )
 184     [ ] [ inc-at ] sequence>assoc! ;
 185
 186 : histogram-by ( seq quot: ( x -- bin ) -- hashtable )
 187     [ inc-at ] sequence>hashtable ; inline
 188
 189 : histogram ( seq -- hashtable )
 190     [ ] histogram-by ;
 191
 192 : sorted-histogram ( seq -- alist )
 193     histogram sort-values ;
 194
 195 : collect-pairs ( seq quot: ( x -- v k ) -- hashtable )
 196     [ push-at ] sequence>hashtable ; inline
 197
 198 : collect-by ( seq quot: ( x -- x' ) -- hashtable )
 199     [ dup ] prepose collect-pairs ; inline
 200
 201 : mode ( seq -- x )
 202     histogram >alist
 203     [ ] [ [ [ second ] bi@ > ] most ] map-reduce first ;
 204
 205 ERROR: empty-sequence ;
 206
 207 : minmax ( seq -- min max )
 208     [
 209         empty-sequence
 210     ] [
 211         [ first dup ] keep [ [ min ] [ max ] bi-curry bi* ] each
 212     ] if-empty ;
 213
 214 : range ( seq -- x )
 215     minmax swap - ;
 216
 217 : sample-var ( seq -- x )
 218     #! normalize by N-1
 219     dup length 1 <= [
 220         drop 0
 221     ] [
 222         [ [ mean ] keep [ - sq ] with map-sum ]
 223         [ length 1 - ] bi /
 224     ] if ;
 225
 226 : full-var ( seq -- x )
 227     dup length 1 <= [
 228         drop 0
 229     ] [
 230         [ [ mean ] keep [ - sq ] with map-sum ]
 231         [ length ] bi /
 232     ] if ;
 233
 234 ALIAS: var sample-var
 235
 236 : sample-std ( seq -- x ) sample-var sqrt ;
 237
 238 : full-std ( seq -- x ) full-var sqrt ;
 239
 240 ALIAS: std sample-std
 241
 242 : sample-ste ( seq -- x ) [ sample-std ] [ length ] bi sqrt / ;
 243
 244 : full-ste ( seq -- x ) [ full-std ] [ length ] bi sqrt / ;
 245
 246 ALIAS: ste sample-ste
 247
 248 : ((r)) ( mean(x) mean(y) {x} {y} -- (r) )
 249     ! finds sigma((xi-mean(x))(yi-mean(y))
 250     0 [ [ [ pick ] dip swap - ] bi@ * + ] 2reduce 2nip ;
 251
 252 : (r) ( mean(x) mean(y) {x} {y} sx sy -- r )
 253     * recip [ [ ((r)) ] keep length 1 - / ] dip * ;
 254
 255 : [r] ( {{x,y}...} -- mean(x) mean(y) {x} {y} sx sy )
 256     first2 [ [ [ mean ] bi@ ] 2keep ] 2keep [ std ] bi@ ;
 257
 258 : r ( {{x,y}...} -- r )
 259     [r] (r) ;
 260
 261 : r^2 ( {{x,y}...} -- r )
 262     r sq ;
 263
 264 : least-squares ( {{x,y}...} -- alpha beta )
 265     [r] { [ 2dup ] [ ] [ ] [ ] [ ] } spread
 266     ! stack is mean(x) mean(y) mean(x) mean(y) {x} {y} sx sy
 267     [ (r) ] 2keep ! stack is mean(x) mean(y) r sx sy
 268     swap / * ! stack is mean(x) mean(y) beta
 269     [ swapd * - ] keep ;
 270
 271 : cov ( {x} {y} -- cov )
 272     [ dup mean v-n ] bi@ v* mean ;
 273
 274 : sample-corr ( {x} {y} -- corr )
 275      [ cov ] [ [ sample-var ] bi@ * sqrt ] 2bi / ;
 276
 277 : full-corr ( {x} {y} -- corr )
 278      [ cov ] [ [ full-var ] bi@ * sqrt ] 2bi / ;
 279
 280 ALIAS: corr sample-corr
 281
 282 : cum-sum ( seq -- seq' )
 283     0 swap [ + dup ] map nip ;
 284
 285 : cum-product ( seq -- seq' )
 286     1 swap [ * dup ] map nip ;
 287
 288 : cum-min ( seq -- seq' )
 289     [ ?first ] keep [ min dup ] map nip ;
 290
 291 : cum-max ( seq -- seq' )
 292     [ ?first ] keep [ max dup ] map nip ;
 293
 294 : entropy ( seq -- n )
 295     dup members [ [ = ] curry count ] with map
 296     dup sum v/n dup [ log ] map v* sum neg ;
 297
 298 : binary-entropy ( p -- h )
 299     [ dup log * ] [ 1 swap - dup log * ] bi + neg 2 log / ;
 300
 301 : standardize ( u -- v )
 302     [ dup mean v-n ] [ std ] bi v/n ;
 303
 304 : differences ( u -- v )
 305     [ 1 tail-slice ] keep [ - ] 2map ;
 306
 307 : rescale ( u -- v )
 308     [ ] [ infimum ] [ supremum over - ] tri
 309     [ v-n ] [ v/n ] bi* ;