basis/math/vectors/vectors-docs.factor

   1 USING: help.markup help.syntax math math.functions sequences ;
   2 IN: math.vectors
   3
   4 ARTICLE: "math-vectors" "Vector arithmetic"
   5 "Any Factor sequence can be used to represent a mathematical vector, however for best performance, the sequences defined by the " { $vocab-link "specialized-arrays" } " and " { $vocab-link "math.vectors.simd" } " vocabularies should be used."
   6 $nl
   7 "Acting on vectors by a scalar:"
   8 { $subsection vneg }
   9 { $subsection v*n }
  10 { $subsection n*v }
  11 { $subsection v/n }
  12 { $subsection n/v }
  13 { $subsection v+n }
  14 { $subsection n+v }
  15 { $subsection v-n }
  16 { $subsection n-v }
  17 "Vector unary operations:"
  18 { $subsection vneg }
  19 { $subsection vabs }
  20 { $subsection vsqrt }
  21 { $subsection vfloor }
  22 { $subsection vceiling }
  23 { $subsection vtruncate }
  24 "Vector/vector binary operations:"
  25 { $subsection v+ }
  26 { $subsection v- }
  27 { $subsection v+- }
  28 { $subsection v* }
  29 { $subsection v/ }
  30 "Saturated arithmetic (only on " { $link "specialized-arrays" } "):"
  31 { $subsection vs+ }
  32 { $subsection vs- }
  33 { $subsection vs* }
  34 "Comparisons:"
  35 { $subsection vmax }
  36 { $subsection vmin }
  37 "Bitwise operations:"
  38 { $subsection vbitand }
  39 { $subsection vbitor }
  40 { $subsection vbitxor }
  41 "Inner product and norm:"
  42 { $subsection v. }
  43 { $subsection norm }
  44 { $subsection norm-sq }
  45 { $subsection normalize }
  46 "Comparing vectors:"
  47 { $subsection distance }
  48 { $subsection v~ }
  49 "Other functions:"
  50 { $subsection vsupremum }
  51 { $subsection vinfimum }
  52 { $subsection trilerp }
  53 { $subsection bilerp }
  54 { $subsection vlerp }
  55 { $subsection vnlerp }
  56 { $subsection vbilerp } ;
  57
  58 ABOUT: "math-vectors"
  59
  60 HELP: vneg
  61 { $values { "u" "a sequence of numbers" } { "v" "a sequence of numbers" } }
  62 { $description "Negates each element of " { $snippet "u" } "." } ;
  63
  64 HELP: vabs
  65 { $values { "u" "a sequence of numbers" } { "v" "a sequence of non-negative real numbers" } }
  66 { $description "Takes the absolute value of each element of " { $snippet "u" } "." } ;
  67
  68 HELP: vsqrt
  69 { $values { "u" "a sequence of non-negative real numbers" } { "v" "a sequence of non-negative real numbers" } }
  70 { $description "Takes the square root of each element of " { $snippet "u" } "." }
  71 { $warning "For performance reasons, this does not work with negative inputs, unlike " { $link sqrt } "." } ;
  72
  73 HELP: vfloor
  74 { $values { "u" "a sequence of real numbers" } { "v" "a sequence of real numbers" } }
  75 { $description "Takes the " { $link floor } " of each element of " { $snippet "u" } "." } ;
  76
  77 HELP: vceiling
  78 { $values { "u" "a sequence of real numbers" } { "v" "a sequence of real numbers" } }
  79 { $description "Takes the " { $link ceiling } " of each element of " { $snippet "u" } "." } ;
  80
  81 HELP: vtruncate
  82 { $values { "u" "a sequence of real numbers" } { "v" "a sequence of real numbers" } }
  83 { $description "Truncates each element of " { $snippet "u" } "." } ;
  84
  85 HELP: n+v
  86 { $values { "n" "a number" } { "u" "a sequence of numbers" } { "v" "a sequence of numbers" } }
  87 { $description "Adds " { $snippet "n" } " to each element of " { $snippet "u" } "." } ;
  88
  89 HELP: v+n
  90 { $values { "u" "a sequence of numbers" } { "n" "a number" } { "v" "a sequence of numbers" } }
  91 { $description "Adds " { $snippet "n" } " to each element of " { $snippet "u" } "." } ;
  92
  93 HELP: n-v
  94 { $values { "n" "a number" } { "u" "a sequence of numbers" } { "v" "a sequence of numbers" } }
  95 { $description "Subtracts each element of " { $snippet "u" } " from " { $snippet "n" } "." } ;
  96
  97 HELP: v-n
  98 { $values { "u" "a sequence of numbers" } { "n" "a number" } { "v" "a sequence of numbers" } }
  99 { $description "Subtracts " { $snippet "n" } " from each element of " { $snippet "u" } "." } ;
 100
 101 HELP: n*v
 102 { $values { "n" "a number" } { "u" "a sequence of numbers" } { "v" "a sequence of numbers" } }
 103 { $description "Multiplies each element of " { $snippet "u" } " by " { $snippet "n" } "." } ;
 104
 105 HELP: v*n
 106 { $values { "u" "a sequence of numbers" } { "n" "a number" } { "v" "a sequence of numbers" } }
 107 { $description "Multiplies each element of " { $snippet "u" } " by " { $snippet "n" } "." } ;
 108
 109 HELP: n/v
 110 { $values { "n" "a number" } { "u" "a sequence of numbers" } { "v" "a sequence of numbers" } }
 111 { $description "Divides " { $snippet "n" } " by each element of " { $snippet "u" } "." }
 112 { $errors "May throw an error if a division by zero occurs; see " { $link "division-by-zero" } "." } ;
 113
 114 HELP: v/n
 115 { $values { "u" "a sequence of numbers" } { "n" "a number" } { "v" "a sequence of numbers" } }
 116 { $description "Divides each element of " { $snippet "u" } " by " { $snippet "n" } "." }
 117 { $errors "May throw an error if a division by zero occurs; see " { $link "division-by-zero" } "." } ;
 118
 119 HELP: v+
 120 { $values { "u" "a sequence of numbers" } { "v" "a sequence of numbers" } { "w" "a sequence of numbers" } }
 121 { $description "Adds " { $snippet "u" } " and " { $snippet "v" } " component-wise." } ;
 122
 123 HELP: v-
 124 { $values { "u" "a sequence of numbers" } { "v" "a sequence of numbers" } { "w" "a sequence of numbers" } }
 125 { $description "Subtracts " { $snippet "v" } " from " { $snippet "u" } " component-wise." } ;
 126
 127 HELP: v+-
 128 { $values { "u" "a sequence of numbers" } { "v" "a sequence of numbers" } { "w" "a sequence of numbers" } }
 129 { $description "Adds and subtracts alternate elements of " { $snippet "v" } " and " { $snippet "u" } " component-wise." }
 130 { $examples
 131     { $example
 132         "USING: math.vectors prettyprint ;"
 133         "{ 1 2 3 } { 2 3 2 } v+- ."
 134         "{ -1 5 1 }"
 135     }
 136 } ;
 137
 138 HELP: [v-]
 139 { $values { "u" "a sequence of real numbers" } { "v" "a sequence of real numbers" } { "w" "a sequence of real numbers" } }
 140 { $description "Subtracts " { $snippet "v" } " from " { $snippet "u" } " component-wise; any components which become negative are set to zero." } ;
 141
 142 HELP: v*
 143 { $values { "u" "a sequence of numbers" } { "v" "a sequence of numbers" } { "w" "a sequence of numbers" } }
 144 { $description "Multiplies " { $snippet "u" } " and " { $snippet "v" } " component-wise." } ;
 145
 146 HELP: v/
 147 { $values { "u" "a sequence of numbers" } { "v" "a sequence of numbers" } { "w" "a sequence of numbers" } }
 148 { $description "Divides " { $snippet "u" } " by " { $snippet "v" } " component-wise." }
 149 { $errors "May throw an error if a division by zero occurs; see " { $link "division-by-zero" } "." } ;
 150
 151 HELP: vmax
 152 { $values { "u" "a sequence of real numbers" } { "v" "a sequence of real numbers" } { "w" "a sequence of real numbers" } }
 153 { $description "Creates a sequence where each element is the maximum of the corresponding elements from " { $snippet "u" } " andd " { $snippet "v" } "." }
 154 { $examples { $example "USING: math.vectors prettyprint ;" "{ 1 2 5 } { -7 6 3 } vmax ." "{ 1 6 5 }" } } ;
 155
 156 HELP: vmin
 157 { $values { "u" "a sequence of real numbers" } { "v" "a sequence of real numbers" } { "w" "a sequence of real numbers" } }
 158 { $description "Creates a sequence where each element is the minimum of the corresponding elements from " { $snippet "u" } " andd " { $snippet "v" } "." }
 159 { $examples { $example "USING: math.vectors prettyprint ;" "{ 1 2 5 } { -7 6 3 } vmin ." "{ -7 2 3 }" } } ;
 160
 161 HELP: v.
 162 { $values { "u" "a sequence of real numbers" } { "v" "a sequence of real numbers" } { "x" "a real number" } }
 163 { $description "Computes the real-valued dot product." }
 164 { $notes
 165     "This word can also take complex number sequences as input, however mathematically it will compute the wrong result. The complex-valued dot product is defined differently:"
 166     { $code "0 [ conjugate * + ] 2reduce" }
 167 } ;
 168
 169 HELP: vs+
 170 { $values { "u" "a sequence of numbers" } { "v" "a sequence of numbers" } { "w" "a sequence of numbers" } }
 171 { $description "Adds " { $snippet "u" } " and " { $snippet "v" } " component-wise with saturation." }
 172 { $examples
 173     "With saturation:"
 174     { $example
 175         "USING: math.vectors prettyprint specialized-arrays ;"
 176         "SPECIALIZED-ARRAY: uchar"
 177         "uchar-array{ 100 200 150 } uchar-array{ 70 70 70 } vs+ ."
 178         "uchar-array{ 170 255 220 }"
 179     }
 180     "Without saturation:"
 181     { $example
 182         "USING: math.vectors prettyprint specialized-arrays ;"
 183         "SPECIALIZED-ARRAY: uchar"
 184         "uchar-array{ 100 200 150 } uchar-array{ 70 70 70 } v+ ."
 185         "uchar-array{ 170 14 220 }"
 186     }
 187 } ;
 188
 189 HELP: vs-
 190 { $values { "u" "a sequence of numbers" } { "v" "a sequence of numbers" } { "w" "a sequence of numbers" } }
 191 { $description "Subtracts " { $snippet "v" } " from " { $snippet "u" } " component-wise with saturation." } ;
 192
 193 HELP: vs*
 194 { $values { "u" "a sequence of numbers" } { "v" "a sequence of numbers" } { "w" "a sequence of numbers" } }
 195 { $description "Multiplies " { $snippet "u" } " and " { $snippet "v" } " component-wise with saturation." } ;
 196
 197 HELP: vbitand
 198 { $values { "u" "a sequence of real numbers" } { "v" "a sequence of real numbers" } { "w" "a sequence of real numbers" } }
 199 { $description "Takes the bitwise and of " { $snippet "u" } " and " { $snippet "v" } " component-wise." }
 200 { $notes "Unlike " { $link bitand } ", this word may be used on a specialized array of floats or doubles, in which case the bitwise representation of the floating point numbers is operated upon." } ;
 201
 202 HELP: vbitor
 203 { $values { "u" "a sequence of real numbers" } { "v" "a sequence of real numbers" } { "w" "a sequence of real numbers" } }
 204 { $description "Takes the bitwise or of " { $snippet "u" } " and " { $snippet "v" } " component-wise." }
 205 { $notes "Unlike " { $link bitor } ", this word may be used on a specialized array of floats or doubles, in which case the bitwise representation of the floating point numbers is operated upon." } ;
 206
 207 HELP: vbitxor
 208 { $values { "u" "a sequence of real numbers" } { "v" "a sequence of real numbers" } { "w" "a sequence of real numbers" } }
 209 { $description "Takes the bitwise exclusive or of " { $snippet "u" } " and " { $snippet "v" } " component-wise." }
 210 { $notes "Unlike " { $link bitxor } ", this word may be used on a specialized array of floats or doubles, in which case the bitwise representation of the floating point numbers is operated upon." } ;
 211
 212 HELP: norm-sq
 213 { $values { "v" "a sequence of numbers" } { "x" "a non-negative real number" } }
 214 { $description "Computes the squared length of a mathematical vector." } ;
 215
 216 HELP: norm
 217 { $values { "v" "a sequence of numbers" } { "x" "a non-negative real number" } }
 218 { $description "Computes the length of a mathematical vector." } ;
 219
 220 HELP: normalize
 221 { $values { "u" "a sequence of numbers, not all zero" } { "v" "a sequence of numbers" } }
 222 { $description "Outputs a vector with the same direction as " { $snippet "u" } " but length 1." } ;
 223
 224 HELP: distance
 225 { $values { "u" "a sequence of numbers" } { "v" "a sequence of numbers" } { "x" "a non-negative real number" } }
 226 { $description "Outputs the Euclidean distance between two vectors." } ;
 227
 228 HELP: set-axis
 229 { $values { "u" "a sequence of numbers" } { "v" "a sequence of numbers" } { "axis" "a sequence of 0/1" } { "w" "a sequence of numbers" } }
 230 { $description "Using " { $snippet "w" } " as a template, creates a new sequence containing corresponding elements from " { $snippet "u" } " in place of 0, and corresponding elements from " { $snippet "v" } " in place of 1." }
 231 { $examples { $example "USING: math.vectors prettyprint ;" "{ 1 2 3 } { 4 5 6 } { 0 1 0 } set-axis ." "{ 1 5 3 }" } } ;
 232
 233 { 2map v+ v- v* v/ } related-words
 234
 235 { 2reduce v. } related-words
 236
 237 { vs+ vs- vs* } related-words