basis/persistent/hashtables/nodes/leaf/leaf.factor

   1 ! Based on Clojure's PersistentHashMap by Rich Hickey.
   2
   3 USING: accessors arrays kernel make persistent.hashtables.nodes ;
   4 IN: persistent.hashtables.nodes.leaf
   5
   6 : matching-key? ( key hashcode leaf-node -- ? )
   7     [ nip ] [ hashcode>> eq? ] 2bi
   8     [ key>> = ] [ 2drop f ] if ; inline
   9
  10 M: leaf-node (entry-at) [ matching-key? ] keep and ;
  11
  12 M: leaf-node (pluck-at) [ matching-key? not ] keep and ;
  13
  14 M:: leaf-node (new-at) ( shift value key hashcode leaf-node -- node' added-leaf )
  15     hashcode leaf-node hashcode>> eq? [
  16         key leaf-node key>> = [
  17             value leaf-node value>> =
  18             [ leaf-node f ] [ value key hashcode <leaf-node> f ] if
  19         ] [
  20             value key hashcode <leaf-node> :> new-leaf
  21             hashcode leaf-node new-leaf 2array <collision-node>
  22             new-leaf
  23         ] if
  24     ] [ shift leaf-node value key hashcode make-bitmap-node ] if ;
  25
  26 M: leaf-node >alist% [ key>> ] [ value>> ] bi 2array , ;