basis/opengl/shaders/shaders.factor

   1 ! Copyright (C) 2008 Joe Groff.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: kernel opengl.gl alien.c-types continuations namespaces
   4 assocs alien alien.strings libc opengl math sequences combinators
   5 combinators.lib macros arrays io.encodings.ascii fry ;
   6 IN: opengl.shaders
   7
   8 : with-gl-shader-source-ptr ( string quot -- )
   9     swap ascii malloc-string [ <void*> swap call ] keep free ; inline
  10
  11 : <gl-shader> ( source kind -- shader )
  12     glCreateShader dup rot
  13     [ 1 swap f glShaderSource ] with-gl-shader-source-ptr
  14     [ glCompileShader ] keep
  15     gl-error ;
  16
  17 : (gl-shader?) ( object -- ? )
  18     dup integer? [ glIsShader c-bool> ] [ drop f ] if ;
  19
  20 : gl-shader-get-int ( shader enum -- value )
  21     0 <int> [ glGetShaderiv ] keep *int ;
  22
  23 : gl-shader-ok? ( shader -- ? )
  24     GL_COMPILE_STATUS gl-shader-get-int c-bool> ;
  25
  26 : <vertex-shader> ( source -- vertex-shader )
  27     GL_VERTEX_SHADER <gl-shader> ; inline
  28
  29 : (vertex-shader?) ( object -- ? )
  30     dup (gl-shader?)
  31     [ GL_SHADER_TYPE gl-shader-get-int GL_VERTEX_SHADER = ]
  32     [ drop f ] if ;
  33
  34 : <fragment-shader> ( source -- fragment-shader )
  35     GL_FRAGMENT_SHADER <gl-shader> ; inline
  36
  37 : (fragment-shader?) ( object -- ? )
  38     dup (gl-shader?)
  39     [ GL_SHADER_TYPE gl-shader-get-int GL_FRAGMENT_SHADER = ]
  40     [ drop f ] if ;
  41
  42 : gl-shader-info-log-length ( shader -- log-length )
  43     GL_INFO_LOG_LENGTH gl-shader-get-int ; inline
  44
  45 : gl-shader-info-log ( shader -- log )
  46     dup gl-shader-info-log-length dup [
  47         [ 0 <int> swap glGetShaderInfoLog ] keep
  48         ascii alien>string
  49     ] with-malloc ;
  50
  51 : check-gl-shader ( shader -- shader )
  52     dup gl-shader-ok? [ dup gl-shader-info-log throw ] unless ;
  53
  54 : delete-gl-shader ( shader -- ) glDeleteShader ; inline
  55
  56 PREDICATE: gl-shader < integer (gl-shader?) ;
  57 PREDICATE: vertex-shader < gl-shader (vertex-shader?) ;
  58 PREDICATE: fragment-shader < gl-shader (fragment-shader?) ;
  59
  60 ! Programs
  61
  62 : <gl-program> ( shaders -- program )
  63     glCreateProgram swap
  64     [ dupd glAttachShader ] each
  65     [ glLinkProgram ] keep
  66     gl-error ;
  67
  68 : (gl-program?) ( object -- ? )
  69     dup integer? [ glIsProgram c-bool> ] [ drop f ] if ;
  70
  71 : gl-program-get-int ( program enum -- value )
  72     0 <int> [ glGetProgramiv ] keep *int ;
  73
  74 : gl-program-ok? ( program -- ? )
  75     GL_LINK_STATUS gl-program-get-int c-bool> ;
  76
  77 : gl-program-info-log-length ( program -- log-length )
  78     GL_INFO_LOG_LENGTH gl-program-get-int ; inline
  79
  80 : gl-program-info-log ( program -- log )
  81     dup gl-program-info-log-length dup [
  82         [ 0 <int> swap glGetProgramInfoLog ] keep
  83         ascii alien>string
  84     ] with-malloc ;
  85
  86 : check-gl-program ( program -- program )
  87     dup gl-program-ok? [ dup gl-program-info-log throw ] unless ;
  88
  89 : gl-program-shaders-length ( program -- shaders-length )
  90     GL_ATTACHED_SHADERS gl-program-get-int ; inline
  91
  92 : gl-program-shaders ( program -- shaders )
  93     dup gl-program-shaders-length
  94     dup "GLuint" <c-array>
  95     0 <int> swap
  96     [ glGetAttachedShaders ] { 3 1 } multikeep
  97     c-uint-array> ;
  98
  99 : delete-gl-program-only ( program -- )
 100     glDeleteProgram ; inline
 101
 102 : detach-gl-program-shader ( program shader -- )
 103     glDetachShader ; inline
 104
 105 : delete-gl-program ( program -- )
 106     dup gl-program-shaders [
 107         2dup detach-gl-program-shader delete-gl-shader
 108     ] each delete-gl-program-only ;
 109
 110 : with-gl-program ( program quot -- )
 111     over glUseProgram [ 0 glUseProgram ] [ ] cleanup ; inline
 112
 113 PREDICATE: gl-program < integer (gl-program?) ;
 114
 115 : <simple-gl-program> ( vertex-shader-source fragment-shader-source -- program )
 116     >r <vertex-shader> check-gl-shader
 117     r> <fragment-shader> check-gl-shader
 118     2array <gl-program> check-gl-program ;
 119