basis/math/statistics/statistics.factor

   1 ! Copyright (C) 2008 Doug Coleman, Michael Judge.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: assocs combinators generalizations kernel locals math
   4 math.functions math.order math.vectors sequences
   5 sequences.private sorting fry arrays grouping sets
   6 splitting.monotonic ;
   7 IN: math.statistics
   8
   9 : power-mean ( seq p -- x )
  10     [ '[ _ ^ ] map-sum ] [ [ length / ] [ recip ^ ] bi* ] 2bi ; inline
  11
  12 : mean ( seq -- x )
  13     [ sum ] [ length ] bi / ; inline
  14
  15 : sum-of-squares ( seq -- x )
  16     [ sq ] map-sum ; inline
  17
  18 : sum-of-squared-errors ( seq -- x )
  19     [ mean ] keep [ - sq ] with map-sum ; inline
  20
  21 : sum-of-absolute-errors ( seq -- x )
  22     [ mean ] keep [ - ] with map-sum ; inline
  23
  24 : quadratic-mean ( seq -- x ) ! root-mean-square
  25     [ sum-of-squares ] [ length ] bi / sqrt ; inline
  26
  27 : geometric-mean ( seq -- x )
  28     [ length ] [ product ] bi nth-root ; inline
  29
  30 : harmonic-mean ( seq -- x )
  31     [ recip ] map-sum recip ; inline
  32
  33 : contraharmonic-mean ( seq -- x )
  34     [ sum-of-squares ] [ sum ] bi / ; inline
  35
  36 <PRIVATE
  37
  38 : trim-points ( p seq -- from to seq  )
  39     [ length [ * >integer ] keep over - ] keep ;
  40
  41 PRIVATE>
  42
  43 : trimmed-mean ( seq p -- x )
  44     swap natural-sort trim-points <slice> mean ;
  45
  46 : winsorized-mean ( seq p -- x )
  47     swap natural-sort trim-points
  48     [ <slice> ]
  49     [ nip dupd nth <array> ]
  50     [ [ 1 - ] dip nth <array> ] 3tri
  51     surround mean ;
  52
  53 <PRIVATE
  54
  55 :: ((kth-object)) ( seq k nth-quot exchange-quot quot: ( x y -- ? ) -- elt )
  56     #! Wirth's method, Algorithm's + Data structues = Programs p. 84
  57     k seq bounds-check 2drop
  58     0 :> i!
  59     0 :> j!
  60     0 :> l!
  61     0 :> x!
  62     seq length 1 - :> m!
  63     [ l m < ]
  64     [
  65         k seq nth x!
  66         l i!
  67         m j!
  68         [ i j <= ]
  69         [
  70             [ i seq nth-quot call x quot call ] [ i 1 + i! ] while
  71             [ x j seq nth-quot call quot call ] [ j 1 - j! ] while
  72             i j <= [
  73                 i j seq exchange-quot call
  74                 i 1 + i!
  75                 j 1 - j!
  76             ] when
  77         ] do while
  78
  79         j k < [ i l! ] when
  80         k i < [ j m! ] when
  81     ] while
  82     k seq nth ; inline
  83
  84 : (kth-object) ( seq k nth-quot exchange-quot quot: ( x y -- ? ) -- elt )
  85     #! The algorithm modifiers seq, so we clone it
  86     [ clone ] 4dip ((kth-object)) ; inline
  87
  88 : kth-object-unsafe ( seq k quot: ( x y -- ? ) -- elt )
  89     [ [ nth-unsafe ] [ exchange-unsafe ] ] dip (kth-object) ; inline
  90
  91 : kth-objects-unsafe ( seq kths quot: ( x y -- ? ) -- elts )
  92     [ clone ] 2dip
  93     '[ [ nth-unsafe ] [ exchange-unsafe ]  _ ((kth-object)) ] with map ; inline
  94
  95 PRIVATE>
  96
  97 : kth-object ( seq k quot: ( x y -- ? ) -- elt )
  98     [ [ nth ] [ exchange ] ] dip (kth-object) ; inline
  99
 100 : kth-objects ( seq kths quot: ( x y -- ? ) -- elts )
 101     [ clone ] 2dip
 102     '[ [ nth ] [ exchange ]  _ ((kth-object)) ] with map ; inline
 103
 104 : kth-smallests ( seq kths -- elts ) [ < ] kth-objects-unsafe ;
 105
 106 : kth-smallest ( seq k -- elt ) [ < ] kth-object-unsafe ;
 107
 108 : kth-largests ( seq kths -- elts ) [ > ] kth-objects-unsafe ;
 109
 110 : kth-largest ( seq k -- elt ) [ > ] kth-object-unsafe ;
 111
 112 : count-relative ( seq k -- lt eq gt )
 113     [ 0 0 0 ] 2dip '[
 114         _ <=> {
 115             { +lt+ [ [ 1 + ] 2dip ] }
 116             { +gt+ [ 1 + ] }
 117             { +eq+ [ [ 1 + ] dip ] }
 118         } case
 119     ] each ;
 120
 121 : minmax-relative ( seq k -- lt eq gt lt-max gt-min )
 122     [ 0 0 0 -1/0. 1/0. ] 2dip '[
 123         dup _ <=> {
 124             { +lt+ [ [ 1 + ] 5 ndip '[ _ max ] dip ] }
 125             { +gt+ [ [ 1 + ] 3dip min ] }
 126             { +eq+ [ [ 1 + ] 4dip drop ] }
 127         } case
 128     ] each ;
 129
 130 : lower-median-index ( seq -- n )
 131     [ midpoint@ ]
 132     [ length odd? [ 1 - ] unless ] bi ;
 133
 134 : lower-median ( seq -- elt )
 135     [ ] [ lower-median-index ] bi kth-smallest ;
 136
 137 : upper-median ( seq -- elt )
 138     dup midpoint@ kth-smallest ;
 139
 140 : medians ( seq -- lower upper )
 141     [ ]
 142     [ [ lower-median-index ] [ midpoint@ ] bi 2array ]
 143     bi kth-smallests first2 ;
 144
 145 : median ( seq -- x )
 146     dup length odd? [ lower-median ] [ medians + 2 / ] if ;
 147
 148 ! quantile can be any n-tile. quartile is n = 4, percentile is n = 100
 149 ! a,b,c,d parameters, N - number of samples, q is quantile (1/2 for median, 1/4 for 1st quartile)
 150 ! http://mathworld.wolfram.com/Quantile.html
 151 ! a + (N + b) q - 1
 152 ! could subtract 1 from a
 153
 154 : quantile-x ( a b N q -- x )
 155     [ + ] dip * + 1 - ; inline
 156
 157 ! 2+1/4 frac is 1/4
 158 : frac ( x -- x' )
 159     >fraction [ /mod nip ] keep / ; inline
 160
 161 :: quantile-indices ( seq qs a b c d -- seq )
 162     qs [ [ a b seq length ] dip quantile-x ] map ;
 163
 164 :: qabcd ( y-floor y-ceiling x c d -- qabcd )
 165     y-floor y-ceiling y-floor - c d x frac * + * + ;
 166
 167 :: quantile-abcd ( seq qs a b c d -- quantile )
 168     seq qs a b c d quantile-indices :> indices
 169     indices [ [ floor ] [ ceiling ] bi 2array ] map
 170     concat :> index-pairs
 171
 172     seq index-pairs kth-smallests
 173     2 group indices [ [ first2 ] dip c d qabcd ] 2map ;
 174
 175 : quantile1 ( seq qs -- seq' )
 176     0 0 1 0 quantile-abcd ;
 177
 178 : quantile3 ( seq qs -- seq' )
 179     1/2 0 0 0 quantile-abcd ;
 180
 181 : quantile4 ( seq qs -- seq' )
 182     0 0 0 1 quantile-abcd ;
 183
 184 : quantile5 ( seq qs -- seq' )
 185     1/2 0 0 1 quantile-abcd ;
 186
 187 : quantile6 ( seq qs -- seq' )
 188     0 1 0 1 quantile-abcd ;
 189
 190 : quantile7 ( seq qs -- seq' )
 191     1 -1 0 1 quantile-abcd ;
 192
 193 : quantile8 ( seq qs -- seq' )
 194     1/3 1/3 0 1 quantile-abcd ;
 195
 196 : quantile9 ( seq qs -- seq' )
 197     3/8 1/4 0 1 quantile-abcd ;
 198
 199 : quartile ( seq -- seq' )
 200     { 1/4 1/2 3/4 } quantile5 ;
 201
 202 <PRIVATE
 203
 204 : (sequence>assoc) ( seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) assoc -- assoc )
 205     [ swap curry compose each ] keep ; inline
 206
 207 PRIVATE>
 208
 209 : sequence>assoc! ( assoc seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) -- assoc )
 210     4 nrot (sequence>assoc) ; inline
 211
 212 : sequence>assoc ( seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) exemplar -- assoc )
 213     clone (sequence>assoc) ; inline
 214
 215 : sequence>hashtable ( seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) -- hashtable )
 216     H{ } sequence>assoc ; inline
 217
 218 : histogram! ( hashtable seq -- hashtable )
 219     [ ] [ inc-at ] sequence>assoc! ;
 220
 221 : histogram-by ( seq quot: ( x -- bin ) -- hashtable )
 222     [ inc-at ] sequence>hashtable ; inline
 223
 224 : histogram ( seq -- hashtable )
 225     [ ] histogram-by ;
 226
 227 : sorted-histogram ( seq -- alist )
 228     histogram sort-values ;
 229
 230 : collect-pairs ( seq quot: ( x -- v k ) -- hashtable )
 231     [ push-at ] sequence>hashtable ; inline
 232
 233 : collect-by ( seq quot: ( x -- x' ) -- hashtable )
 234     [ dup ] prepose collect-pairs ; inline
 235
 236 : mode ( seq -- x )
 237     histogram >alist
 238     [ ] [ [ [ second ] bi@ > ] most ] map-reduce first ;
 239
 240 ERROR: empty-sequence ;
 241
 242 : minmax ( seq -- min max )
 243     [
 244         empty-sequence
 245     ] [
 246         [ first dup ] keep [ [ min ] [ max ] bi-curry bi* ] each
 247     ] if-empty ;
 248
 249 : range ( seq -- x )
 250     minmax swap - ;
 251
 252 : sample-var ( seq -- x )
 253     #! normalize by N-1; unbiased
 254     dup length 1 <= [
 255         drop 0
 256     ] [
 257         [ sum-of-squared-errors ] [ length 1 - ] bi /
 258     ] if ;
 259
 260 : full-var ( seq -- x )
 261     dup length 1 <= [
 262         drop 0
 263     ] [
 264         [ sum-of-squared-errors ] [ length ] bi /
 265     ] if ;
 266
 267 ALIAS: var sample-var
 268
 269 : sample-std ( seq -- x ) sample-var sqrt ;
 270
 271 : full-std ( seq -- x ) full-var sqrt ;
 272
 273 ALIAS: std sample-std
 274
 275 : signal-to-noise ( seq -- x ) [ mean ] [ std ] bi / ;
 276
 277 : mean-dev ( seq -- x ) dup mean v-n vabs mean ;
 278
 279 : median-dev ( seq -- x ) dup median v-n vabs mean ;
 280
 281 : sample-ste ( seq -- x ) [ sample-std ] [ length ] bi sqrt / ;
 282
 283 : full-ste ( seq -- x ) [ full-std ] [ length ] bi sqrt / ;
 284
 285 ALIAS: ste sample-ste
 286
 287 : ((r)) ( mean(x) mean(y) {x} {y} -- (r) )
 288     ! finds sigma((xi-mean(x))(yi-mean(y))
 289     0 [ [ [ pick ] dip swap - ] bi@ * + ] 2reduce 2nip ;
 290
 291 : (r) ( mean(x) mean(y) {x} {y} sx sy -- r )
 292     * recip [ [ ((r)) ] keep length 1 - / ] dip * ;
 293
 294 : [r] ( {{x,y}...} -- mean(x) mean(y) {x} {y} sx sy )
 295     first2 [ [ [ mean ] bi@ ] 2keep ] 2keep [ std ] bi@ ;
 296
 297 : r ( {{x,y}...} -- r )
 298     [r] (r) ;
 299
 300 : r^2 ( {{x,y}...} -- r )
 301     r sq ;
 302
 303 : least-squares ( {{x,y}...} -- alpha beta )
 304     [r] { [ 2dup ] [ ] [ ] [ ] [ ] } spread
 305     ! stack is mean(x) mean(y) mean(x) mean(y) {x} {y} sx sy
 306     [ (r) ] 2keep ! stack is mean(x) mean(y) r sx sy
 307     swap / * ! stack is mean(x) mean(y) beta
 308     [ swapd * - ] keep ;
 309
 310 : cov ( {x} {y} -- cov )
 311     [ dup mean v-n ] bi@ v* mean ;
 312
 313 : sample-corr ( {x} {y} -- corr )
 314      [ cov ] [ [ sample-var ] bi@ * sqrt ] 2bi / ;
 315
 316 : full-corr ( {x} {y} -- corr )
 317      [ cov ] [ [ full-var ] bi@ * sqrt ] 2bi / ;
 318
 319 ALIAS: corr sample-corr
 320
 321 : cum-map ( seq identity quot -- seq' )
 322     swapd [ dup ] compose map nip ; inline
 323
 324 : cum-sum ( seq -- seq' )
 325     0 [ + ] cum-map ;
 326
 327 : cum-product ( seq -- seq' )
 328     1 [ * ] cum-map ;
 329
 330 : cum-min ( seq -- seq' )
 331     dup ?first [ min ] cum-map ;
 332
 333 : cum-max ( seq -- seq' )
 334     dup ?first [ max ] cum-map ;
 335
 336 : probabilities ( seq -- probabilities )
 337     [ histogram values ] [ length ] bi v/n ;
 338
 339 : entropy ( probabilities -- n )
 340     dup sum '[ _ / dup log * ] map-sum neg ;
 341
 342 : maximum-entropy ( probabilities -- n )
 343     length log ;
 344
 345 : normalized-entropy ( probabilities -- n )
 346     [ entropy ] [ maximum-entropy ] bi / ;
 347
 348 : binary-entropy ( p -- h )
 349     [ dup log * ] [ 1 swap - dup log * ] bi + neg 2 log / ;
 350
 351 : standardize ( u -- v )
 352     [ dup mean v-n ] [ std ] bi v/n ;
 353
 354 : differences ( u -- v )
 355     [ 1 tail-slice ] keep [ - ] 2map ;
 356
 357 : rescale ( u -- v )
 358     dup minmax over - [ v-n ] [ v/n ] bi* ;
 359
 360 : rank-values ( seq -- seq' )
 361     [
 362         [ ] [ length iota ] bi zip sort-keys
 363         [ [ first ] bi@ = ] monotonic-split
 364         [ values ] map [ 0 [ length + ] accumulate nip ] [ ] bi zip
 365     ] [ length f <array> ] bi
 366     [ '[ first2 [ _ set-nth ] with each ] each ] keep ;