basis/math/statistics/statistics.factor

   1 ! Copyright (C) 2008 Doug Coleman, Michael Judge, Loryn Jenkins.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays assocs combinators fry generalizations
   4 grouping kernel locals math math.functions math.order
   5 math.vectors sequences sequences.private sorting ;
   6 FROM: math.ranges => [a,b] ;
   7 IN: math.statistics
   8
   9 : power-mean ( seq p -- x )
  10     [ '[ _ ^ ] map-sum ] [ [ length / ] [ recip ^ ] bi* ] 2bi ; inline
  11
  12 ! Delta in degrees-of-freedom
  13 : mean-ddof ( seq ddof -- x )
  14     [ [ sum ] [ length ] bi ] dip -
  15     [ drop 0 ] [ / ] if-zero ; inline
  16
  17 : mean ( seq -- x )
  18     0 mean-ddof ; inline
  19
  20 : meanest ( seq -- x )
  21     [ mean ] keep [ - abs ] with infimum-by ;
  22
  23 GENERIC: sum-of-squares ( seq -- x )
  24 M: object sum-of-squares [ sq ] map-sum ;
  25 M: iota sum-of-squares
  26     n>> 1 - [ ] [ 1 + ] [ 1/2 + ] tri * * 3 / ;
  27
  28 GENERIC: sum-of-cubes ( seq -- x )
  29 M: object sum-of-cubes [ 3 ^ ] map-sum ;
  30 M: iota sum-of-cubes sum sq ;
  31
  32 GENERIC: sum-of-quads ( seq -- x )
  33 M: object sum-of-quads [ 4 ^ ] map-sum ;
  34 M: iota sum-of-quads
  35     [let n>> 1 - :> n
  36         n 0 > [
  37             n
  38             n 1 +
  39             n 2 * 1 +
  40             n sq 3 * n 3 * + 1 -
  41             * * * 30 /
  42         ] [ 0 ] if
  43     ] ;
  44
  45 : sum-of-squared-errors ( seq -- x )
  46     [ mean ] keep [ - sq ] with map-sum ; inline
  47
  48 : sum-of-absolute-errors ( seq -- x )
  49     [ mean ] keep [ - ] with map-sum ; inline
  50
  51 : quadratic-mean ( seq -- x ) ! root-mean-square
  52     [ sum-of-squares ] [ length ] bi / sqrt ; inline
  53
  54 : geometric-mean ( seq -- x )
  55     [ [ log ] map-sum ] [ length ] bi /f e^ ; inline
  56
  57 : harmonic-mean ( seq -- x )
  58     [ [ recip ] map-sum ] [ length swap / ] bi ; inline
  59
  60 : contraharmonic-mean ( seq -- x )
  61     [ sum-of-squares ] [ sum ] bi / ; inline
  62
  63 <PRIVATE
  64
  65 : trim-points ( p seq -- from to seq  )
  66     [ length [ * >integer ] keep over - ] keep ;
  67
  68 PRIVATE>
  69
  70 : trimmed-mean ( seq p -- x )
  71     swap natural-sort trim-points <slice> mean ;
  72
  73 : winsorized-mean ( seq p -- x )
  74     swap natural-sort trim-points
  75     [ <slice> ]
  76     [ nip dupd nth <array> ]
  77     [ [ 1 - ] dip nth <array> ] 3tri
  78     surround mean ;
  79
  80 <PRIVATE
  81
  82 :: kth-object-impl ( seq k nth-quot exchange-quot quot: ( x y -- ? ) -- elt )
  83     ! Wirth's method, Algorithm's + Data structues = Programs p. 84
  84     k seq bounds-check 2drop
  85     0 :> i!
  86     0 :> j!
  87     0 :> l!
  88     0 :> x!
  89     seq length 1 - :> m!
  90     [ l m < ]
  91     [
  92         k seq nth-unsafe x!
  93         l i!
  94         m j!
  95         [ i j <= ]
  96         [
  97             [ i seq nth-quot call x quot call ] [ i 1 + i! ] while
  98             [ x j seq nth-quot call quot call ] [ j 1 - j! ] while
  99             i j <= [
 100                 i j seq exchange-quot call
 101                 i 1 + i!
 102                 j 1 - j!
 103             ] when
 104         ] do while
 105
 106         j k < [ i l! ] when
 107         k i < [ j m! ] when
 108     ] while
 109     k seq nth-unsafe ; inline
 110
 111 : (kth-object) ( seq k nth-quot exchange-quot quot: ( x y -- ? ) -- elt )
 112     ! The algorithm modifiers seq, so we clone it
 113     [ >array ] 4dip kth-object-impl ; inline
 114
 115 : kth-object-unsafe ( seq k quot: ( x y -- ? ) -- elt )
 116     [ [ nth-unsafe ] [ exchange-unsafe ] ] dip (kth-object) ; inline
 117
 118 : kth-objects-unsafe ( seq kths quot: ( x y -- ? ) -- elts )
 119     '[ _ kth-object-unsafe ] with map ; inline
 120
 121 PRIVATE>
 122
 123 : kth-object ( seq k quot: ( x y -- ? ) -- elt )
 124     [ [ nth ] [ exchange ] ] dip (kth-object) ; inline
 125
 126 : kth-objects ( seq kths quot: ( x y -- ? ) -- elts )
 127     '[ _ kth-object ] with map ; inline
 128
 129 : kth-smallests ( seq kths -- elts ) [ < ] kth-objects-unsafe ;
 130
 131 : kth-smallest ( seq k -- elt ) [ < ] kth-object-unsafe ;
 132
 133 : kth-largests ( seq kths -- elts ) [ > ] kth-objects-unsafe ;
 134
 135 : kth-largest ( seq k -- elt ) [ > ] kth-object-unsafe ;
 136
 137 : count-relative ( seq k -- lt eq gt )
 138     [ 0 0 0 ] 2dip '[
 139         _ <=> {
 140             { +lt+ [ [ 1 + ] 2dip ] }
 141             { +gt+ [ 1 + ] }
 142             { +eq+ [ [ 1 + ] dip ] }
 143         } case
 144     ] each ;
 145
 146 : minmax-relative ( seq k -- lt eq gt lt-max gt-min )
 147     [ 0 0 0 -1/0. 1/0. ] 2dip '[
 148         dup _ <=> {
 149             { +lt+ [ [ 1 + ] 5 ndip '[ _ max ] dip ] }
 150             { +gt+ [ [ 1 + ] 3dip min ] }
 151             { +eq+ [ [ 1 + ] 4dip drop ] }
 152         } case
 153     ] each ;
 154
 155 : lower-median-index ( seq -- n )
 156     [ midpoint@ ]
 157     [ length odd? [ 1 - ] unless ] bi ;
 158
 159 : lower-median ( seq -- elt )
 160     [ ] [ lower-median-index ] bi kth-smallest ;
 161
 162 : upper-median ( seq -- elt )
 163     dup midpoint@ kth-smallest ;
 164
 165 : medians ( seq -- lower upper )
 166     [ ]
 167     [ [ lower-median-index ] [ midpoint@ ] bi 2array ]
 168     bi kth-smallests first2 ;
 169
 170 : median ( seq -- x )
 171     dup length odd? [ lower-median ] [ medians + 2 / ] if ;
 172
 173 ! quantile can be any n-tile. quartile is n = 4, percentile is n = 100
 174 ! a,b,c,d parameters, N - number of samples, q is quantile (1/2 for median, 1/4 for 1st quartile)
 175 ! http://mathworld.wolfram.com/Quantile.html
 176 ! a + (N + b) q - 1
 177 ! could subtract 1 from a
 178
 179 : quantile-x ( a b N q -- x )
 180     [ + ] dip * + 1 - ; inline
 181
 182 ! 2+1/4 frac is 1/4
 183 : frac ( x -- x' )
 184     >fraction [ /mod nip ] keep / ; inline
 185
 186 :: quantile-indices ( seq qs a b -- seq )
 187     qs [ [ a b seq length ] dip quantile-x ] map ;
 188
 189 :: qabcd ( y-floor y-ceiling x c d -- qabcd )
 190     y-floor y-ceiling y-floor - c d x frac * + * + ;
 191
 192 :: quantile-abcd ( seq qs a b c d -- quantile )
 193     seq qs a b quantile-indices :> indices
 194     indices [ [ floor 0 max ] [ ceiling seq length 1 - min ] bi 2array ] map
 195     concat :> index-pairs
 196
 197     seq index-pairs kth-smallests
 198     2 group indices [ [ first2 ] dip c d qabcd ] 2map ;
 199
 200 : quantile1 ( seq qs -- seq' )
 201     0 0 1 0 quantile-abcd ;
 202
 203 : quantile3 ( seq qs -- seq' )
 204     1/2 0 0 0 quantile-abcd ;
 205
 206 : quantile4 ( seq qs -- seq' )
 207     0 0 0 1 quantile-abcd ;
 208
 209 : quantile5 ( seq qs -- seq' )
 210     1/2 0 0 1 quantile-abcd ;
 211
 212 : quantile6 ( seq qs -- seq' )
 213     0 1 0 1 quantile-abcd ;
 214
 215 : quantile7 ( seq qs -- seq' )
 216     1 -1 0 1 quantile-abcd ;
 217
 218 : quantile8 ( seq qs -- seq' )
 219     1/3 1/3 0 1 quantile-abcd ;
 220
 221 : quantile9 ( seq qs -- seq' )
 222     3/8 1/4 0 1 quantile-abcd ;
 223
 224 : quartile ( seq -- seq' )
 225     { 1/4 1/2 3/4 } quantile5 ;
 226
 227 : interquartile ( seq -- q1 q3 )
 228     quartile [ first ] [ last ] bi ;
 229
 230 : interquartile-range ( seq -- n )
 231     interquartile - ;
 232
 233 : midhinge ( seq -- n )
 234     interquartile + 2 / ;
 235
 236 : trimean ( seq -- x )
 237     quartile first3 [ 2 * ] dip + + 4 / ;
 238
 239 : histogram! ( hashtable seq -- hashtable )
 240     over '[ _ inc-at ] each ;
 241
 242 : histogram-by ( seq quot: ( x -- bin ) -- hashtable )
 243     H{ } clone [ '[ @ _ inc-at ] each ] keep ; inline
 244
 245 : histogram ( seq -- hashtable )
 246     [ ] histogram-by ;
 247
 248 : sorted-histogram ( seq -- alist )
 249     histogram sort-values ;
 250
 251 : normalized-histogram ( seq -- alist )
 252     [ histogram ] [ length ] bi '[ _ / ] assoc-map ;
 253
 254 : equal-probabilities ( n -- array )
 255     dup recip <array> ; inline
 256
 257 : mode ( seq -- x )
 258     histogram >alist [ second ] supremum-by first ;
 259
 260 : minmax ( seq -- min max )
 261     [ first dup ] keep [ [ min ] [ max ] bi-curry bi* ] 1 each-from ;
 262
 263 : range ( seq -- x )
 264     minmax swap - ;
 265
 266 : fivenum ( seq -- seq' )
 267     [ quartile ] [ minmax ] bi [ prefix ] [ suffix ] bi* ;
 268
 269 : var-ddof ( seq n -- x )
 270     2dup [ length ] dip - 0 <= [
 271         2drop 0
 272     ] [
 273         [ [ sum-of-squared-errors ] [ length ] bi ] dip - /
 274     ] if ; inline
 275
 276 : population-var ( seq -- x ) 0 var-ddof ; inline
 277
 278 : sample-var ( seq -- x ) 1 var-ddof ; inline
 279
 280 : std-ddof ( seq n -- x ) var-ddof sqrt ; inline
 281
 282 : population-std ( seq -- x ) 0 std-ddof ; inline
 283
 284 : sample-std ( seq -- x ) 1 std-ddof ; inline
 285
 286 ALIAS: std sample-std
 287
 288 : signal-to-noise ( seq -- x ) [ mean ] [ population-std ] bi / ;
 289
 290 : demean ( seq -- seq' ) dup mean v-n ;
 291
 292 : mean-dev ( seq -- x ) demean vabs mean ;
 293
 294 : demedian ( seq -- seq' ) dup median v-n ;
 295
 296 : median-dev ( seq -- x ) demedian vabs mean ;
 297
 298 : ste-ddof ( seq n -- x ) '[ _ std-ddof ] [ length ] bi sqrt / ;
 299
 300 : population-ste ( seq -- x ) 0 ste-ddof ;
 301
 302 : sample-ste ( seq -- x ) 1 ste-ddof ;
 303
 304 <PRIVATE
 305 : r-sum-diffs ( x-mean y-mean x-seq y-seq -- (r) )
 306     ! finds sigma((xi-mean(x))(yi-mean(y))
 307     0 [ [ reach - ] bi@ * + ] 2reduce 2nip ;
 308
 309 : (r) ( x-mean y-mean x-seq y-seq x-std y-std -- r )
 310     * recip [ [ r-sum-diffs ] keep length 1 - / ] dip * ;
 311
 312 : r-stats ( xy-pairs -- x-mean y-mean x-seq y-seq x-std y-std )
 313     first2 [ [ [ mean ] bi@ ] 2keep ] 2keep [ population-std ] bi@ ;
 314 PRIVATE>
 315
 316 : pearson-r ( xy-pairs -- r ) r-stats (r) ;
 317
 318 : least-squares ( xy-pairs -- alpha beta )
 319     r-stats [ 2dup ] 4dip
 320     ! stack is x-mean y-mean x-mean y-mean x-seq y-seq x-std y-std
 321     [ (r) ] 2keep ! stack is mean(x) mean(y) r sx sy
 322     swap / * ! stack is mean(x) mean(y) beta
 323     [ swapd * - ] keep ;
 324
 325 : cov-ddof ( x-seq y-seq ddof -- cov )
 326     [ [ demean ] bi@ v* ] dip mean-ddof ;
 327
 328 : population-cov ( x-seq y-seq -- cov ) 0 cov-ddof ; inline
 329
 330 : sample-cov ( x-seq y-seq -- cov ) 1 cov-ddof ; inline
 331
 332 : corr-ddof ( x-seq y-seq n -- corr )
 333     [ [ population-cov ] ] dip
 334     '[ [ _ var-ddof ] bi@ * sqrt ] 2bi / ;
 335
 336 : population-corr ( x-seq y-seq -- corr ) 0 corr-ddof ; inline
 337
 338 : sample-corr ( x-seq y-seq -- corr ) 1 corr-ddof ; inline
 339
 340 : cum-sum ( seq -- seq' )
 341     0 [ + ] accumulate* ;
 342
 343 : cum-sum0 ( seq -- seq' )
 344     0 [ + ] accumulate nip ;
 345
 346 : cum-product ( seq -- seq' )
 347     1 [ * ] accumulate* ;
 348
 349 : cum-product1 ( seq -- seq' )
 350     1 [ * ] accumulate nip ;
 351
 352 : cum-mean ( seq -- seq' )
 353     0 swap [ [ + dup ] dip 1 + / ] map-index nip ;
 354
 355 : cum-count ( seq quot: ( elt -- ? ) -- seq' )
 356     [ 0 ] dip '[ @ [ 1 + ] when ] accumulate* ; inline
 357
 358 : cum-min ( seq -- seq' )
 359     dup ?first [ min ] accumulate* ;
 360
 361 : cum-max ( seq -- seq' )
 362     dup ?first [ max ] accumulate* ;
 363
 364 : entropy ( probabilities -- n )
 365     dup sum '[ _ / dup log * ] map-sum neg ;
 366
 367 : maximum-entropy ( probabilities -- n )
 368     length log ;
 369
 370 : normalized-entropy ( probabilities -- n )
 371     [ entropy ] [ maximum-entropy ] bi / ;
 372
 373 : binary-entropy ( p -- h )
 374     [ dup log * ] [ 1 swap - dup log * ] bi + neg 2 log / ;
 375
 376 : standardize ( u -- v )
 377     [ demean ] [ sample-std ] bi [ v/n ] unless-zero ;
 378
 379 : standardize-2d ( u -- v )
 380     flip [ standardize ] map flip ;
 381
 382 : differences ( u -- v )
 383     [ rest-slice ] keep v- ;
 384
 385 : rescale ( u -- v )
 386     dup minmax over - [ v-n ] [ v/n ] bi* ;
 387
 388 : rankings ( histogram -- assoc )
 389     sort-keys 0 swap [ rot [ + ] keep swapd ] H{ } assoc-map-as nip ;
 390
 391 : rank-values ( seq -- seq' )
 392     dup histogram rankings '[ _ at ] map ;
 393
 394 : z-score ( seq -- n )
 395     [ demean ] [ sample-std ] bi v/n ;
 396
 397 : dcg ( scores -- dcg )
 398     dup length 1 + 2 swap [a,b] [ log 2 log /f ] map v/ sum ;
 399
 400 : ndcg ( scores -- ndcg )
 401     [ 0.0 ] [
 402         dup dcg [
 403             drop 0.0
 404         ] [
 405             swap natural-sort <reversed> dcg /f
 406         ] if-zero
 407     ] if-empty ;