basis/opengl/textures/textures.factor

   1 ! Copyright (C) 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors assocs cache colors.constants destructors kernel
   4 opengl opengl.gl opengl.capabilities combinators images
   5 images.tesselation grouping specialized-arrays.float sequences math
   6 math.vectors math.matrices generalizations fry arrays namespaces
   7 system ;
   8 IN: opengl.textures
   9
  10 SYMBOL: non-power-of-2-textures?
  11
  12 : check-extensions ( -- )
  13     #! ATI frglx driver doesn't implement GL_ARB_texture_non_power_of_two properly.
  14     #! See thread 'Linux font display problem' April 2009 on Factor-talk
  15     gl-vendor "ATI Technologies Inc." = not os macosx? or [
  16         "2.0" { "GL_ARB_texture_non_power_of_two" }
  17         has-gl-version-or-extensions?
  18         non-power-of-2-textures? set
  19     ] when ;
  20
  21 : gen-texture ( -- id ) [ glGenTextures ] (gen-gl-object) ;
  22
  23 : delete-texture ( id -- ) [ glDeleteTextures ] (delete-gl-object) ;
  24
  25 GENERIC: component-order>format ( component-order -- format type )
  26
  27 M: RGB component-order>format drop GL_RGB GL_UNSIGNED_BYTE ;
  28 M: BGR component-order>format drop GL_BGR GL_UNSIGNED_BYTE ;
  29 M: RGBA component-order>format drop GL_RGBA GL_UNSIGNED_BYTE ;
  30 M: ARGB component-order>format drop GL_BGRA_EXT GL_UNSIGNED_INT_8_8_8_8_REV ;
  31 M: BGRA component-order>format drop GL_BGRA_EXT GL_UNSIGNED_BYTE ;
  32 M: BGRX component-order>format drop GL_BGRA_EXT GL_UNSIGNED_BYTE ;
  33 M: LA component-order>format drop GL_LUMINANCE_ALPHA GL_UNSIGNED_BYTE ;
  34 M: L component-order>format drop GL_LUMINANCE GL_UNSIGNED_BYTE ;
  35
  36 SLOT: display-list
  37
  38 : draw-texture ( texture -- ) display-list>> [ glCallList ] when* ;
  39
  40 GENERIC: draw-scaled-texture ( dim texture -- )
  41
  42 DEFER: make-texture
  43
  44 <PRIVATE
  45
  46 TUPLE: single-texture image dim loc texture-coords texture display-list disposed ;
  47
  48 : adjust-texture-dim ( dim -- dim' )
  49     non-power-of-2-textures? get [
  50         [ dup 1 = [ next-power-of-2 ] unless ] map
  51     ] unless ;
  52
  53 : tex-image ( image bitmap -- )
  54     [
  55         [ GL_TEXTURE_2D 0 GL_RGBA ] dip
  56         [ dim>> adjust-texture-dim first2 0 ]
  57         [ component-order>> component-order>format ] bi
  58     ] dip
  59     glTexImage2D ;
  60
  61 : tex-sub-image ( image -- )
  62     [ GL_TEXTURE_2D 0 0 0 ] dip
  63     [ dim>> first2 ]
  64     [ component-order>> component-order>format ]
  65     [ bitmap>> ] tri
  66     glTexSubImage2D ;
  67
  68 : init-texture ( -- )
  69     GL_TEXTURE_2D GL_TEXTURE_MAG_FILTER GL_NEAREST glTexParameteri
  70     GL_TEXTURE_2D GL_TEXTURE_MIN_FILTER GL_NEAREST glTexParameteri
  71     GL_TEXTURE_2D GL_TEXTURE_WRAP_S GL_REPEAT glTexParameteri
  72     GL_TEXTURE_2D GL_TEXTURE_WRAP_T GL_REPEAT glTexParameteri ;
  73
  74 : with-texturing ( quot -- )
  75     GL_TEXTURE_2D [
  76         GL_TEXTURE_BIT [
  77             GL_TEXTURE_COORD_ARRAY [
  78                 COLOR: white gl-color
  79                 call
  80             ] do-enabled-client-state
  81         ] do-attribs
  82     ] do-enabled ; inline
  83
  84 : (draw-textured-rect) ( dim texture -- )
  85     [ loc>> ]
  86     [ [ GL_TEXTURE_2D ] dip texture>> glBindTexture ]
  87     [ init-texture texture-coords>> gl-texture-coord-pointer ] tri
  88     swap gl-fill-rect ;
  89
  90 : draw-textured-rect ( dim texture -- )
  91     [
  92         [ image>> has-alpha? [ GL_BLEND glDisable ] unless ]
  93         [ (draw-textured-rect) GL_TEXTURE_2D 0 glBindTexture ]
  94         [ image>> has-alpha? [ GL_BLEND glEnable ] unless ]
  95         tri
  96     ] with-texturing ;
  97
  98 : texture-coords ( texture -- coords )
  99     [ [ dim>> ] [ image>> dim>> adjust-texture-dim ] bi v/ ]
 100     [
 101         image>> upside-down?>>
 102         { { 0 1 } { 1 1 } { 1 0 } { 0 0 } }
 103         { { 0 0 } { 1 0 } { 1 1 } { 0 1 } } ?
 104     ] bi
 105     [ v* ] with map float-array{ } join ;
 106
 107 : make-texture-display-list ( texture -- dlist )
 108     GL_COMPILE [ [ dim>> ] keep draw-textured-rect ] make-dlist ;
 109
 110 : <single-texture> ( image loc -- texture )
 111     single-texture new swap >>loc swap [ >>image ] [ dim>> >>dim ] bi
 112     dup image>> dim>> product 0 = [
 113         dup texture-coords >>texture-coords
 114         dup image>> make-texture >>texture
 115         dup make-texture-display-list >>display-list
 116     ] unless ;
 117
 118 M: single-texture dispose*
 119     [ texture>> [ delete-texture ] when* ]
 120     [ display-list>> [ delete-dlist ] when* ] bi ;
 121
 122 M: single-texture draw-scaled-texture
 123     2dup dim>> = [ nip draw-texture ] [
 124         dup texture>> [ draw-textured-rect ] [ 2drop ] if
 125     ] if ;
 126
 127 TUPLE: multi-texture grid display-list loc disposed ;
 128
 129 : image-locs ( image-grid -- loc-grid )
 130     [ first [ dim>> first ] map ] [ [ first dim>> second ] map ] bi
 131     [ 0 [ + ] accumulate nip ] bi@
 132     cross-zip flip ;
 133
 134 : <texture-grid> ( image-grid loc -- grid )
 135     [ dup image-locs ] dip
 136     '[ [ _ v+ <single-texture> |dispose ] 2map ] 2map ;
 137
 138 : draw-textured-grid ( grid -- )
 139     [ [ [ dim>> ] keep (draw-textured-rect) ] each ] each ;
 140
 141 : grid-has-alpha? ( grid -- ? )
 142     first first image>> has-alpha? ;
 143
 144 : make-textured-grid-display-list ( grid -- dlist )
 145     GL_COMPILE [
 146         [
 147             [ grid-has-alpha? [ GL_BLEND glDisable ] unless ]
 148             [ [ [ [ dim>> ] keep (draw-textured-rect) ] each ] each ]
 149             [ grid-has-alpha? [ GL_BLEND glEnable ] unless ] tri
 150             GL_TEXTURE_2D 0 glBindTexture
 151         ] with-texturing
 152     ] make-dlist ;
 153
 154 : <multi-texture> ( image-grid loc -- multi-texture )
 155     [
 156         [
 157             <texture-grid> dup
 158             make-textured-grid-display-list
 159         ] keep
 160         f multi-texture boa
 161     ] with-destructors ;
 162
 163 M: multi-texture draw-scaled-texture nip draw-texture ;
 164
 165 M: multi-texture dispose* grid>> [ [ dispose ] each ] each ;
 166
 167 CONSTANT: max-texture-size { 512 512 }
 168
 169 PRIVATE>
 170
 171 : make-texture ( image -- id )
 172     #! We use glTexSubImage2D to work around the power of 2 texture size
 173     #! limitation
 174     gen-texture [
 175         GL_TEXTURE_BIT [
 176             GL_TEXTURE_2D swap glBindTexture
 177             non-power-of-2-textures? get
 178             [ dup bitmap>> tex-image ]
 179             [ [ f tex-image ] [ tex-sub-image ] bi ] if
 180         ] do-attribs
 181     ] keep ;
 182
 183 : <texture> ( image loc -- texture )
 184     over dim>> max-texture-size [ <= ] 2all?
 185     [ <single-texture> ]
 186     [ [ max-texture-size tesselate ] dip <multi-texture> ] if ;