basis/opengl/textures/textures.factor

   1 ! Copyright (C) 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors assocs cache colors.constants destructors fry kernel
   4 opengl opengl.gl opengl.capabilities combinators images
   5 images.tesselation grouping specialized-arrays.float sequences math
   6 math.vectors math.matrices generalizations fry arrays namespaces
   7 system ;
   8 IN: opengl.textures
   9
  10 SYMBOL: non-power-of-2-textures?
  11
  12 : check-extensions ( -- )
  13     #! ATI frglx driver doesn't implement GL_ARB_texture_non_power_of_two properly.
  14     #! See thread 'Linux font display problem' April 2009 on Factor-talk
  15     gl-vendor "ATI Technologies Inc." = not os macosx? or [
  16         "2.0" { "GL_ARB_texture_non_power_of_two" }
  17         has-gl-version-or-extensions?
  18         non-power-of-2-textures? set
  19     ] when ;
  20
  21 : gen-texture ( -- id ) [ glGenTextures ] (gen-gl-object) ;
  22
  23 : delete-texture ( id -- ) [ glDeleteTextures ] (delete-gl-object) ;
  24
  25 GENERIC: component-order>format ( component-order -- format type )
  26
  27 M: RGB component-order>format drop GL_RGB GL_UNSIGNED_BYTE ;
  28 M: BGR component-order>format drop GL_BGR GL_UNSIGNED_BYTE ;
  29 M: RGBA component-order>format drop GL_RGBA GL_UNSIGNED_BYTE ;
  30 M: ARGB component-order>format drop GL_BGRA_EXT GL_UNSIGNED_INT_8_8_8_8_REV ;
  31 M: BGRA component-order>format drop GL_BGRA_EXT GL_UNSIGNED_BYTE ;
  32 M: BGRX component-order>format drop GL_BGRA_EXT GL_UNSIGNED_BYTE ;
  33 M: LA component-order>format drop GL_LUMINANCE_ALPHA GL_UNSIGNED_BYTE ;
  34 M: L component-order>format drop GL_LUMINANCE GL_UNSIGNED_BYTE ;
  35
  36 SLOT: display-list
  37
  38 : draw-texture ( texture -- ) display-list>> [ glCallList ] when* ;
  39
  40 GENERIC: draw-scaled-texture ( dim texture -- )
  41
  42 <PRIVATE
  43
  44 TUPLE: single-texture image dim loc texture-coords texture display-list disposed ;
  45
  46 : adjust-texture-dim ( dim -- dim' )
  47     non-power-of-2-textures? get [
  48         [ dup 1 = [ next-power-of-2 ] unless ] map
  49     ] unless ;
  50
  51 : (tex-image) ( image bitmap -- )
  52     [
  53         [ GL_TEXTURE_2D 0 GL_RGBA ] dip
  54         [ dim>> adjust-texture-dim first2 0 ]
  55         [ component-order>> component-order>format ] bi
  56     ] dip
  57     glTexImage2D ;
  58
  59 : (tex-sub-image) ( image -- )
  60     [ GL_TEXTURE_2D 0 0 0 ] dip
  61     [ dim>> first2 ] [ component-order>> component-order>format ] [ bitmap>> ] tri
  62     glTexSubImage2D ;
  63
  64 : make-texture ( image -- id )
  65     #! We use glTexSubImage2D to work around the power of 2 texture size
  66     #! limitation
  67     gen-texture [
  68         GL_TEXTURE_BIT [
  69             GL_TEXTURE_2D swap glBindTexture
  70             non-power-of-2-textures? get
  71             [ dup bitmap>> (tex-image) ]
  72             [ [ f (tex-image) ] [ (tex-sub-image) ] bi ] if
  73         ] do-attribs
  74     ] keep ;
  75
  76 : init-texture ( -- )
  77     GL_TEXTURE_2D GL_TEXTURE_MAG_FILTER GL_NEAREST glTexParameteri
  78     GL_TEXTURE_2D GL_TEXTURE_MIN_FILTER GL_NEAREST glTexParameteri
  79     GL_TEXTURE_2D GL_TEXTURE_WRAP_S GL_REPEAT glTexParameteri
  80     GL_TEXTURE_2D GL_TEXTURE_WRAP_T GL_REPEAT glTexParameteri ;
  81
  82 : with-texturing ( quot -- )
  83     GL_TEXTURE_2D [
  84         GL_TEXTURE_BIT [
  85             GL_TEXTURE_COORD_ARRAY [
  86                 COLOR: white gl-color
  87                 call
  88             ] do-enabled-client-state
  89         ] do-attribs
  90     ] do-enabled ; inline
  91
  92 : (draw-textured-rect) ( dim texture -- )
  93     [ loc>> ]
  94     [ [ GL_TEXTURE_2D ] dip texture>> glBindTexture ]
  95     [ init-texture texture-coords>> gl-texture-coord-pointer ] tri
  96     swap gl-fill-rect ;
  97
  98 : draw-textured-rect ( dim texture -- )
  99     [
 100         [ image>> has-alpha? [ GL_BLEND glDisable ] unless ]
 101         [ (draw-textured-rect) GL_TEXTURE_2D 0 glBindTexture ]
 102         [ image>> has-alpha? [ GL_BLEND glEnable ] unless ]
 103         tri
 104     ] with-texturing ;
 105
 106 : texture-coords ( texture -- coords )
 107     [ [ dim>> ] [ image>> dim>> adjust-texture-dim ] bi v/ ]
 108     [
 109         image>> upside-down?>>
 110         { { 0 1 } { 1 1 } { 1 0 } { 0 0 } }
 111         { { 0 0 } { 1 0 } { 1 1 } { 0 1 } } ?
 112     ] bi
 113     [ v* ] with map float-array{ } join ;
 114
 115 : make-texture-display-list ( texture -- dlist )
 116     GL_COMPILE [ [ dim>> ] keep draw-textured-rect ] make-dlist ;
 117
 118 : <single-texture> ( image loc -- texture )
 119     single-texture new swap >>loc swap [ >>image ] [ dim>> >>dim ] bi
 120     dup image>> dim>> product 0 = [
 121         dup texture-coords >>texture-coords
 122         dup image>> make-texture >>texture
 123         dup make-texture-display-list >>display-list
 124     ] unless ;
 125
 126 M: single-texture dispose*
 127     [ texture>> [ delete-texture ] when* ]
 128     [ display-list>> [ delete-dlist ] when* ] bi ;
 129
 130 M: single-texture draw-scaled-texture
 131     2dup dim>> = [ nip draw-texture ] [
 132         dup texture>> [ draw-textured-rect ] [ 2drop ] if
 133     ] if ;
 134
 135 TUPLE: multi-texture grid display-list loc disposed ;
 136
 137 : image-locs ( image-grid -- loc-grid )
 138     [ first [ dim>> first ] map ] [ [ first dim>> second ] map ] bi
 139     [ 0 [ + ] accumulate nip ] bi@
 140     cross-zip flip ;
 141
 142 : <texture-grid> ( image-grid loc -- grid )
 143     [ dup image-locs ] dip
 144     '[ [ _ v+ <single-texture> |dispose ] 2map ] 2map ;
 145
 146 : draw-textured-grid ( grid -- )
 147     [ [ [ dim>> ] keep (draw-textured-rect) ] each ] each ;
 148
 149 : grid-has-alpha? ( grid -- ? )
 150     first first image>> has-alpha? ;
 151
 152 : make-textured-grid-display-list ( grid -- dlist )
 153     GL_COMPILE [
 154         [
 155             [ grid-has-alpha? [ GL_BLEND glDisable ] unless ]
 156             [ [ [ [ dim>> ] keep (draw-textured-rect) ] each ] each ]
 157             [ grid-has-alpha? [ GL_BLEND glEnable ] unless ] tri
 158             GL_TEXTURE_2D 0 glBindTexture
 159         ] with-texturing
 160     ] make-dlist ;
 161
 162 : <multi-texture> ( image-grid loc -- multi-texture )
 163     [
 164         [
 165             <texture-grid> dup
 166             make-textured-grid-display-list
 167         ] keep
 168         f multi-texture boa
 169     ] with-destructors ;
 170
 171 M: multi-texture draw-scaled-texture nip draw-texture ;
 172
 173 M: multi-texture dispose* grid>> [ [ dispose ] each ] each ;
 174
 175 CONSTANT: max-texture-size { 512 512 }
 176
 177 PRIVATE>
 178
 179 : <texture> ( image loc -- texture )
 180     over dim>> max-texture-size [ <= ] 2all?
 181     [ <single-texture> ]
 182     [ [ max-texture-size tesselate ] dip <multi-texture> ] if ;