basis/random/mersenne-twister/mersenne-twister.factor

   1 ! Copyright (C) 2005, 2008 Doug Coleman.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 ! mersenne twister based on
   4 ! http://www.math.sci.hiroshima-u.ac.jp/~m-mat/MT/MT2002/CODES/mt19937ar.c
   5 USING: alien.c-types alien.data kernel math namespaces sequences
   6 sequences.private system init accessors math.ranges random
   7 math.bitwise combinators specialized-arrays fry ;
   8 SPECIALIZED-ARRAY: uint
   9 IN: random.mersenne-twister
  10
  11 <PRIVATE
  12
  13 TUPLE: mersenne-twister { seq uint-array } { i fixnum } ;
  14
  15 CONSTANT: n 624
  16 CONSTANT: m 397
  17 CONSTANT: a uint-array{ 0 0x9908b0df }
  18
  19 : y ( n seq -- y )
  20     [ nth-unsafe 31 mask-bit ]
  21     [ [ 1 + ] [ nth-unsafe ] bi* 31 bits ] 2bi bitor ; inline
  22
  23 : mt[k] ( offset n seq -- )
  24     [
  25         [ [ + ] dip nth-unsafe ]
  26         [ y [ 2/ ] [ 1 bitand a nth ] bi bitxor ] 2bi
  27         bitxor
  28     ] 2keep set-nth-unsafe ; inline
  29
  30 : mt-generate ( mt -- )
  31     [
  32         seq>>
  33         [ [ n m - ] dip '[ [ m ] dip _ mt[k] ] each-integer ]
  34         [ [ m 1 - ] dip '[ [ m n - ] [ n m - + ] bi* _ mt[k] ] each-integer ]
  35         bi
  36     ] [ 0 >>i drop ] bi ; inline
  37
  38 : init-mt-formula ( i seq -- f(seq[i]) )
  39     dupd nth dup -30 shift bitxor 1812433253 * + 1 + 32 bits ; inline
  40
  41 : init-mt-rest ( seq -- )
  42     n 1 - swap '[
  43         _ [ init-mt-formula ] [ [ 1 + ] dip set-nth ] 2bi
  44     ] each-integer ; inline
  45
  46 : init-mt-seq ( seed -- seq )
  47     32 bits n uint <c-array>
  48     [ set-first ] [ init-mt-rest ] [ ] tri ; inline
  49
  50 : mt-temper ( y -- yt )
  51     dup -11 shift bitxor
  52     dup 7 shift 0x9d2c5680 bitand bitxor
  53     dup 15 shift 0xefc60000 bitand bitxor
  54     dup -18 shift bitxor ; inline
  55
  56 : next-index  ( mt -- i )
  57     dup i>> dup n < [ nip ] [ drop mt-generate 0 ] if ; inline
  58
  59 PRIVATE>
  60
  61 : <mersenne-twister> ( seed -- obj )
  62     init-mt-seq 0 mersenne-twister boa
  63     dup mt-generate ;
  64
  65 M: mersenne-twister seed-random ( mt seed -- mt' )
  66     init-mt-seq >>seq
  67     [ mt-generate ]
  68     [ 0 >>i drop ]
  69     [ ] tri ;
  70
  71 M: mersenne-twister random-32* ( mt -- r )
  72     [ next-index ]
  73     [ seq>> nth-unsafe mt-temper ]
  74     [ [ 1 + ] change-i drop ] tri ;
  75
  76 : default-mersenne-twister ( -- mersenne-twister )
  77     [ 32 random-bits ] with-system-random
  78     <mersenne-twister> ;
  79
  80 [
  81     default-mersenne-twister random-generator set-global
  82 ] "bootstrap.random" add-startup-hook
  83