basis/opengl/shaders/shaders.factor

   1 ! Copyright (C) 2008 Joe Groff.
   2 ! See https://factorcode.org/license.txt for BSD license.
   3 USING: alien.c-types alien.data alien.strings arrays
   4 continuations destructors io.encodings.ascii kernel libc math
   5 opengl opengl.gl sequences specialized-arrays ;
   6 SPECIALIZED-ARRAY: uint
   7 IN: opengl.shaders
   8
   9 : with-gl-shader-source-ptr ( string quot -- )
  10     swap ascii malloc-string [ void* <ref> swap call ] keep free ; inline
  11
  12 : <gl-shader> ( source kind -- shader )
  13     glCreateShader dup rot
  14     [ 1 swap f glShaderSource ] with-gl-shader-source-ptr
  15     [ glCompileShader ] keep
  16     gl-error ;
  17
  18 : (gl-shader?) ( object -- ? )
  19     dup integer? [ glIsShader c-bool> ] [ drop f ] if ;
  20
  21 : gl-shader-get-int ( shader enum -- value )
  22     { int } [ glGetShaderiv ] with-out-parameters ;
  23
  24 : gl-shader-ok? ( shader -- ? )
  25     GL_COMPILE_STATUS gl-shader-get-int c-bool> ;
  26
  27 : <vertex-shader> ( source -- vertex-shader )
  28     GL_VERTEX_SHADER <gl-shader> ; inline
  29
  30 : (vertex-shader?) ( object -- ? )
  31     dup (gl-shader?)
  32     [ GL_SHADER_TYPE gl-shader-get-int GL_VERTEX_SHADER = ]
  33     [ drop f ] if ;
  34
  35 : <fragment-shader> ( source -- fragment-shader )
  36     GL_FRAGMENT_SHADER <gl-shader> ; inline
  37
  38 : (fragment-shader?) ( object -- ? )
  39     dup (gl-shader?)
  40     [ GL_SHADER_TYPE gl-shader-get-int GL_FRAGMENT_SHADER = ]
  41     [ drop f ] if ;
  42
  43 : gl-shader-info-log-length ( shader -- log-length )
  44     GL_INFO_LOG_LENGTH gl-shader-get-int ; inline
  45
  46 : gl-shader-info-log ( shader -- log )
  47     dup gl-shader-info-log-length dup [
  48         1 calloc &free
  49         [ 0 int <ref> swap glGetShaderInfoLog ] keep
  50         ascii alien>string
  51     ] with-destructors ;
  52
  53 : check-gl-shader ( shader -- shader )
  54     dup gl-shader-ok? [ dup gl-shader-info-log throw ] unless ;
  55
  56 PREDICATE: gl-shader < integer (gl-shader?) ;
  57 PREDICATE: vertex-shader < gl-shader (vertex-shader?) ;
  58 PREDICATE: fragment-shader < gl-shader (fragment-shader?) ;
  59
  60 ! Programs
  61
  62 : attach-shaders ( program shaders -- )
  63     [ glAttachShader ] with each ;
  64
  65 : (gl-program) ( shaders quot: ( gl-program -- ) -- program )
  66     glCreateProgram
  67     [
  68         dup roll attach-shaders swap call
  69     ] [ glLinkProgram ] [ ] tri gl-error ; inline
  70
  71 : <gl-program> ( shaders -- program )
  72     [ drop ] (gl-program) ;
  73
  74 : (gl-program?) ( object -- ? )
  75     dup integer? [ glIsProgram c-bool> ] [ drop f ] if ;
  76
  77 : gl-program-get-int ( program enum -- value )
  78     { int } [ glGetProgramiv ] with-out-parameters ;
  79
  80 : gl-program-ok? ( program -- ? )
  81     GL_LINK_STATUS gl-program-get-int c-bool> ;
  82
  83 : gl-program-info-log-length ( program -- log-length )
  84     GL_INFO_LOG_LENGTH gl-program-get-int ; inline
  85
  86 : gl-program-info-log ( program -- log )
  87     dup gl-program-info-log-length dup [
  88         1 calloc &free
  89         [ 0 int <ref> swap glGetProgramInfoLog ] keep
  90         ascii alien>string
  91     ] with-destructors ;
  92
  93 : check-gl-program ( program -- program )
  94     dup gl-program-ok? [ dup gl-program-info-log throw ] unless ;
  95
  96 : gl-program-shaders-length ( program -- shaders-length )
  97     GL_ATTACHED_SHADERS gl-program-get-int ; inline
  98
  99 ! On some macosx-x86-64 graphics drivers, glGetAttachedShaders tries to treat the
 100 ! shaders parameter as a ulonglong array rather than a GLuint array as documented.
 101 ! We hack around this by allocating a buffer twice the size and sifting out the zero
 102 ! values
 103
 104 : gl-program-shaders ( program -- shaders )
 105     dup gl-program-shaders-length 2 *
 106     0 int <ref>
 107     over uint <c-array>
 108     [ glGetAttachedShaders ] keep [ zero? ] reject ;
 109
 110 : delete-gl-program ( program -- )
 111     dup gl-program-shaders [
 112         2dup glDetachShader glDeleteShader
 113     ] each glDeleteProgram ;
 114
 115 : with-gl-program ( program quot -- )
 116     over glUseProgram [ 0 glUseProgram ] finally ; inline
 117
 118 PREDICATE: gl-program < integer (gl-program?) ;
 119
 120 : <simple-gl-program> ( vertex-shader-source fragment-shader-source
 121                         -- program )
 122     [ <vertex-shader> check-gl-shader ]
 123     [ <fragment-shader> check-gl-shader ] bi*
 124     2array <gl-program> check-gl-program ;