basis/math/vectors/simd/simd-tests.factor

   1 USING: accessors arrays classes compiler compiler.tree.debugger
   2 effects fry io kernel kernel.private math math.functions
   3 math.private math.vectors math.vectors.simd
   4 math.vectors.simd.private prettyprint random sequences system
   5 tools.test vocabs assocs compiler.cfg.debugger words
   6 locals math.vectors.specialization combinators cpu.architecture
   7 math.vectors.conversion.backend
   8 math.vectors.simd.intrinsics namespaces byte-arrays alien
   9 specialized-arrays classes.struct eval classes.algebra sets
  10 quotations math.constants compiler.units ;
  11 QUALIFIED-WITH: alien.c-types c
  12 SPECIALIZED-ARRAY: c:float
  13 SIMD: c:char
  14 SIMDS: c:uchar c:short c:ushort c:int c:uint c:longlong c:ulonglong c:float c:double ;
  15 IN: math.vectors.simd.tests
  16
  17 ! Make sure the functor doesn't generate bogus vocabularies
  18 2 [ [ "USE: math.vectors.simd SIMD: rubinius" eval( -- ) ] must-fail ] times
  19
  20 [ f ] [ "math.vectors.simd.instances.rubinius" vocab ] unit-test
  21
  22 ! Test type propagation
  23 [ V{ float } ] [ [ { float-4 } declare norm-sq ] final-classes ] unit-test
  24
  25 [ V{ float } ] [ [ { float-4 } declare norm ] final-classes ] unit-test
  26
  27 [ V{ float-4 } ] [ [ { float-4 } declare normalize ] final-classes ] unit-test
  28
  29 [ V{ float-4 } ] [ [ { float-4 float-4 } declare v+ ] final-classes ] unit-test
  30
  31 [ V{ float } ] [ [ { float-4 } declare second ] final-classes ] unit-test
  32
  33 [ V{ int-4 } ] [ [ { int-4 int-4 } declare v+ ] final-classes ] unit-test
  34
  35 [ t ] [ [ { int-4 } declare second ] final-classes first integer class<= ] unit-test
  36
  37 [ V{ longlong-2 } ] [ [ { longlong-2 longlong-2 } declare v+ ] final-classes ] unit-test
  38
  39 [ V{ integer } ] [ [ { longlong-2 } declare second ] final-classes ] unit-test
  40
  41 [ V{ int-8 } ] [ [ { int-8 int-8 } declare v+ ] final-classes ] unit-test
  42
  43 [ t ] [ [ { int-8 } declare second ] final-classes first integer class<= ] unit-test
  44
  45 ! Test puns; only on x86
  46 cpu x86? [
  47     [ double-2{ 4 1024 } ] [
  48         float-4{ 0 1 0 2 }
  49         [ { float-4 } declare dup v+ underlying>> double-2 boa dup v+ ] compile-call
  50     ] unit-test
  51
  52     [ 33.0 ] [
  53         double-2{ 1 2 } double-2{ 10 20 }
  54         [ { double-2 double-2 } declare v+ underlying>> 3.0 float* ] compile-call
  55     ] unit-test
  56 ] when
  57
  58 ! Fuzz testing
  59 CONSTANT: simd-classes
  60     {
  61         char-16
  62         uchar-16
  63         char-32
  64         uchar-32
  65         short-8
  66         ushort-8
  67         short-16
  68         ushort-16
  69         int-4
  70         uint-4
  71         int-8
  72         uint-8
  73         longlong-2
  74         ulonglong-2
  75         longlong-4
  76         ulonglong-4
  77         float-4
  78         float-8
  79         double-2
  80         double-4
  81     }
  82
  83 : with-ctors ( -- seq )
  84     simd-classes [ [ name>> "-with" append ] [ vocabulary>> ] bi lookup ] map ;
  85
  86 : boa-ctors ( -- seq )
  87     simd-classes [ [ name>> "-boa" append ] [ vocabulary>> ] bi lookup ] map ;
  88
  89 : check-optimizer ( seq quot eq-quot -- failures )
  90     '[
  91         @
  92         [ dup [ class ] { } map-as ] dip '[ _ declare @ ]
  93         {
  94             [ "print-mr" get [ nip test-mr mr. ] [ 2drop ] if ]
  95             [ "print-checks" get [ [ . ] bi@ ] [ 2drop ] if ]
  96             [ [ call ] dip call ]
  97             [ [ call ] dip compile-call ]
  98         } 2cleave
  99         @ not
 100     ] filter ; inline
 101
 102 "== Checking -new constructors" print
 103
 104 [ { } ] [
 105     simd-classes [ [ [ ] ] dip '[ _ new ] ] [ = ] check-optimizer
 106 ] unit-test
 107
 108 [ { } ] [
 109     simd-classes [ '[ _ new ] compile-call [ zero? ] all? not ] filter
 110 ] unit-test
 111
 112 "== Checking -with constructors" print
 113
 114 [ { } ] [
 115     with-ctors [
 116         [ 1000 random '[ _ ] ] dip '[ _ execute ]
 117     ] [ = ] check-optimizer
 118 ] unit-test
 119
 120 [ HEX: ffffffff ] [ HEX: ffffffff uint-4-with first ] unit-test
 121
 122 [ HEX: ffffffff ] [ HEX: ffffffff [ uint-4-with ] compile-call first ] unit-test
 123
 124 [ HEX: ffffffff ] [ [ HEX: ffffffff uint-4-with ] compile-call first ] unit-test
 125
 126 "== Checking -boa constructors" print
 127
 128 [ { } ] [
 129     boa-ctors [
 130         [ stack-effect in>> length [ 1000 random ] [ ] replicate-as ] keep
 131         '[ _ execute ]
 132     ] [ = ] check-optimizer
 133 ] unit-test
 134
 135 [ HEX: ffffffff ] [ HEX: ffffffff 2 3 4 [ uint-4-boa ] compile-call first ] unit-test
 136
 137 "== Checking vector operations" print
 138
 139 : random-int-vector ( class -- vec )
 140     new [ drop 1,000 random ] map ;
 141 : random-float-vector ( class -- vec )
 142     new [
 143         drop
 144         1000 random
 145         10 swap <array> 0/0. suffix random
 146     ] map ;
 147
 148 : random-vector ( class elt-class -- vec )
 149     float =
 150     [ random-float-vector ]
 151     [ random-int-vector ] if ;
 152
 153 :: check-vector-op ( word inputs class elt-class -- inputs quot )
 154     inputs [
 155         {
 156             { +vector+ [ class elt-class random-vector ] }
 157             { +scalar+ [ 1000 random elt-class float = [ >float ] when ] }
 158         } case
 159     ] [ ] map-as
 160     word '[ _ execute ] ;
 161
 162 : remove-float-words ( alist -- alist' )
 163     { vsqrt n/v v/n v/ normalize } unique assoc-diff ;
 164
 165 : remove-integer-words ( alist -- alist' )
 166     { vlshift vrshift } unique assoc-diff ;
 167
 168 : boolean-ops ( -- words )
 169     { vand vandn vor vxor vnot } ;
 170
 171 : remove-boolean-words ( alist -- alist' )
 172     boolean-ops unique assoc-diff ;
 173
 174 : remove-special-words ( alist -- alist' )
 175     ! These have their own tests later
 176     {
 177         hlshift hrshift vshuffle-bytes vshuffle-elements vbroadcast
 178         vany? vall? vnone?
 179         (v>float) (v>integer)
 180         (vpack-signed) (vpack-unsigned)
 181         (vunpack-head) (vunpack-tail)
 182     } unique assoc-diff ;
 183
 184 : ops-to-check ( elt-class -- alist )
 185     [ vector-words >alist ] dip
 186     float = [ remove-integer-words ] [ remove-float-words ] if
 187     remove-boolean-words
 188     remove-special-words ;
 189
 190 : check-vector-ops ( class elt-class compare-quot -- )
 191     [
 192         [ nip ops-to-check ] 2keep
 193         '[ first2 inputs _ _ check-vector-op ]
 194     ] dip check-optimizer ; inline
 195
 196 : approx= ( x y -- ? )
 197     {
 198         { [ 2dup [ fp-nan? ] both? ] [ 2drop t ] }
 199         { [ 2dup [ float? ] both? ] [ -1.e8 ~ ] }
 200         { [ 2dup [ fp-infinity? ] either? ] [ fp-bitwise= ] }
 201         { [ 2dup [ sequence? ] both? ] [
 202             [
 203                 {
 204                     { [ 2dup [ fp-nan? ] both? ] [ 2drop t ] }
 205                     { [ 2dup [ fp-infinity? ] either? ] [ fp-bitwise= ] }
 206                     { [ 2dup [ fp-nan? ] either? not ] [ -1.e8 ~ ] }
 207                 } cond
 208             ] 2all?
 209         ] }
 210     } cond ;
 211
 212 : exact= ( x y -- ? )
 213     {
 214         { [ 2dup [ float? ] both? ] [ fp-bitwise= ] }
 215         { [ 2dup [ sequence? ] both? ] [ [ fp-bitwise= ] 2all? ] }
 216     } cond ;
 217
 218 : simd-classes&reps ( -- alist )
 219     simd-classes [
 220         {
 221             { [ dup name>> "float" head? ] [ float [ approx= ] ] }
 222             { [ dup name>> "double" head? ] [ float [ exact= ] ] }
 223             [ fixnum [ = ] ]
 224         } cond 3array
 225     ] map ;
 226
 227 simd-classes&reps [
 228     [ [ { } ] ] dip first3 '[ _ _ _ check-vector-ops ] unit-test
 229 ] each
 230
 231 "== Checking boolean operations" print
 232
 233 : random-boolean-vector ( class -- vec )
 234     new [ drop 2 random zero? ] map ;
 235
 236 :: check-boolean-op ( word inputs class elt-class -- inputs quot )
 237     inputs [
 238         {
 239             { +vector+ [ class random-boolean-vector ] }
 240             { +scalar+ [ 1000 random elt-class float = [ >float ] when ] }
 241         } case
 242     ] [ ] map-as
 243     word '[ _ execute ] ;
 244
 245 : check-boolean-ops ( class elt-class compare-quot -- )
 246     [
 247         [ boolean-ops [ dup word-schema ] { } map>assoc ] 2dip
 248         '[ first2 inputs _ _ check-boolean-op ]
 249     ] dip check-optimizer ; inline
 250
 251 simd-classes&reps [
 252     [ [ { } ] ] dip first3 '[ _ _ _ check-boolean-ops ] unit-test
 253 ] each
 254
 255 "== Checking vector blend" print
 256
 257 [ char-16{ 0 1 22 33 4 5 6 77 8 99 110 121 12 143 14 15 } ]
 258 [
 259     char-16{ t  t  f  f  t  t  t  f  t  f   f   f   t   f   t   t }
 260     char-16{ 0  1  2  3  4  5  6  7  8  9  10  11  12  13  14  15 }
 261     char-16{ 0 11 22 33 44 55 66 77 88 99 110 121 132 143 154 165 } v?
 262 ] unit-test
 263
 264 [ char-16{ 0 1 22 33 4 5 6 77 8 99 110 121 12 143 14 15 } ]
 265 [
 266     char-16{ t  t  f  f  t  t  t  f  t  f   f   f   t   f   t   t }
 267     char-16{ 0  1  2  3  4  5  6  7  8  9  10  11  12  13  14  15 }
 268     char-16{ 0 11 22 33 44 55 66 77 88 99 110 121 132 143 154 165 }
 269     [ { char-16 char-16 char-16 } declare v? ] compile-call
 270 ] unit-test
 271
 272 [ int-4{ 1 22 33 4 } ]
 273 [ int-4{ t f f t } int-4{ 1 2 3 4 } int-4{ 11 22 33 44 } v? ] unit-test
 274
 275 [ int-4{ 1 22 33 4 } ]
 276 [
 277     int-4{ t f f t } int-4{ 1 2 3 4 } int-4{ 11 22 33 44 }
 278     [ { int-4 int-4 int-4 } declare v? ] compile-call
 279 ] unit-test
 280
 281 [ float-4{ 1.0 22.0 33.0 4.0 } ]
 282 [ float-4{ t f f t } float-4{ 1.0 2.0 3.0 4.0 } float-4{ 11.0 22.0 33.0 44.0 } v? ] unit-test
 283
 284 [ float-4{ 1.0 22.0 33.0 4.0 } ]
 285 [
 286     float-4{ t f f t } float-4{ 1.0 2.0 3.0 4.0 } float-4{ 11.0 22.0 33.0 44.0 }
 287     [ { float-4 float-4 float-4 } declare v? ] compile-call
 288 ] unit-test
 289
 290 "== Checking shifts and permutations" print
 291
 292 [ int-4{ 256 512 1024 2048 } ]
 293 [ int-4{ 1 2 4 8 } 1 hlshift ] unit-test
 294
 295 [ int-4{ 256 512 1024 2048 } ]
 296 [ int-4{ 1 2 4 8 } [ { int-4 } declare 1 hlshift ] compile-call ] unit-test
 297
 298 [ int-4{ 256 512 1024 2048 } ]
 299 [ int-4{ 1 2 4 8 } 1 [ { int-4 fixnum } declare hlshift ] compile-call ] unit-test
 300
 301 [ int-4{ 1 2 4 8 } ]
 302 [ int-4{ 256 512 1024 2048 } 1 hrshift ] unit-test
 303
 304 [ int-4{ 1 2 4 8 } ]
 305 [ int-4{ 256 512 1024 2048 } [ { int-4 } declare 1 hrshift ] compile-call ] unit-test
 306
 307 [ int-4{ 1 2 4 8 } ]
 308 [ int-4{ 256 512 1024 2048 } 1 [ { int-4 fixnum } declare hrshift ] compile-call ] unit-test
 309
 310 ! Invalid inputs should not cause the compiler to throw errors
 311 [ ] [
 312     [ [ { int-4 } declare t hrshift ] (( a -- b )) define-temp drop ] with-compilation-unit
 313 ] unit-test
 314
 315 [ ] [
 316     [ [ { int-4 } declare { 3 2 1 } vshuffle ] (( a -- b )) define-temp drop ] with-compilation-unit
 317 ] unit-test
 318
 319 ! Shuffles
 320 : shuffles-for ( n -- shuffles )
 321     {
 322         { 2 [
 323             {
 324                 { 0 1 }
 325                 { 1 1 }
 326                 { 1 0 }
 327                 { 0 0 }
 328             }
 329         ] }
 330         { 4 [
 331             {
 332                 { 1 2 3 0 }
 333                 { 0 1 2 3 }
 334                 { 1 1 2 2 }
 335                 { 0 0 1 1 }
 336                 { 2 2 3 3 }
 337                 { 0 1 0 1 }
 338                 { 2 3 2 3 }
 339                 { 0 0 2 2 }
 340                 { 1 1 3 3 }
 341                 { 0 1 0 1 }
 342                 { 2 2 3 3 }
 343             }
 344         ] }
 345         { 8 [
 346             4 shuffles-for
 347             4 shuffles-for
 348             [ [ 4 + ] map ] map
 349             [ append ] 2map
 350         ] }
 351         [ dup '[ _ random ] replicate 1array ]
 352     } case ;
 353
 354 simd-classes [
 355     [ [ { } ] ] dip
 356     [ new length shuffles-for ] keep
 357     '[
 358         _ [ [ _ new [ length iota ] keep like 1quotation ] dip '[ _ vshuffle ] ]
 359         [ = ] check-optimizer
 360     ] unit-test
 361 ] each
 362
 363 "== Checking variable shuffles" print
 364
 365 : random-shift-vector ( class -- vec )
 366     new [ drop 16 random ] map ;
 367
 368 :: test-shift-vector ( class -- ? )
 369     class random-int-vector :> src
 370     char-16 random-shift-vector :> perm
 371     { class char-16 } :> decl
 372
 373     src perm vshuffle
 374     src perm [ decl declare vshuffle ] compile-call
 375     = ; inline
 376
 377 { char-16 uchar-16 short-8 ushort-8 int-4 uint-4 longlong-2 ulonglong-2 }
 378 [ 10 swap '[ [ t ] [ _ test-shift-vector ] unit-test ] times ] each
 379
 380 "== Checking vector tests" print
 381
 382 :: test-vector-tests-bool ( vector declaration -- none? any? all? )
 383     vector
 384     [ [ declaration declare vnone? ] compile-call ]
 385     [ [ declaration declare vany?  ] compile-call ]
 386     [ [ declaration declare vall?  ] compile-call ] tri ; inline
 387
 388 : yes ( -- x ) t ;
 389 : no ( -- x ) f ;
 390
 391 :: test-vector-tests-branch ( vector declaration -- none? any? all? )
 392     vector
 393     [ [ declaration declare vnone? [ yes ] [ no ] if ] compile-call ]
 394     [ [ declaration declare vany?  [ yes ] [ no ] if ] compile-call ]
 395     [ [ declaration declare vall?  [ yes ] [ no ] if ] compile-call ] tri ; inline
 396
 397 TUPLE: inconsistent-vector-test bool branch ;
 398
 399 : ?inconsistent ( bool branch -- ?/inconsistent )
 400     2dup = [ drop ] [ inconsistent-vector-test boa ] if ;
 401
 402 :: test-vector-tests ( vector decl -- none? any? all? )
 403     vector decl test-vector-tests-bool :> bool-all :> bool-any :> bool-none
 404     vector decl test-vector-tests-branch :> branch-all :> branch-any :> branch-none
 405
 406     bool-none branch-none ?inconsistent
 407     bool-any  branch-any  ?inconsistent
 408     bool-all  branch-all  ?inconsistent ; inline
 409
 410 [ f t t ]
 411 [ float-4{ t t t t } { float-4 } test-vector-tests ] unit-test
 412 [ f t f ]
 413 [ float-4{ f t t t } { float-4 } test-vector-tests ] unit-test
 414 [ t f f ]
 415 [ float-4{ f f f f } { float-4 } test-vector-tests ] unit-test
 416
 417 [ f t t ]
 418 [ double-2{ t t } { double-2 } test-vector-tests ] unit-test
 419 [ f t f ]
 420 [ double-2{ f t } { double-2 } test-vector-tests ] unit-test
 421 [ t f f ]
 422 [ double-2{ f f } { double-2 } test-vector-tests ] unit-test
 423
 424 [ f t t ]
 425 [ int-4{ t t t t } { int-4 } test-vector-tests ] unit-test
 426 [ f t f ]
 427 [ int-4{ f t t t } { int-4 } test-vector-tests ] unit-test
 428 [ t f f ]
 429 [ int-4{ f f f f } { int-4 } test-vector-tests ] unit-test
 430
 431 [ f t t ]
 432 [ float-8{ t t t t t t t t } { float-8 } test-vector-tests ] unit-test
 433 [ f t f ]
 434 [ float-8{ f t t t t f t t } { float-8 } test-vector-tests ] unit-test
 435 [ t f f ]
 436 [ float-8{ f f f f f f f f } { float-8 } test-vector-tests ] unit-test
 437
 438 [ f t t ]
 439 [ double-4{ t t t t } { double-4 } test-vector-tests ] unit-test
 440 [ f t f ]
 441 [ double-4{ f t t f } { double-4 } test-vector-tests ] unit-test
 442 [ t f f ]
 443 [ double-4{ f f f f } { double-4 } test-vector-tests ] unit-test
 444
 445 [ f t t ]
 446 [ int-8{ t t t t t t t t } { int-8 } test-vector-tests ] unit-test
 447 [ f t f ]
 448 [ int-8{ f t t t t f f f } { int-8 } test-vector-tests ] unit-test
 449 [ t f f ]
 450 [ int-8{ f f f f f f f f } { int-8 } test-vector-tests ] unit-test
 451
 452 "== Checking element access" print
 453
 454 ! Test element access -- it should box bignums for int-4 on x86
 455 : test-accesses ( seq -- failures )
 456     [ length >array ] keep
 457     '[ [ _ 1quotation ] dip '[ _ swap nth ] ] [ = ] check-optimizer ; inline
 458
 459 [ { } ] [ float-4{ 1.0 2.0 3.0 4.0 } test-accesses ] unit-test
 460 [ { } ] [ int-4{ HEX: 7fffffff 3 4 -8 } test-accesses ] unit-test
 461 [ { } ] [ uint-4{ HEX: ffffffff 2 3 4 } test-accesses ] unit-test
 462
 463 [ HEX: 7fffffff ] [ int-4{ HEX: 7fffffff 3 4 -8 } first ] unit-test
 464 [ -8 ] [ int-4{ HEX: 7fffffff 3 4 -8 } last ] unit-test
 465 [ HEX: ffffffff ] [ uint-4{ HEX: ffffffff 2 3 4 } first ] unit-test
 466
 467 [ { } ] [ double-2{ 1.0 2.0 } test-accesses ] unit-test
 468 [ { } ] [ longlong-2{ 1 2 } test-accesses ] unit-test
 469 [ { } ] [ ulonglong-2{ 1 2 } test-accesses ] unit-test
 470
 471 [ { } ] [ float-8{ 1.0 2.0 3.0 4.0 5.0 6.0 7.0 8.0 } test-accesses ] unit-test
 472 [ { } ] [ int-8{ 1 2 3 4 5 6 7 8 } test-accesses ] unit-test
 473 [ { } ] [ uint-8{ 1 2 3 4 5 6 7 8 } test-accesses ] unit-test
 474
 475 [ { } ] [ double-4{ 1.0 2.0 3.0 4.0 } test-accesses ] unit-test
 476 [ { } ] [ longlong-4{ 1 2 3 4 } test-accesses ] unit-test
 477 [ { } ] [ ulonglong-4{ 1 2 3 4 } test-accesses ] unit-test
 478
 479 "== Checking broadcast" print
 480 : test-broadcast ( seq -- failures )
 481     [ length >array ] keep
 482     '[ [ _ 1quotation ] dip '[ _ vbroadcast ] ] [ = ] check-optimizer ; inline
 483
 484 [ { } ] [ float-4{ 1.0 2.0 3.0 4.0 } test-broadcast ] unit-test
 485 [ { } ] [ int-4{ HEX: 7fffffff 3 4 -8 } test-broadcast ] unit-test
 486 [ { } ] [ uint-4{ HEX: ffffffff 2 3 4 } test-broadcast ] unit-test
 487
 488 [ { } ] [ double-2{ 1.0 2.0 } test-broadcast ] unit-test
 489 [ { } ] [ longlong-2{ 1 2 } test-broadcast ] unit-test
 490 [ { } ] [ ulonglong-2{ 1 2 } test-broadcast ] unit-test
 491
 492 [ { } ] [ float-8{ 1.0 2.0 3.0 4.0 5.0 6.0 7.0 8.0 } test-broadcast ] unit-test
 493 [ { } ] [ int-8{ 1 2 3 4 5 6 7 8 } test-broadcast ] unit-test
 494 [ { } ] [ uint-8{ 1 2 3 4 5 6 7 8 } test-broadcast ] unit-test
 495
 496 [ { } ] [ double-4{ 1.0 2.0 3.0 4.0 } test-broadcast ] unit-test
 497 [ { } ] [ longlong-4{ 1 2 3 4 } test-broadcast ] unit-test
 498 [ { } ] [ ulonglong-4{ 1 2 3 4 } test-broadcast ] unit-test
 499
 500 ! Make sure we use the fallback in the correct situations
 501 [ int-4{ 3 3 3 3 } ] [ int-4{ 12 34 3 17 } 2 [ { int-4 fixnum } declare vbroadcast ] compile-call ] unit-test
 502
 503 "== Checking alien operations" print
 504
 505 [ float-4{ 1 2 3 4 } ] [
 506     [
 507         float-4{ 1 2 3 4 }
 508         underlying>> 0 float-4-rep alien-vector
 509     ] compile-call float-4 boa
 510 ] unit-test
 511
 512 [ B{ 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 } ] [
 513     16 [ 1 ] B{ } replicate-as 16 <byte-array>
 514     [
 515         0 [
 516             { byte-array c-ptr fixnum } declare
 517             float-4-rep set-alien-vector
 518         ] compile-call
 519     ] keep
 520 ] unit-test
 521
 522 [ float-array{ 1 2 3 4 } ] [
 523     [
 524         float-array{ 1 2 3 4 } underlying>>
 525         float-array{ 4 3 2 1 } clone
 526         [ underlying>> 0 float-4-rep set-alien-vector ] keep
 527     ] compile-call
 528 ] unit-test
 529
 530 STRUCT: simd-struct
 531 { x float-4 }
 532 { y longlong-2 }
 533 { z double-4 }
 534 { w int-8 } ;
 535
 536 [ t ] [ [ simd-struct <struct> ] compile-call >c-ptr [ 0 = ] all? ] unit-test
 537
 538 [
 539     float-4{ 1 2 3 4 }
 540     longlong-2{ 2 1 }
 541     double-4{ 4 3 2 1 }
 542     int-8{ 1 2 3 4 5 6 7 8 }
 543 ] [
 544     simd-struct <struct>
 545     float-4{ 1 2 3 4 } >>x
 546     longlong-2{ 2 1 } >>y
 547     double-4{ 4 3 2 1 } >>z
 548     int-8{ 1 2 3 4 5 6 7 8 } >>w
 549     { [ x>> ] [ y>> ] [ z>> ] [ w>> ] } cleave
 550 ] unit-test
 551
 552 [
 553     float-4{ 1 2 3 4 }
 554     longlong-2{ 2 1 }
 555     double-4{ 4 3 2 1 }
 556     int-8{ 1 2 3 4 5 6 7 8 }
 557 ] [
 558     [
 559         simd-struct <struct>
 560         float-4{ 1 2 3 4 } >>x
 561         longlong-2{ 2 1 } >>y
 562         double-4{ 4 3 2 1 } >>z
 563         int-8{ 1 2 3 4 5 6 7 8 } >>w
 564         { [ x>> ] [ y>> ] [ z>> ] [ w>> ] } cleave
 565     ] compile-call
 566 ] unit-test
 567
 568 "== Misc tests" print
 569
 570 [ ] [ char-16 new 1array stack. ] unit-test
 571
 572 ! CSSA bug
 573 [ 8000000 ] [
 574     int-8{ 1000 1000 1000 1000 1000 1000 1000 1000 }
 575     [ { int-8 } declare dup [ * ] [ + ] 2map-reduce ] compile-call
 576 ] unit-test
 577
 578 ! Coalescing was too aggressive
 579 :: broken ( axis theta -- a b c )
 580    axis { float-4 } declare drop
 581    theta { float } declare drop
 582
 583    theta cos float-4-with :> cc
 584    theta sin float-4-with :> ss
 585
 586    axis cc v+ :> diagonal
 587
 588    diagonal cc ss ; inline
 589
 590 [ t ] [
 591     float-4{ 1.0 0.0 1.0 0.0 } pi [ broken 3array ]
 592     [ compile-call ] [ call ] 3bi =
 593 ] unit-test