basis/opengl/opengl.factor

   1 ! Copyright (C) 2005, 2009 Slava Pestov.
   2 ! Portions copyright (C) 2007 Eduardo Cavazos.
   3 ! Portions copyright (C) 2008 Joe Groff.
   4 ! See http://factorcode.org/license.txt for BSD license.
   5 USING: alien alien.c-types alien.data ascii calendar
   6 combinators.short-circuit continuations kernel libc math macros
   7 namespaces math.vectors math.parser opengl.gl combinators
   8 combinators.smart arrays sequences splitting words byte-arrays
   9 assocs vocabs colors colors.constants accessors generalizations
  10 sequences.generalizations locals fry specialized-arrays ;
  11 FROM: alien.c-types => float ;
  12 SPECIALIZED-ARRAY: float
  13 SPECIALIZED-ARRAY: uint
  14 IN: opengl
  15
  16 SYMBOL: gl-scale-factor
  17
  18 : gl-color ( color -- ) >rgba-components glColor4d ; inline
  19
  20 : gl-clear-color ( color -- ) >rgba-components glClearColor ;
  21
  22 : gl-clear ( color -- )
  23     gl-clear-color GL_COLOR_BUFFER_BIT glClear ;
  24
  25 : error>string ( n -- string )
  26     H{
  27         { 0x0 "No error" }
  28         { 0x0501 "Invalid value" }
  29         { 0x0500 "Invalid enumerant" }
  30         { 0x0502 "Invalid operation" }
  31         { 0x0503 "Stack overflow" }
  32         { 0x0504 "Stack underflow" }
  33         { 0x0505 "Out of memory" }
  34         { 0x0506 "Invalid framebuffer operation" }
  35     } at "Unknown error" or ;
  36
  37 TUPLE: gl-error function code string ;
  38
  39 : <gl-error> ( function code -- gl-error )
  40     dup error>string \ gl-error boa ; inline
  41
  42 : gl-error-code ( -- code/f )
  43     glGetError dup 0 = [ drop f ] when ; inline
  44
  45 : (gl-error) ( function -- )
  46     gl-error-code [ <gl-error> throw ] [ drop ] if* ;
  47
  48 : gl-error ( -- )
  49     f (gl-error) ; inline
  50
  51 : do-enabled ( what quot -- )
  52     over glEnable dip glDisable ; inline
  53
  54 : do-enabled-client-state ( what quot -- )
  55     over glEnableClientState dip glDisableClientState ; inline
  56
  57 : words>values ( word/value-seq -- value-seq )
  58     [ ?execute ] map ;
  59
  60 : (all-enabled) ( seq quot -- )
  61     [ dup [ glEnable ] each ] dip
  62     dip
  63     [ glDisable ] each ; inline
  64
  65 : (all-enabled-client-state) ( seq quot -- )
  66     [ dup [ glEnableClientState ] each ] dip
  67     dip
  68     [ glDisableClientState ] each ; inline
  69
  70 MACRO: all-enabled ( seq quot -- )
  71     [ words>values ] dip '[ _ _ (all-enabled) ] ;
  72
  73 MACRO: all-enabled-client-state ( seq quot -- )
  74     [ words>values ] dip '[ _ _ (all-enabled-client-state) ] ;
  75
  76 : do-matrix ( quot -- )
  77     glPushMatrix call glPopMatrix ; inline
  78
  79 : gl-material ( face pname params -- )
  80     float-array{ } like glMaterialfv ;
  81
  82 : gl-vertex-pointer ( seq -- )
  83     [ 2 GL_FLOAT 0 ] dip glVertexPointer ; inline
  84
  85 : gl-color-pointer ( seq -- )
  86     [ 4 GL_FLOAT 0 ] dip glColorPointer ; inline
  87
  88 : gl-texture-coord-pointer ( seq -- )
  89     [ 2 GL_FLOAT 0 ] dip glTexCoordPointer ; inline
  90
  91 : line-vertices ( a b -- )
  92     [ first2 [ 0.5 + ] bi@ ] bi@ 4 float-array{ } nsequence
  93     gl-vertex-pointer ;
  94
  95 : gl-line ( a b -- )
  96     line-vertices GL_LINES 0 2 glDrawArrays ;
  97
  98 :: (rect-vertices) ( loc dim -- vertices )
  99     #! We use GL_LINE_STRIP with a duplicated first vertex
 100     #! instead of GL_LINE_LOOP to work around a bug in Apple's
 101     #! X3100 driver.
 102     loc first2 :> ( x y )
 103     dim first2 :> ( w h )
 104     [
 105         x 0.5 +     y 0.5 +
 106         x w + 0.3 - y 0.5 +
 107         x w + 0.3 - y h + 0.3 -
 108         x           y h + 0.3 -
 109         x 0.5 +     y 0.5 +
 110     ] float-array{ } output>sequence ;
 111
 112 : rect-vertices ( loc dim -- )
 113     (rect-vertices) gl-vertex-pointer ;
 114
 115 : (gl-rect) ( -- )
 116     GL_LINE_STRIP 0 5 glDrawArrays ;
 117
 118 : gl-rect ( loc dim -- )
 119     rect-vertices (gl-rect) ;
 120
 121 :: (fill-rect-vertices) ( loc dim -- vertices )
 122     loc first2 :> ( x y )
 123     dim first2 :> ( w h )
 124     [
 125         x      y
 126         x w +  y
 127         x w +  y h +
 128         x      y h +
 129     ] float-array{ } output>sequence ;
 130
 131 : fill-rect-vertices ( loc dim -- )
 132     (fill-rect-vertices) gl-vertex-pointer ;
 133
 134 : (gl-fill-rect) ( -- )
 135     GL_QUADS 0 4 glDrawArrays ;
 136
 137 : gl-fill-rect ( loc dim -- )
 138     fill-rect-vertices (gl-fill-rect) ;
 139
 140 : do-attribs ( bits quot -- )
 141     swap glPushAttrib call glPopAttrib ; inline
 142
 143 : (gen-gl-object) ( quot -- id )
 144     [ 1 { uint } ] dip with-out-parameters ; inline
 145
 146 : (delete-gl-object) ( id quot -- )
 147     [ 1 swap uint <ref> ] dip call ; inline
 148
 149 : gen-gl-buffer ( -- id )
 150     [ glGenBuffers ] (gen-gl-object) ;
 151
 152 : delete-gl-buffer ( id -- )
 153     [ glDeleteBuffers ] (delete-gl-object) ;
 154
 155 :: with-gl-buffer ( binding id quot -- )
 156     binding id glBindBuffer
 157     quot [ binding 0 glBindBuffer ] [ ] cleanup ; inline
 158
 159 : with-array-element-buffers ( array-buffer element-buffer quot -- )
 160     [ GL_ELEMENT_ARRAY_BUFFER ] 2dip '[
 161         GL_ARRAY_BUFFER swap _ with-gl-buffer
 162     ] with-gl-buffer ; inline
 163
 164 : gen-vertex-array ( -- id )
 165     [ glGenVertexArrays ] (gen-gl-object) ;
 166
 167 : delete-vertex-array ( id -- )
 168     [ glDeleteVertexArrays ] (delete-gl-object) ;
 169
 170 :: with-vertex-array ( id quot -- )
 171     id glBindVertexArray
 172     quot [ 0 glBindVertexArray ] [ ] cleanup ; inline
 173
 174 : <gl-buffer> ( target data hint -- id )
 175     pick gen-gl-buffer [
 176         [
 177             [ [ byte-length ] keep ] dip glBufferData
 178         ] with-gl-buffer
 179     ] keep ;
 180
 181 : buffer-offset ( int -- alien )
 182     <alien> ; inline
 183
 184 : bind-texture-unit ( id target unit -- )
 185     glActiveTexture swap glBindTexture gl-error ;
 186
 187 : (set-draw-buffers) ( buffers -- )
 188     [ length ] [ uint >c-array ] bi glDrawBuffers ;
 189
 190 MACRO: set-draw-buffers ( buffers -- )
 191     words>values '[ _ (set-draw-buffers) ] ;
 192
 193 : gen-dlist ( -- id ) 1 glGenLists ;
 194
 195 : make-dlist ( type quot -- id )
 196     [ gen-dlist ] 2dip '[ _ glNewList @ glEndList ] keep ; inline
 197
 198 : gl-translate ( point -- ) first2 0.0 glTranslated ;
 199
 200 : delete-dlist ( id -- ) 1 glDeleteLists ;
 201
 202 : with-translation ( loc quot -- )
 203     [ [ gl-translate ] dip call ] do-matrix ; inline
 204
 205 : gl-scale ( m -- n )
 206     gl-scale-factor get-global [ * ] when* ; inline
 207
 208 : gl-unscale ( m -- n )
 209     gl-scale-factor get-global [ / ] when* ; inline
 210
 211 : fix-coordinates ( point1 point2 -- x1 y1 x2 y2 )
 212     [ first2 [ gl-scale >fixnum ] bi@ ] bi@ ;
 213
 214 : gl-set-clip ( loc dim -- )
 215     fix-coordinates glScissor ;
 216
 217 : gl-viewport ( loc dim -- )
 218     fix-coordinates glViewport ;
 219
 220 : init-matrices ( -- )
 221     #! Leaves with matrix mode GL_MODELVIEW
 222     GL_PROJECTION glMatrixMode
 223     glLoadIdentity
 224     GL_MODELVIEW glMatrixMode
 225     glLoadIdentity ;