basis/multiline/multiline.factor

   1 ! Copyright (C) 2007 Daniel Ehrenberg
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: namespaces make parser lexer kernel sequences words
   4 quotations math accessors locals ;
   5 IN: multiline
   6
   7 ERROR: bad-heredoc identifier ;
   8
   9 <PRIVATE
  10 : next-line-text ( -- str )
  11     lexer get dup next-line line-text>> ;
  12
  13 : (parse-here) ( -- )
  14     next-line-text [
  15         dup ";" =
  16         [ drop lexer get next-line ]
  17         [ % "\n" % (parse-here) ] if
  18     ] [ ";" unexpected-eof ] if* ;
  19 PRIVATE>
  20
  21 : parse-here ( -- str )
  22     [ (parse-here) ] "" make but-last
  23     lexer get next-line ;
  24
  25 SYNTAX: STRING:
  26     CREATE-WORD
  27     parse-here 1quotation
  28     (( -- string )) define-inline ;
  29
  30 <PRIVATE
  31
  32 :: (scan-multiline-string) ( i end -- j )
  33     lexer get line-text>> :> text
  34     text [
  35         end text i start* [| j |
  36             i j text subseq % j end length +
  37         ] [
  38             text i short tail % CHAR: \n ,
  39             lexer get next-line
  40             0 end (scan-multiline-string)
  41         ] if*
  42     ] [ end unexpected-eof ] if ;
  43
  44 :: (parse-multiline-string) ( end-text skip-n-chars -- str )
  45     [
  46         lexer get
  47         [ skip-n-chars + end-text (scan-multiline-string) ]
  48         change-column drop
  49     ] "" make ;
  50
  51 : rest-of-line ( -- seq )
  52     lexer get [ line-text>> ] [ column>> ] bi tail ;
  53
  54 :: advance-same-line ( text -- )
  55     lexer get [ text length + ] change-column drop ;
  56
  57 :: (parse-til-line-begins) ( begin-text -- )
  58     lexer get still-parsing? [
  59         lexer get line-text>> begin-text sequence= [
  60             begin-text advance-same-line
  61         ] [
  62             lexer get line-text>> % "\n" %
  63             lexer get next-line
  64             begin-text (parse-til-line-begins)
  65         ] if
  66     ] [
  67         begin-text bad-heredoc
  68     ] if ;
  69
  70 : parse-til-line-begins ( begin-text -- seq )
  71     [ (parse-til-line-begins) ] "" make ;
  72
  73 PRIVATE>
  74
  75 : parse-multiline-string ( end-text -- str )
  76     1 (parse-multiline-string) ;
  77
  78 SYNTAX: /* "*/" parse-multiline-string drop ;
  79
  80 SYNTAX: HEREDOC:
  81     lexer get skip-blank
  82     rest-of-line
  83     lexer get next-line
  84     parse-til-line-begins suffix! ;
  85
  86 SYNTAX: DELIMITED:
  87     lexer get skip-blank
  88     rest-of-line
  89     lexer get next-line
  90     0 (parse-multiline-string) suffix! ;