basis/mirrors/mirrors.factor

   1 ! Copyright (C) 2007, 2008 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: assocs hashtables kernel sequences generic words
   4 arrays classes slots slots.private classes.tuple
   5 classes.tuple.private math vectors quotations accessors
   6 combinators ;
   7 IN: mirrors
   8
   9 TUPLE: mirror { object read-only } ;
  10
  11 C: <mirror> mirror
  12
  13 : object-slots ( mirror -- slots ) object>> class all-slots ; inline
  14
  15 M: mirror at*
  16     [ nip object>> ] [ object-slots slot-named ] 2bi
  17     dup [ offset>> slot t ] [ 2drop f f ] if ;
  18
  19 ERROR: no-such-slot slot ;
  20 ERROR: read-only-slot slot ;
  21
  22 : check-set-slot ( val slot -- val offset )
  23     {
  24         { [ dup not ] [ no-such-slot ] }
  25         { [ dup read-only>> ] [ read-only-slot ] }
  26         { [ 2dup class>> instance? not ] [ class>> bad-slot-value ] }
  27         [ offset>> ]
  28     } cond ; inline
  29
  30 M: mirror set-at ( val key mirror -- )
  31     [ object-slots slot-named check-set-slot ] [ object>> ] bi
  32     swap set-slot ;
  33
  34 M: mirror delete-at ( key mirror -- )
  35     f -rot set-at ;
  36
  37 M: mirror clear-assoc ( mirror -- )
  38     [ object>> ] [ object-slots ] bi [
  39         [ initial>> ] [ offset>> ] bi swapd set-slot
  40     ] with each ;
  41
  42 M: mirror >alist ( mirror -- alist )
  43     [ object-slots [ [ name>> ] map ] [ [ offset>> ] map ] bi ]
  44     [ object>> [ swap slot ] curry ] bi
  45     map zip ;
  46
  47 M: mirror assoc-size object>> layout-of size>> ;
  48
  49 INSTANCE: mirror assoc
  50
  51 GENERIC: make-mirror ( obj -- assoc )
  52 M: hashtable make-mirror ;
  53 M: integer make-mirror drop f ;
  54 M: array make-mirror <enum> ;
  55 M: vector make-mirror <enum> ;
  56 M: quotation make-mirror <enum> ;
  57 M: object make-mirror <mirror> ;