basis/opengl/opengl.factor

   1 ! Copyright (C) 2005, 2009 Slava Pestov.
   2 ! Portions copyright (C) 2007 Eduardo Cavazos.
   3 ! Portions copyright (C) 2008 Joe Groff.
   4 ! See http://factorcode.org/license.txt for BSD license.
   5 USING: alien alien.c-types alien.data assocs colors
   6 combinators.smart continuations fry init io kernel locals macros
   7 math math.parser namespaces opengl.gl sequences
   8 sequences.generalizations specialized-arrays words ;
   9 FROM: alien.c-types => float ;
  10 SPECIALIZED-ARRAY: float
  11 SPECIALIZED-ARRAY: uint
  12 IN: opengl
  13
  14 SYMBOL: gl-scale-factor
  15
  16 : gl-color ( color -- ) >rgba-components glColor4d ; inline
  17
  18 : gl-clear-color ( color -- ) >rgba-components glClearColor ;
  19
  20 : gl-clear ( color -- )
  21     gl-clear-color GL_COLOR_BUFFER_BIT glClear ;
  22
  23 : error>string ( n -- string )
  24     H{
  25         { 0x0000 "No error" }
  26         { 0x0501 "Invalid value" }
  27         { 0x0500 "Invalid enumerant" }
  28         { 0x0502 "Invalid operation" }
  29         { 0x0503 "Stack overflow" }
  30         { 0x0504 "Stack underflow" }
  31         { 0x0505 "Out of memory" }
  32         { 0x0506 "Invalid framebuffer operation" }
  33     } at "Unknown error" or ;
  34
  35 TUPLE: gl-error-tuple function code string ;
  36
  37 : <gl-error> ( function code -- gl-error )
  38     dup error>string \ gl-error-tuple boa ; inline
  39
  40 : gl-error-code ( -- code/f )
  41     glGetError dup 0 = [ drop f ] when ; inline
  42
  43 : (gl-error) ( function -- )
  44     gl-error-code [ <gl-error> throw ] [ drop ] if* ;
  45
  46 : gl-error ( -- )
  47     f (gl-error) ; inline
  48
  49 : gl-error-nonfatal ( -- )
  50     gl-error-code [
  51         [
  52             [ number>string ] [ error>string ] bi ": " glue
  53             "OpenGL error: " prepend print flush
  54         ] with-global
  55     ] when* ;
  56
  57 : do-enabled ( what quot -- )
  58     over glEnable dip glDisable ; inline
  59
  60 : do-enabled-client-state ( what quot -- )
  61     over glEnableClientState dip glDisableClientState ; inline
  62
  63 : words>values ( word/value-seq -- value-seq )
  64     [ dup word? [ execute( -- x ) ] when ] map ;
  65
  66 : (all-enabled) ( seq quot -- )
  67     [ dup [ glEnable ] each ] dip
  68     dip
  69     [ glDisable ] each ; inline
  70
  71 : (all-enabled-client-state) ( seq quot -- )
  72     [ dup [ glEnableClientState ] each ] dip
  73     dip
  74     [ glDisableClientState ] each ; inline
  75
  76 MACRO: all-enabled ( seq quot -- quot )
  77     [ words>values ] dip '[ _ _ (all-enabled) ] ;
  78
  79 MACRO: all-enabled-client-state ( seq quot -- quot )
  80     [ words>values ] dip '[ _ _ (all-enabled-client-state) ] ;
  81
  82 : do-matrix ( quot -- )
  83     glPushMatrix call glPopMatrix ; inline
  84
  85 : gl-material ( face pname params -- )
  86     float-array{ } like glMaterialfv ;
  87
  88 : gl-vertex-pointer ( seq -- )
  89     [ 2 GL_FLOAT 0 ] dip glVertexPointer ; inline
  90
  91 : gl-color-pointer ( seq -- )
  92     [ 4 GL_FLOAT 0 ] dip glColorPointer ; inline
  93
  94 : gl-texture-coord-pointer ( seq -- )
  95     [ 2 GL_FLOAT 0 ] dip glTexCoordPointer ; inline
  96
  97 : (line-vertices) ( a b -- vertices )
  98     [ first2 [ 0.3 + ] bi@ ] bi@ 4 float-array{ } nsequence ;
  99
 100 : line-vertices ( a b -- )
 101     (line-vertices) gl-vertex-pointer ;
 102
 103 : gl-line ( a b -- )
 104     line-vertices GL_LINES 0 2 glDrawArrays ;
 105
 106 :: (rect-vertices) ( loc dim -- vertices )
 107     ! We use GL_LINE_STRIP with a duplicated first vertex
 108     ! instead of GL_LINE_LOOP to work around a bug in Apple's
 109     ! X3100 driver.
 110     loc first2 [ 0.3 + ] bi@ :> ( x y )
 111     dim first2 [ 0.6 - ] bi@ :> ( w h )
 112     [
 113         x           y
 114         x w +       y
 115         x w +       y h +
 116         x           y h +
 117         x           y
 118     ] float-array{ } output>sequence ;
 119
 120 : rect-vertices ( loc dim -- )
 121     (rect-vertices) gl-vertex-pointer ;
 122
 123 : (gl-rect) ( -- )
 124     GL_LINE_STRIP 0 5 glDrawArrays ;
 125
 126 : gl-rect ( loc dim -- )
 127     rect-vertices (gl-rect) ;
 128
 129 :: (fill-rect-vertices) ( loc dim -- vertices )
 130     loc first2 :> ( x y )
 131     dim first2 :> ( w h )
 132     [
 133         x      y
 134         x w +  y
 135         x w +  y h +
 136         x      y h +
 137     ] float-array{ } output>sequence ;
 138
 139 : fill-rect-vertices ( loc dim -- )
 140     (fill-rect-vertices) gl-vertex-pointer ;
 141
 142 : (gl-fill-rect) ( -- )
 143     GL_QUADS 0 4 glDrawArrays ;
 144
 145 : gl-fill-rect ( loc dim -- )
 146     fill-rect-vertices (gl-fill-rect) ;
 147
 148 : do-attribs ( bits quot -- )
 149     swap glPushAttrib call glPopAttrib ; inline
 150
 151 : (gen-gl-object) ( quot -- id )
 152     [ 1 { uint } ] dip with-out-parameters ; inline
 153
 154 : (delete-gl-object) ( id quot -- )
 155     [ 1 swap uint <ref> ] dip call ; inline
 156
 157 : gen-gl-buffer ( -- id )
 158     [ glGenBuffers ] (gen-gl-object) ;
 159
 160 : delete-gl-buffer ( id -- )
 161     [ glDeleteBuffers ] (delete-gl-object) ;
 162
 163 :: with-gl-buffer ( binding id quot -- )
 164     binding id glBindBuffer
 165     quot [ binding 0 glBindBuffer ] [ ] cleanup ; inline
 166
 167 : with-array-element-buffers ( array-buffer element-buffer quot -- )
 168     [ GL_ELEMENT_ARRAY_BUFFER ] 2dip '[
 169         GL_ARRAY_BUFFER swap _ with-gl-buffer
 170     ] with-gl-buffer ; inline
 171
 172 : gen-vertex-array ( -- id )
 173     [ glGenVertexArrays ] (gen-gl-object) ;
 174
 175 : delete-vertex-array ( id -- )
 176     [ glDeleteVertexArrays ] (delete-gl-object) ;
 177
 178 :: with-vertex-array ( id quot -- )
 179     id glBindVertexArray
 180     quot [ 0 glBindVertexArray ] [ ] cleanup ; inline
 181
 182 : <gl-buffer> ( target data hint -- id )
 183     pick gen-gl-buffer [
 184         [
 185             [ [ byte-length ] keep ] dip glBufferData
 186         ] with-gl-buffer
 187     ] keep ;
 188
 189 : buffer-offset ( int -- alien )
 190     <alien> ; inline
 191
 192 : bind-texture-unit ( id target unit -- )
 193     glActiveTexture swap glBindTexture gl-error ;
 194
 195 : (set-draw-buffers) ( buffers -- )
 196     [ length ] [ uint >c-array ] bi glDrawBuffers ;
 197
 198 MACRO: set-draw-buffers ( buffers -- quot )
 199     words>values '[ _ (set-draw-buffers) ] ;
 200
 201 : gen-dlist ( -- id ) 1 glGenLists ;
 202
 203 : make-dlist ( type quot -- id )
 204     [ gen-dlist ] 2dip '[ _ glNewList @ glEndList ] keep ; inline
 205
 206 : gl-translate ( point -- ) first2 0.0 glTranslated ;
 207
 208 : delete-dlist ( id -- ) 1 glDeleteLists ;
 209
 210 : with-translation ( loc quot -- )
 211     [ [ gl-translate ] dip call ] do-matrix ; inline
 212
 213 : gl-scale ( m -- n )
 214     gl-scale-factor get-global [ * ] when* ; inline
 215
 216 : gl-unscale ( m -- n )
 217     gl-scale-factor get-global [ / ] when* ; inline
 218
 219 : fix-coordinates ( point1 point2 -- x1 y1 x2 y2 )
 220     [ first2 [ gl-scale >fixnum ] bi@ ] bi@ ;
 221
 222 : gl-set-clip ( loc dim -- )
 223     fix-coordinates glScissor ;
 224
 225 : gl-viewport ( loc dim -- )
 226     fix-coordinates glViewport ;
 227
 228 : init-matrices ( -- )
 229     ! Leaves with matrix mode GL_MODELVIEW
 230     GL_PROJECTION glMatrixMode
 231     glLoadIdentity
 232     GL_MODELVIEW glMatrixMode
 233     glLoadIdentity ;
 234
 235 [ f gl-scale-factor set-global ] "opengl" add-startup-hook