basis/math/statistics/statistics.factor

   1 ! Copyright (C) 2008 Doug Coleman, Michael Judge.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: assocs combinators generalizations kernel locals math
   4 math.functions math.order math.vectors sequences
   5 sequences.private sorting fry arrays grouping sets
   6 splitting.monotonic ;
   7 IN: math.statistics
   8
   9 : power-mean ( seq p -- x )
  10     [ '[ _ ^ ] map-sum ] [ [ length / ] [ recip ^ ] bi* ] 2bi ; inline
  11
  12 ! Delta in degrees-of-freedom
  13 : mean-ddof ( seq ddof -- x )
  14     [ [ sum ] [ length ] bi ] dip -
  15     dup zero? [ 2drop 0 ] [ / ] if ; inline
  16
  17 : mean ( seq -- x )
  18     0 mean-ddof ; inline
  19
  20 : unbiased-mean ( seq -- x )
  21     1 mean-ddof ; inline
  22
  23 : sum-of-squares ( seq -- x )
  24     [ sq ] map-sum ; inline
  25
  26 : sum-of-squared-errors ( seq -- x )
  27     [ mean ] keep [ - sq ] with map-sum ; inline
  28
  29 : sum-of-absolute-errors ( seq -- x )
  30     [ mean ] keep [ - ] with map-sum ; inline
  31
  32 : quadratic-mean ( seq -- x ) ! root-mean-square
  33     [ sum-of-squares ] [ length ] bi / sqrt ; inline
  34
  35 : geometric-mean ( seq -- x )
  36     [ length ] [ product ] bi nth-root ; inline
  37
  38 : harmonic-mean ( seq -- x )
  39     [ recip ] map-sum recip ; inline
  40
  41 : contraharmonic-mean ( seq -- x )
  42     [ sum-of-squares ] [ sum ] bi / ; inline
  43
  44 <PRIVATE
  45
  46 : trim-points ( p seq -- from to seq  )
  47     [ length [ * >integer ] keep over - ] keep ;
  48
  49 PRIVATE>
  50
  51 : trimmed-mean ( seq p -- x )
  52     swap natural-sort trim-points <slice> mean ;
  53
  54 : winsorized-mean ( seq p -- x )
  55     swap natural-sort trim-points
  56     [ <slice> ]
  57     [ nip dupd nth <array> ]
  58     [ [ 1 - ] dip nth <array> ] 3tri
  59     surround mean ;
  60
  61 <PRIVATE
  62
  63 :: ((kth-object)) ( seq k nth-quot exchange-quot quot: ( x y -- ? ) -- elt )
  64     #! Wirth's method, Algorithm's + Data structues = Programs p. 84
  65     k seq bounds-check 2drop
  66     0 :> i!
  67     0 :> j!
  68     0 :> l!
  69     0 :> x!
  70     seq length 1 - :> m!
  71     [ l m < ]
  72     [
  73         k seq nth x!
  74         l i!
  75         m j!
  76         [ i j <= ]
  77         [
  78             [ i seq nth-quot call x quot call ] [ i 1 + i! ] while
  79             [ x j seq nth-quot call quot call ] [ j 1 - j! ] while
  80             i j <= [
  81                 i j seq exchange-quot call
  82                 i 1 + i!
  83                 j 1 - j!
  84             ] when
  85         ] do while
  86
  87         j k < [ i l! ] when
  88         k i < [ j m! ] when
  89     ] while
  90     k seq nth ; inline
  91
  92 : (kth-object) ( seq k nth-quot exchange-quot quot: ( x y -- ? ) -- elt )
  93     #! The algorithm modifiers seq, so we clone it
  94     [ clone ] 4dip ((kth-object)) ; inline
  95
  96 : kth-object-unsafe ( seq k quot: ( x y -- ? ) -- elt )
  97     [ [ nth-unsafe ] [ exchange-unsafe ] ] dip (kth-object) ; inline
  98
  99 : kth-objects-unsafe ( seq kths quot: ( x y -- ? ) -- elts )
 100     [ clone ] 2dip
 101     '[ [ nth-unsafe ] [ exchange-unsafe ]  _ ((kth-object)) ] with map ; inline
 102
 103 PRIVATE>
 104
 105 : kth-object ( seq k quot: ( x y -- ? ) -- elt )
 106     [ [ nth ] [ exchange ] ] dip (kth-object) ; inline
 107
 108 : kth-objects ( seq kths quot: ( x y -- ? ) -- elts )
 109     [ clone ] 2dip
 110     '[ [ nth ] [ exchange ]  _ ((kth-object)) ] with map ; inline
 111
 112 : kth-smallests ( seq kths -- elts ) [ < ] kth-objects-unsafe ;
 113
 114 : kth-smallest ( seq k -- elt ) [ < ] kth-object-unsafe ;
 115
 116 : kth-largests ( seq kths -- elts ) [ > ] kth-objects-unsafe ;
 117
 118 : kth-largest ( seq k -- elt ) [ > ] kth-object-unsafe ;
 119
 120 : count-relative ( seq k -- lt eq gt )
 121     [ 0 0 0 ] 2dip '[
 122         _ <=> {
 123             { +lt+ [ [ 1 + ] 2dip ] }
 124             { +gt+ [ 1 + ] }
 125             { +eq+ [ [ 1 + ] dip ] }
 126         } case
 127     ] each ;
 128
 129 : minmax-relative ( seq k -- lt eq gt lt-max gt-min )
 130     [ 0 0 0 -1/0. 1/0. ] 2dip '[
 131         dup _ <=> {
 132             { +lt+ [ [ 1 + ] 5 ndip '[ _ max ] dip ] }
 133             { +gt+ [ [ 1 + ] 3dip min ] }
 134             { +eq+ [ [ 1 + ] 4dip drop ] }
 135         } case
 136     ] each ;
 137
 138 : lower-median-index ( seq -- n )
 139     [ midpoint@ ]
 140     [ length odd? [ 1 - ] unless ] bi ;
 141
 142 : lower-median ( seq -- elt )
 143     [ ] [ lower-median-index ] bi kth-smallest ;
 144
 145 : upper-median ( seq -- elt )
 146     dup midpoint@ kth-smallest ;
 147
 148 : medians ( seq -- lower upper )
 149     [ ]
 150     [ [ lower-median-index ] [ midpoint@ ] bi 2array ]
 151     bi kth-smallests first2 ;
 152
 153 : median ( seq -- x )
 154     dup length odd? [ lower-median ] [ medians + 2 / ] if ;
 155
 156 ! quantile can be any n-tile. quartile is n = 4, percentile is n = 100
 157 ! a,b,c,d parameters, N - number of samples, q is quantile (1/2 for median, 1/4 for 1st quartile)
 158 ! http://mathworld.wolfram.com/Quantile.html
 159 ! a + (N + b) q - 1
 160 ! could subtract 1 from a
 161
 162 : quantile-x ( a b N q -- x )
 163     [ + ] dip * + 1 - ; inline
 164
 165 ! 2+1/4 frac is 1/4
 166 : frac ( x -- x' )
 167     >fraction [ /mod nip ] keep / ; inline
 168
 169 :: quantile-indices ( seq qs a b c d -- seq )
 170     qs [ [ a b seq length ] dip quantile-x ] map ;
 171
 172 :: qabcd ( y-floor y-ceiling x c d -- qabcd )
 173     y-floor y-ceiling y-floor - c d x frac * + * + ;
 174
 175 :: quantile-abcd ( seq qs a b c d -- quantile )
 176     seq qs a b c d quantile-indices :> indices
 177     indices [ [ floor ] [ ceiling ] bi 2array ] map
 178     concat :> index-pairs
 179
 180     seq index-pairs kth-smallests
 181     2 group indices [ [ first2 ] dip c d qabcd ] 2map ;
 182
 183 : quantile1 ( seq qs -- seq' )
 184     0 0 1 0 quantile-abcd ;
 185
 186 : quantile3 ( seq qs -- seq' )
 187     1/2 0 0 0 quantile-abcd ;
 188
 189 : quantile4 ( seq qs -- seq' )
 190     0 0 0 1 quantile-abcd ;
 191
 192 : quantile5 ( seq qs -- seq' )
 193     1/2 0 0 1 quantile-abcd ;
 194
 195 : quantile6 ( seq qs -- seq' )
 196     0 1 0 1 quantile-abcd ;
 197
 198 : quantile7 ( seq qs -- seq' )
 199     1 -1 0 1 quantile-abcd ;
 200
 201 : quantile8 ( seq qs -- seq' )
 202     1/3 1/3 0 1 quantile-abcd ;
 203
 204 : quantile9 ( seq qs -- seq' )
 205     3/8 1/4 0 1 quantile-abcd ;
 206
 207 : quartile ( seq -- seq' )
 208     { 1/4 1/2 3/4 } quantile5 ;
 209
 210 <PRIVATE
 211
 212 : (sequence>assoc) ( seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) assoc -- assoc )
 213     [ swap curry compose each ] keep ; inline
 214
 215 PRIVATE>
 216
 217 : sequence>assoc! ( assoc seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) -- assoc )
 218     4 nrot (sequence>assoc) ; inline
 219
 220 : sequence>assoc ( seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) exemplar -- assoc )
 221     clone (sequence>assoc) ; inline
 222
 223 : sequence>hashtable ( seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) -- hashtable )
 224     H{ } sequence>assoc ; inline
 225
 226 : histogram! ( hashtable seq -- hashtable )
 227     [ ] [ inc-at ] sequence>assoc! ;
 228
 229 : histogram-by ( seq quot: ( x -- bin ) -- hashtable )
 230     [ inc-at ] sequence>hashtable ; inline
 231
 232 : histogram ( seq -- hashtable )
 233     [ ] histogram-by ;
 234
 235 : sorted-histogram ( seq -- alist )
 236     histogram sort-values ;
 237
 238 : normalized-histogram ( seq -- alist )
 239     [ histogram ] [ length ] bi '[ _ / ] assoc-map ;
 240
 241 : collect-pairs ( seq quot: ( x -- v k ) -- hashtable )
 242     [ push-at ] sequence>hashtable ; inline
 243
 244 : collect-by ( seq quot: ( x -- x' ) -- hashtable )
 245     [ dup ] prepose collect-pairs ; inline
 246
 247 : mode ( seq -- x )
 248     histogram >alist
 249     [ ] [ [ [ second ] bi@ > ] most ] map-reduce first ;
 250
 251 : minmax ( seq -- min max )
 252     [ first dup ] keep [ [ min ] [ max ] bi-curry bi* ] each ;
 253
 254 : range ( seq -- x )
 255     minmax swap - ;
 256
 257 : var-ddof ( seq n -- x )
 258     2dup [ length ] dip - 0 <= [
 259         2drop 0
 260     ] [
 261         [ [ sum-of-squared-errors ] [ length ] bi ] dip - /
 262     ] if ; inline
 263
 264 : population-var ( seq -- x ) 0 var-ddof ; inline
 265
 266 : sample-var ( seq -- x ) 1 var-ddof ; inline
 267
 268 : std-ddof ( seq n -- x )
 269     var-ddof sqrt ; inline
 270
 271 : population-std ( seq -- x ) 0 std-ddof ; inline
 272
 273 : sample-std ( seq -- x ) 1 std-ddof ; inline
 274
 275 ALIAS: std sample-std
 276
 277 : signal-to-noise ( seq -- x ) [ mean ] [ population-std ] bi / ;
 278
 279 : mean-dev ( seq -- x ) dup mean v-n vabs mean ;
 280
 281 : median-dev ( seq -- x ) dup median v-n vabs mean ;
 282
 283 : ste-ddof ( seq n -- x ) '[ _ std-ddof ] [ length ] bi sqrt / ;
 284
 285 : population-ste ( seq -- x ) 0 ste-ddof ;
 286
 287 : sample-ste ( seq -- x ) 1 ste-ddof ;
 288
 289 : ((r)) ( mean(x) mean(y) {x} {y} -- (r) )
 290     ! finds sigma((xi-mean(x))(yi-mean(y))
 291     0 [ [ [ pick ] dip swap - ] bi@ * + ] 2reduce 2nip ;
 292
 293 : (r) ( mean(x) mean(y) {x} {y} sx sy -- r )
 294     * recip [ [ ((r)) ] keep length 1 - / ] dip * ;
 295
 296 : [r] ( {{x,y}...} -- mean(x) mean(y) {x} {y} sx sy )
 297     first2 [ [ [ mean ] bi@ ] 2keep ] 2keep [ population-std ] bi@ ;
 298
 299 : r ( {{x,y}...} -- r )
 300     [r] (r) ;
 301
 302 : r^2 ( {{x,y}...} -- r )
 303     r sq ;
 304
 305 : least-squares ( {{x,y}...} -- alpha beta )
 306     [r] { [ 2dup ] [ ] [ ] [ ] [ ] } spread
 307     ! stack is mean(x) mean(y) mean(x) mean(y) {x} {y} sx sy
 308     [ (r) ] 2keep ! stack is mean(x) mean(y) r sx sy
 309     swap / * ! stack is mean(x) mean(y) beta
 310     [ swapd * - ] keep ;
 311
 312 : cov-ddof ( {x} {y} ddof -- cov )
 313     [ [ dup mean v-n ] bi@ v* ] dip mean-ddof ;
 314
 315 : population-cov ( {x} {y} -- cov ) 0 cov-ddof ; inline
 316
 317 : sample-cov ( {x} {y} -- cov ) 1 cov-ddof ; inline
 318
 319 : corr-ddof ( {x} {y} n -- corr )
 320     [ [ population-cov ] ] dip
 321     '[ [ _ var-ddof ] bi@ * sqrt ] 2bi / ;
 322
 323 : population-corr ( {x} {y} -- corr ) 0 corr-ddof ; inline
 324
 325 : sample-corr ( {x} {y} -- corr ) 1 corr-ddof ; inline
 326
 327 : cum-map ( seq identity quot -- seq' )
 328     swapd [ dup ] compose map nip ; inline
 329
 330 : cum-map0 ( seq identity quot -- seq' )
 331     accumulate nip ; inline
 332
 333 : cum-sum ( seq -- seq' )
 334     0 [ + ] cum-map ;
 335
 336 : cum-sum0 ( seq -- seq' )
 337     0 [ + ] cum-map0 ;
 338
 339 : cum-product ( seq -- seq' )
 340     1 [ * ] cum-map ;
 341
 342 : cum-count ( seq quot -- seq' )
 343     [ 0 ] dip
 344     '[ _ call [ 1 + ] when ] cum-map ; inline
 345
 346 : cum-min ( seq -- seq' )
 347     dup ?first [ min ] cum-map ;
 348
 349 : cum-max ( seq -- seq' )
 350     dup ?first [ max ] cum-map ;
 351
 352 : entropy ( probabilities -- n )
 353     dup sum '[ _ / dup log * ] map-sum neg ;
 354
 355 : maximum-entropy ( probabilities -- n )
 356     length log ;
 357
 358 : normalized-entropy ( probabilities -- n )
 359     [ entropy ] [ maximum-entropy ] bi / ;
 360
 361 : binary-entropy ( p -- h )
 362     [ dup log * ] [ 1 swap - dup log * ] bi + neg 2 log / ;
 363
 364 : standardize ( u -- v )
 365     [ dup mean v-n ] [ sample-std ] bi
 366     dup zero? [ drop ] [ v/n ] if ;
 367
 368 : standardize-2d ( u -- v )
 369     flip dup [ [ mean ] [ sample-std ] bi 2array ] map
 370     [ [ first v-n ] 2map ] keep [ second v/n ] 2map flip ;
 371
 372 : differences ( u -- v )
 373     [ 1 tail-slice ] keep [ - ] 2map ;
 374
 375 : rescale ( u -- v )
 376     dup minmax over - [ v-n ] [ v/n ] bi* ;
 377
 378 : rank-values ( seq -- seq' )
 379     [
 380         [ ] [ length iota ] bi zip sort-keys
 381         [ [ first ] bi@ = ] monotonic-split
 382         [ values ] map [ 0 [ length + ] accumulate nip ] [ ] bi zip
 383     ] [ length f <array> ] bi
 384     [ '[ first2 [ _ set-nth ] with each ] each ] keep ;
 385