basis/math/vectors/conversion/conversion-docs.factor

   1 ! Copyright (C) 2009 Joe Groff.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: classes help.markup help.syntax kernel ;
   4 IN: math.vectors.conversion
   5
   6 HELP: bad-vconvert
   7 { $values
   8     { "from-type" "a SIMD type" } { "to-type" "a SIMD type" }
   9 }
  10 { $description "This error is thrown when " { $link vconvert } " is given two SIMD types it cannot directly convert." } ;
  11
  12 HELP: bad-vconvert-input
  13 { $values
  14     { "value" object } { "expected-type" class }
  15 }
  16 { $description "This error is thrown when an input to " { $link vconvert } " does not match the expected " { $snippet "from-type" } "." } ;
  17
  18 { bad-vconvert bad-vconvert-input } related-words
  19
  20 HELP: vconvert
  21 { $values
  22     { "from-type" "a SIMD type" } { "to-type" "a SIMD type" }
  23 }
  24 { $description "Converts SIMD vectors of " { $snippet "from-type" } " to " { $snippet "to-type" } ". The number of inputs and outputs depends on the relationship of the two types:"
  25 { $list
  26 { "If " { $snippet "to-type" } " is a floating-point vector type with the same byte length and element count as the integer vector type " { $snippet "from-type" } " (for example, from " { $snippet "int-4" } " to " { $snippet "float-4" } " or from " { $snippet "longlong-2" } " to " { $snippet "double-2" } "), " { $snippet "vconvert" } " takes one vector of " { $snippet "from-type" } " and converts its elements to floating-point, outputting one vector of " { $snippet "to-type" } "." }
  27 { "Likewise, if " { $snippet "to-type" } " is an integer vector type with the same byte length and element count as the floating-point vector type " { $snippet "from-type" } ", " { $snippet "vconvert" } " takes one vector of " { $snippet "from-type" } " and truncates its elements to integers, outputting one vector of " { $snippet "to-type" } "." }
  28 { "If " { $snippet "to-type" } " is a vector type with the same byte length as and twice the element count of the vector type " { $snippet "from-type" } " (for example, from " { $snippet "int-4" } " to " { $snippet "ushort-8" } ", from " { $snippet "double-2" } " to " { $snippet "float-4" } ", or from " { $snippet "short-8" } " to " { $snippet "char-16" } "), " { $snippet "vconvert" } " takes two vectors of " { $snippet "from-type" } " and packs them into one vector of " { $snippet "to-type" } ", saturating values too large or small to be representable as elements of " { $snippet "to-type" } "." }
  29 { "If " { $snippet "to-type" } " is a vector type with the same byte length as and half the element count of the vector type " { $snippet "from-type" } " (for example, from " { $snippet "ushort-8" } " to " { $snippet "int-4" } ", from " { $snippet "float-4" } " to " { $snippet "double-2" } ", or from " { $snippet "char-16" } " to " { $snippet "short-8" } "), " { $snippet "vconvert" } " takes one vector of " { $snippet "from-type" } " and unpacks it into two vectors of " { $snippet "to-type" } "." }
  30 }
  31 { $snippet "from-type" } " and " { $snippet "to-type" } " must adhere to the following restrictions; a " { $link bad-vconvert } " error will be thrown otherwise:"
  32 { $list
  33 { { $snippet "from-type" } " and " { $snippet "to-type" } " must have the same byte length. You cannot currently convert between 128- and 256-bit vector types." }
  34 { "For conversions between floating-point and integer vectors, " { $snippet "from-type" } " and " { $snippet "to-type" } " must have the same element length." }
  35 { "For packing conversions, " { $snippet "from-type" } " and " { $snippet "to-type" } " must be both floating-point or both integer types. Integer types can be packed from signed to unsigned or from unsigned to unsigned types. Unsigned to signed packing is invalid." }
  36 { "For unpacking conversions, " { $snippet "from-type" } " and " { $snippet "to-type" } " must be both floating-point or both integer types. Integer types can be unpacked from unsigned to signed or from unsigned to unsigned types. Signed to unsigned unpacking is invalid." }
  37 }
  38 }
  39 { $examples
  40 "Conversion between integer and float vectors:"
  41 { $example "USING: alien.c-types math.vectors.conversion math.vectors.simd
  42 prettyprint ;
  43
  44 int-4{ 0 1 2 3 } int-4 float-4 vconvert .
  45 double-2{ 1.25 3.75 } double-2 longlong-2 vconvert ."
  46 "float-4{ 0.0 1.0 2.0 3.0 }
  47 longlong-2{ 1 3 }" }
  48 "Packing conversions:"
  49 { $example "USING: alien.c-types math.vectors.conversion math.vectors.simd
  50 prettyprint ;
  51
  52 int-4{ -8 70000 6000 50 } int-4{ 4 3 2 -1 } int-4 ushort-8 vconvert .
  53 double-2{ 0.0 1.0e100 }
  54 double-2{ -1.0e100 0.0 } double-2 float-4 vconvert ."
  55 "ushort-8{ 0 65535 6000 50 4 3 2 0 }
  56 float-4{ 0.0 1/0. -1/0. 0.0 }" }
  57 "Unpacking conversions:"
  58 { $example "USING: alien.c-types kernel math.vectors.conversion
  59 math.vectors.simd prettyprint ;
  60
  61 uchar-16{ 8 70 60 50 4 30 200 1 9 10 110 102 133 143 115 0 }
  62 uchar-16 short-8 vconvert [ . ] bi@"
  63 "short-8{ 8 70 60 50 4 30 200 1 }
  64 short-8{ 9 10 110 102 133 143 115 0 }" }
  65 } ;
  66
  67 ARTICLE: "math.vectors.conversion" "SIMD vector conversion"
  68 "The " { $vocab-link "math.vectors.conversion" } " vocabulary provides facilities for converting SIMD vectors between floating-point and integer representations and between different-sized integer representations."
  69 { $subsections
  70     vconvert
  71 } ;
  72
  73 ABOUT: "math.vectors.conversion"