basis/math/statistics/statistics.factor

   1 ! Copyright (C) 2008 Doug Coleman, Michael Judge.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: assocs combinators generalizations kernel locals math
   4 math.functions math.order math.vectors sequences
   5 sequences.private sorting fry arrays grouping sets ;
   6 IN: math.statistics
   7
   8 : power-mean ( seq p -- x )
   9     [ '[ _ ^ ] map-sum ] [ [ length / ] [ recip ^ ] bi* ] 2bi ; inline
  10
  11 : mean ( seq -- x )
  12     [ sum ] [ length ] bi / ; inline
  13
  14 : sum-of-squares ( seq -- x )
  15     [ sq ] map-sum ; inline
  16
  17 : sum-of-squared-errors ( seq -- x )
  18     [ mean ] keep [ - sq ] with map-sum ; inline
  19
  20 : sum-of-absolute-errors ( seq -- x )
  21     [ mean ] keep [ - ] with map-sum ; inline
  22
  23 : quadratic-mean ( seq -- x ) ! root-mean-square
  24     [ sum-of-squares ] [ length ] bi / sqrt ; inline
  25
  26 : geometric-mean ( seq -- x )
  27     [ length ] [ product ] bi nth-root ; inline
  28
  29 : harmonic-mean ( seq -- x )
  30     [ recip ] map-sum recip ; inline
  31
  32 : contraharmonic-mean ( seq -- x )
  33     [ sum-of-squares ] [ sum ] bi / ; inline
  34
  35 <PRIVATE
  36
  37 : trim-points ( p seq -- from to seq  )
  38     [ length [ * >integer ] keep over - ] keep ;
  39
  40 PRIVATE>
  41
  42 : trimmed-mean ( seq p -- x )
  43     swap natural-sort trim-points <slice> mean ;
  44
  45 : winsorized-mean ( seq p -- x )
  46     swap natural-sort trim-points
  47     [ <slice> ]
  48     [ nip dupd nth <array> ]
  49     [ [ 1 - ] dip nth <array> ] 3tri
  50     surround mean ;
  51
  52 <PRIVATE
  53
  54 :: ((kth-object)) ( seq k nth-quot exchange-quot quot: ( x y -- ? ) -- elt )
  55     #! Wirth's method, Algorithm's + Data structues = Programs p. 84
  56     k seq bounds-check 2drop
  57     0 :> i!
  58     0 :> j!
  59     0 :> l!
  60     0 :> x!
  61     seq length 1 - :> m!
  62     [ l m < ]
  63     [
  64         k seq nth x!
  65         l i!
  66         m j!
  67         [ i j <= ]
  68         [
  69             [ i seq nth-quot call x quot call ] [ i 1 + i! ] while
  70             [ x j seq nth-quot call quot call ] [ j 1 - j! ] while
  71             i j <= [
  72                 i j seq exchange-quot call
  73                 i 1 + i!
  74                 j 1 - j!
  75             ] when
  76         ] do while
  77
  78         j k < [ i l! ] when
  79         k i < [ j m! ] when
  80     ] while
  81     k seq nth ; inline
  82
  83 : (kth-object) ( seq k nth-quot exchange-quot quot: ( x y -- ? ) -- elt )
  84     #! The algorithm modifiers seq, so we clone it
  85     [ clone ] 4dip ((kth-object)) ; inline
  86
  87 : kth-object-unsafe ( seq k quot: ( x y -- ? ) -- elt )
  88     [ [ nth-unsafe ] [ exchange-unsafe ] ] dip (kth-object) ; inline
  89
  90 : kth-objects-unsafe ( seq kths quot: ( x y -- ? ) -- elts )
  91     [ clone ] 2dip
  92     '[ [ nth-unsafe ] [ exchange-unsafe ]  _ ((kth-object)) ] with map ; inline
  93
  94 PRIVATE>
  95
  96 : kth-object ( seq k quot: ( x y -- ? ) -- elt )
  97     [ [ nth ] [ exchange ] ] dip (kth-object) ; inline
  98
  99 : kth-objects ( seq kths quot: ( x y -- ? ) -- elts )
 100     [ clone ] 2dip
 101     '[ [ nth ] [ exchange ]  _ ((kth-object)) ] with map ; inline
 102
 103 : kth-smallests ( seq kths -- elts ) [ < ] kth-objects-unsafe ;
 104
 105 : kth-smallest ( seq k -- elt ) [ < ] kth-object-unsafe ;
 106
 107 : kth-largests ( seq kths -- elts ) [ > ] kth-objects-unsafe ;
 108
 109 : kth-largest ( seq k -- elt ) [ > ] kth-object-unsafe ;
 110
 111 : count-relative ( seq k -- lt eq gt )
 112     [ 0 0 0 ] 2dip '[
 113         _ <=> {
 114             { +lt+ [ [ 1 + ] 2dip ] }
 115             { +gt+ [ 1 + ] }
 116             { +eq+ [ [ 1 + ] dip ] }
 117         } case
 118     ] each ;
 119
 120 : minmax-relative ( seq k -- lt eq gt lt-max gt-min )
 121     [ 0 0 0 -1/0. 1/0. ] 2dip '[
 122         dup _ <=> {
 123             { +lt+ [ [ 1 + ] 5 ndip '[ _ max ] dip ] }
 124             { +gt+ [ [ 1 + ] 3dip min ] }
 125             { +eq+ [ [ 1 + ] 4dip drop ] }
 126         } case
 127     ] each ;
 128
 129 : lower-median-index ( seq -- n )
 130     [ midpoint@ ]
 131     [ length odd? [ 1 - ] unless ] bi ;
 132
 133 : lower-median ( seq -- elt )
 134     [ ] [ lower-median-index ] bi kth-smallest ;
 135
 136 : upper-median ( seq -- elt )
 137     dup midpoint@ kth-smallest ;
 138
 139 : medians ( seq -- lower upper )
 140     [ ]
 141     [ [ lower-median-index ] [ midpoint@ ] bi 2array ]
 142     bi kth-smallests first2 ;
 143
 144 : median ( seq -- x )
 145     dup length odd? [ lower-median ] [ medians + 2 / ] if ;
 146
 147 ! quantile can be any n-tile. quartile is n = 4, percentile is n = 100
 148 ! a,b,c,d parameters, N - number of samples, q is quantile (1/2 for median, 1/4 for 1st quartile)
 149 ! http://mathworld.wolfram.com/Quantile.html
 150 ! a + (N + b) q - 1
 151 ! could subtract 1 from a
 152
 153 : quantile-x ( a b N q -- x )
 154     [ + ] dip * + 1 - ; inline
 155
 156 ! 2+1/4 frac is 1/4
 157 : frac ( x -- x' )
 158     >fraction [ /mod nip ] keep / ; inline
 159
 160 :: quantile-indices ( seq qs a b c d -- seq )
 161     qs [ [ a b seq length ] dip quantile-x ] map ;
 162
 163 :: qabcd ( y-floor y-ceiling x c d -- qabcd )
 164     y-floor y-ceiling y-floor - c d x frac * + * + ;
 165
 166 :: quantile-abcd ( seq qs a b c d -- quantile )
 167     seq qs a b c d quantile-indices :> indices
 168     indices [ [ floor ] [ ceiling ] bi 2array ] map
 169     concat :> index-pairs
 170
 171     seq index-pairs kth-smallests
 172     2 group indices [ [ first2 ] dip c d qabcd ] 2map ;
 173
 174 : quantile1 ( seq qs -- seq' )
 175     0 0 1 0 quantile-abcd ;
 176
 177 : quantile3 ( seq qs -- seq' )
 178     1/2 0 0 0 quantile-abcd ;
 179
 180 : quantile4 ( seq qs -- seq' )
 181     0 0 0 1 quantile-abcd ;
 182
 183 : quantile5 ( seq qs -- seq' )
 184     1/2 0 0 1 quantile-abcd ;
 185
 186 : quantile6 ( seq qs -- seq' )
 187     0 1 0 1 quantile-abcd ;
 188
 189 : quantile7 ( seq qs -- seq' )
 190     1 -1 0 1 quantile-abcd ;
 191
 192 : quantile8 ( seq qs -- seq' )
 193     1/3 1/3 0 1 quantile-abcd ;
 194
 195 : quantile9 ( seq qs -- seq' )
 196     3/8 1/4 0 1 quantile-abcd ;
 197
 198 : quartile ( seq -- seq' )
 199     { 1/4 1/2 3/4 } quantile5 ;
 200
 201 <PRIVATE
 202
 203 : (sequence>assoc) ( seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) assoc -- assoc )
 204     [ swap curry compose each ] keep ; inline
 205
 206 PRIVATE>
 207
 208 : sequence>assoc! ( assoc seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) -- assoc )
 209     4 nrot (sequence>assoc) ; inline
 210
 211 : sequence>assoc ( seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) exemplar -- assoc )
 212     clone (sequence>assoc) ; inline
 213
 214 : sequence>hashtable ( seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) -- hashtable )
 215     H{ } sequence>assoc ; inline
 216
 217 : histogram! ( hashtable seq -- hashtable )
 218     [ ] [ inc-at ] sequence>assoc! ;
 219
 220 : histogram-by ( seq quot: ( x -- bin ) -- hashtable )
 221     [ inc-at ] sequence>hashtable ; inline
 222
 223 : histogram ( seq -- hashtable )
 224     [ ] histogram-by ;
 225
 226 : sorted-histogram ( seq -- alist )
 227     histogram sort-values ;
 228
 229 : collect-pairs ( seq quot: ( x -- v k ) -- hashtable )
 230     [ push-at ] sequence>hashtable ; inline
 231
 232 : collect-by ( seq quot: ( x -- x' ) -- hashtable )
 233     [ dup ] prepose collect-pairs ; inline
 234
 235 : mode ( seq -- x )
 236     histogram >alist
 237     [ ] [ [ [ second ] bi@ > ] most ] map-reduce first ;
 238
 239 ERROR: empty-sequence ;
 240
 241 : minmax ( seq -- min max )
 242     [
 243         empty-sequence
 244     ] [
 245         [ first dup ] keep [ [ min ] [ max ] bi-curry bi* ] each
 246     ] if-empty ;
 247
 248 : range ( seq -- x )
 249     minmax swap - ;
 250
 251 : sample-var ( seq -- x )
 252     #! normalize by N-1; unbiased
 253     dup length 1 <= [
 254         drop 0
 255     ] [
 256         [ sum-of-squared-errors ] [ length 1 - ] bi /
 257     ] if ;
 258
 259 : full-var ( seq -- x )
 260     dup length 1 <= [
 261         drop 0
 262     ] [
 263         [ sum-of-squared-errors ] [ length ] bi /
 264     ] if ;
 265
 266 ALIAS: var sample-var
 267
 268 : sample-std ( seq -- x ) sample-var sqrt ;
 269
 270 : full-std ( seq -- x ) full-var sqrt ;
 271
 272 ALIAS: std sample-std
 273
 274 : signal-to-noise ( seq -- x ) [ mean ] [ std ] bi / ;
 275
 276 : mean-dev ( seq -- x ) dup mean v-n vabs mean ;
 277
 278 : median-dev ( seq -- x ) dup median v-n vabs mean ;
 279
 280 : sample-ste ( seq -- x ) [ sample-std ] [ length ] bi sqrt / ;
 281
 282 : full-ste ( seq -- x ) [ full-std ] [ length ] bi sqrt / ;
 283
 284 ALIAS: ste sample-ste
 285
 286 : ((r)) ( mean(x) mean(y) {x} {y} -- (r) )
 287     ! finds sigma((xi-mean(x))(yi-mean(y))
 288     0 [ [ [ pick ] dip swap - ] bi@ * + ] 2reduce 2nip ;
 289
 290 : (r) ( mean(x) mean(y) {x} {y} sx sy -- r )
 291     * recip [ [ ((r)) ] keep length 1 - / ] dip * ;
 292
 293 : [r] ( {{x,y}...} -- mean(x) mean(y) {x} {y} sx sy )
 294     first2 [ [ [ mean ] bi@ ] 2keep ] 2keep [ std ] bi@ ;
 295
 296 : r ( {{x,y}...} -- r )
 297     [r] (r) ;
 298
 299 : r^2 ( {{x,y}...} -- r )
 300     r sq ;
 301
 302 : least-squares ( {{x,y}...} -- alpha beta )
 303     [r] { [ 2dup ] [ ] [ ] [ ] [ ] } spread
 304     ! stack is mean(x) mean(y) mean(x) mean(y) {x} {y} sx sy
 305     [ (r) ] 2keep ! stack is mean(x) mean(y) r sx sy
 306     swap / * ! stack is mean(x) mean(y) beta
 307     [ swapd * - ] keep ;
 308
 309 : cov ( {x} {y} -- cov )
 310     [ dup mean v-n ] bi@ v* mean ;
 311
 312 : sample-corr ( {x} {y} -- corr )
 313      [ cov ] [ [ sample-var ] bi@ * sqrt ] 2bi / ;
 314
 315 : full-corr ( {x} {y} -- corr )
 316      [ cov ] [ [ full-var ] bi@ * sqrt ] 2bi / ;
 317
 318 ALIAS: corr sample-corr
 319
 320 : cum-sum ( seq -- seq' )
 321     0 swap [ + dup ] map nip ;
 322
 323 : cum-product ( seq -- seq' )
 324     1 swap [ * dup ] map nip ;
 325
 326 : cum-min ( seq -- seq' )
 327     [ ?first ] keep [ min dup ] map nip ;
 328
 329 : cum-max ( seq -- seq' )
 330     [ ?first ] keep [ max dup ] map nip ;
 331
 332 : entropy ( seq -- n )
 333     histogram values dup sum '[ _ / dup log * ] map-sum neg ;
 334
 335 : binary-entropy ( p -- h )
 336     [ dup log * ] [ 1 swap - dup log * ] bi + neg 2 log / ;
 337
 338 : standardize ( u -- v )
 339     [ dup mean v-n ] [ std ] bi v/n ;
 340
 341 : differences ( u -- v )
 342     [ 1 tail-slice ] keep [ - ] 2map ;
 343
 344 : rescale ( u -- v )
 345     dup minmax over - [ v-n ] [ v/n ] bi* ;