basis/models/models.factor

   1 ! Copyright (C) 2006, 2008 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors continuations kernel math math.order sequences ;
   4 IN: models
   5
   6 TUPLE: model < identity-tuple
   7 value connections dependencies ref locked? ;
   8
   9 : new-model ( value class -- model )
  10     new
  11         swap >>value
  12         V{ } clone >>connections
  13         V{ } clone >>dependencies
  14         0 >>ref ; inline
  15
  16 : <model> ( value -- model )
  17     model new-model ;
  18
  19 : add-dependency ( dep model -- )
  20     dependencies>> push ;
  21
  22 : remove-dependency ( dep model -- )
  23     dependencies>> remove! drop ;
  24
  25 DEFER: add-connection
  26
  27 GENERIC: model-activated ( model -- )
  28
  29 M: model model-activated drop ;
  30
  31 : ref-model ( model -- n )
  32     [ 1 + dup ] change-ref drop ;
  33
  34 : unref-model ( model -- n )
  35     [ 1 - dup ] change-ref drop ;
  36
  37 : activate-model ( model -- )
  38     dup ref-model 1 = [
  39         dup dependencies>>
  40         [ dup activate-model dupd add-connection ] each
  41         model-activated
  42     ] [
  43         drop
  44     ] if ;
  45
  46 DEFER: remove-connection
  47
  48 : deactivate-model ( model -- )
  49     dup unref-model zero? [
  50         dup dependencies>>
  51         [ dup deactivate-model remove-connection ] with each
  52     ] [
  53         drop
  54     ] if ;
  55
  56 : compute-model ( model -- value )
  57     [ activate-model ] [ deactivate-model ] [ value>> ] tri ;
  58
  59 GENERIC: model-changed ( model observer -- )
  60
  61 : add-connection ( observer model -- )
  62     dup connections>>
  63     [ empty? [ activate-model ] [ drop ] if ]
  64     [ push ] bi ;
  65
  66 : remove-connection ( observer model -- )
  67     [ connections>> remove! ] keep swap
  68     empty? [ deactivate-model ] [ drop ] if ;
  69
  70 : with-locked-model ( model quot -- )
  71     [ '[ _ t >>locked? @ ] ]
  72     [ drop '[ f _ locked?<< ] ]
  73     2bi finally ; inline
  74
  75 GENERIC: update-model ( model -- )
  76
  77 M: model update-model drop ;
  78
  79 : notify-connections ( model -- )
  80     dup connections>> [ model-changed ] with each ;
  81
  82 : set-model ( value model -- )
  83     dup locked?>> [
  84         2drop
  85     ] [
  86         [
  87             swap >>value
  88             [ update-model ] [ notify-connections ] bi
  89         ] with-locked-model
  90     ] if ;
  91
  92 : ?set-model ( value model -- )
  93     2dup value>> = [ 2drop ] [ set-model ] if ;
  94
  95 : call-change-model ( model quot -- newvalue model )
  96     over [ [ value>> ] dip call ] dip ; inline
  97
  98 : change-model ( ..a model quot: ( ..a obj -- ..b newobj ) -- ..b )
  99     call-change-model set-model ; inline
 100
 101 : (change-model) ( ..a model quot: ( ..a obj -- ..b newobj ) -- ..b )
 102     call-change-model value<< ; inline
 103
 104 GENERIC: range-value ( model -- value )
 105 GENERIC: range-page-value ( model -- value )
 106 GENERIC: range-min-value ( model -- value )
 107 GENERIC: range-max-value ( model -- value )
 108 GENERIC: range-max-value* ( model -- value )
 109 GENERIC: set-range-value ( value model -- )
 110 GENERIC: set-range-page-value ( value model -- )
 111 GENERIC: set-range-min-value ( value model -- )
 112 GENERIC: set-range-max-value ( value model -- )
 113
 114 : clamp-value ( value range -- newvalue )
 115     [ range-min-value ] [ range-max-value* ] bi clamp ;
 116
 117 : change-model* ( ..a model quot: ( ..a obj -- ..b ) -- ..b )
 118     '[ _ keep ] change-model ; inline
 119
 120 : push-model ( value model -- )
 121     [ push ] change-model* ;
 122
 123 : pop-model ( model -- value )
 124     [ pop ] change-model* ;