basis/opengl/shaders/shaders.factor

   1 ! Copyright (C) 2008 Joe Groff.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: kernel opengl.gl alien.c-types continuations namespaces
   4 assocs alien alien.strings libc opengl math sequences combinators
   5 macros arrays io.encodings.ascii fry specialized-arrays.uint
   6 destructors accessors ;
   7 IN: opengl.shaders
   8
   9 : with-gl-shader-source-ptr ( string quot -- )
  10     swap ascii malloc-string [ <void*> swap call ] keep free ; inline
  11
  12 : <gl-shader> ( source kind -- shader )
  13     glCreateShader dup rot
  14     [ 1 swap f glShaderSource ] with-gl-shader-source-ptr
  15     [ glCompileShader ] keep
  16     gl-error ;
  17
  18 : (gl-shader?) ( object -- ? )
  19     dup integer? [ glIsShader c-bool> ] [ drop f ] if ;
  20
  21 : gl-shader-get-int ( shader enum -- value )
  22     0 <int> [ glGetShaderiv ] keep *int ;
  23
  24 : gl-shader-ok? ( shader -- ? )
  25     GL_COMPILE_STATUS gl-shader-get-int c-bool> ;
  26
  27 : <vertex-shader> ( source -- vertex-shader )
  28     GL_VERTEX_SHADER <gl-shader> ; inline
  29
  30 : (vertex-shader?) ( object -- ? )
  31     dup (gl-shader?)
  32     [ GL_SHADER_TYPE gl-shader-get-int GL_VERTEX_SHADER = ]
  33     [ drop f ] if ;
  34
  35 : <fragment-shader> ( source -- fragment-shader )
  36     GL_FRAGMENT_SHADER <gl-shader> ; inline
  37
  38 : (fragment-shader?) ( object -- ? )
  39     dup (gl-shader?)
  40     [ GL_SHADER_TYPE gl-shader-get-int GL_FRAGMENT_SHADER = ]
  41     [ drop f ] if ;
  42
  43 : gl-shader-info-log-length ( shader -- log-length )
  44     GL_INFO_LOG_LENGTH gl-shader-get-int ; inline
  45
  46 : gl-shader-info-log ( shader -- log )
  47     dup gl-shader-info-log-length dup [
  48         1 calloc &free
  49         [ 0 <int> swap glGetShaderInfoLog ] keep
  50         ascii alien>string
  51     ] with-destructors ;
  52
  53 : check-gl-shader ( shader -- shader )
  54     dup gl-shader-ok? [ dup gl-shader-info-log throw ] unless ;
  55
  56 : delete-gl-shader ( shader -- ) glDeleteShader ; inline
  57
  58 PREDICATE: gl-shader < integer (gl-shader?) ;
  59 PREDICATE: vertex-shader < gl-shader (vertex-shader?) ;
  60 PREDICATE: fragment-shader < gl-shader (fragment-shader?) ;
  61
  62 ! Programs
  63
  64 : <mrt-gl-program> ( shaders frag-data-locations -- program )
  65     glCreateProgram
  66     [
  67         [ swap [ glAttachShader ] with each ]
  68         [ swap [ first2 swap glBindFragDataLocationEXT ] with each ] bi-curry bi*
  69     ]
  70     [ glLinkProgram ]
  71     [ ] tri
  72     gl-error ;
  73
  74 : <gl-program> ( shaders -- program )
  75     glCreateProgram
  76     [ swap [ glAttachShader ] with each ]
  77     [ glLinkProgram ]
  78     [ ] tri
  79     gl-error ;
  80
  81 : (gl-program?) ( object -- ? )
  82     dup integer? [ glIsProgram c-bool> ] [ drop f ] if ;
  83
  84 : gl-program-get-int ( program enum -- value )
  85     0 <int> [ glGetProgramiv ] keep *int ;
  86
  87 : gl-program-ok? ( program -- ? )
  88     GL_LINK_STATUS gl-program-get-int c-bool> ;
  89
  90 : gl-program-info-log-length ( program -- log-length )
  91     GL_INFO_LOG_LENGTH gl-program-get-int ; inline
  92
  93 : gl-program-info-log ( program -- log )
  94     dup gl-program-info-log-length dup [
  95         1 calloc &free
  96         [ 0 <int> swap glGetProgramInfoLog ] keep
  97         ascii alien>string
  98     ] with-destructors ;
  99
 100 : check-gl-program ( program -- program )
 101     dup gl-program-ok? [ dup gl-program-info-log throw ] unless ;
 102
 103 : gl-program-shaders-length ( program -- shaders-length )
 104     GL_ATTACHED_SHADERS gl-program-get-int ; inline
 105
 106 ! On some macosx-x86-64 graphics drivers, glGetAttachedShaders tries to treat the
 107 ! shaders parameter as a ulonglong array rather than a GLuint array as documented.
 108 ! We hack around this by allocating a buffer twice the size and sifting out the zero
 109 ! values
 110
 111 : gl-program-shaders ( program -- shaders )
 112     dup gl-program-shaders-length 2 *
 113     0 <int>
 114     over <uint-array>
 115     [ glGetAttachedShaders ] keep [ zero? not ] filter ;
 116
 117 : delete-gl-program-only ( program -- )
 118     glDeleteProgram ; inline
 119
 120 : detach-gl-program-shader ( program shader -- )
 121     glDetachShader ; inline
 122
 123 : delete-gl-program ( program -- )
 124     dup gl-program-shaders [
 125         2dup detach-gl-program-shader delete-gl-shader
 126     ] each delete-gl-program-only ;
 127
 128 : with-gl-program ( program quot -- )
 129     over glUseProgram [ 0 glUseProgram ] [ ] cleanup ; inline
 130
 131 PREDICATE: gl-program < integer (gl-program?) ;
 132
 133 : <simple-gl-program> ( vertex-shader-source fragment-shader-source -- program )
 134     [ <vertex-shader> check-gl-shader ]
 135     [ <fragment-shader> check-gl-shader ] bi*
 136     2array <gl-program> check-gl-program ;
 137