basis/random/random.factor

   1 ! Copyright (C) 2008 Doug Coleman.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: alien.c-types kernel math namespaces sequences
   4 io.backend io.binary combinators system vocabs.loader
   5 summary math.bitwise byte-vectors fry byte-arrays
   6 math.ranges math.constants math.functions accessors ;
   7 IN: random
   8
   9 SYMBOL: system-random-generator
  10 SYMBOL: secure-random-generator
  11 SYMBOL: random-generator
  12
  13 GENERIC: seed-random ( tuple seed -- )
  14 GENERIC: random-32* ( tuple -- r )
  15 GENERIC: random-bytes* ( n tuple -- byte-array )
  16
  17 M: object random-bytes* ( n tuple -- byte-array )
  18     [ [ <byte-vector> ] keep 4 /mod ] dip
  19     [ pick '[ _ random-32* 4 >le _ push-all ] times ]
  20     [
  21         over zero?
  22         [ 2drop ] [ random-32* 4 >le swap head over push-all ] if
  23     ] bi-curry bi* ;
  24
  25 M: object random-32* ( tuple -- r ) 4 random-bytes* le> ;
  26
  27 ERROR: no-random-number-generator ;
  28
  29 M: no-random-number-generator summary
  30     drop "Random number generator is not defined." ;
  31
  32 M: f random-bytes* ( n obj -- * ) no-random-number-generator ;
  33
  34 M: f random-32* ( obj -- * ) no-random-number-generator ;
  35
  36 : random-bytes ( n -- byte-array )
  37     random-generator get random-bytes* ;
  38
  39 <PRIVATE
  40
  41 : random-integer ( n -- n' )
  42     dup log2 7 + 8 /i 1 +
  43     [ random-bytes >byte-array byte-array>bignum ]
  44     [ 3 shift 2^ ] bi / * >integer ;
  45
  46 PRIVATE>
  47
  48 : random-bits ( numbits -- r ) 2^ random-integer ;
  49
  50 : random-bits* ( numbits -- n )
  51     1 - [ random-bits ] keep set-bit ;
  52
  53 : random ( seq -- elt )
  54     [ f ] [
  55         [ length random-integer ] keep nth
  56     ] if-empty ;
  57
  58 : randomize ( seq -- seq )
  59     dup length [ dup 1 > ]
  60     [ [ iota random ] [ 1 - ] bi [ pick exchange ] keep ]
  61     while drop ;
  62
  63 : delete-random ( seq -- elt )
  64     [ length random-integer ] keep [ nth ] 2keep delete-nth ;
  65
  66 : with-random ( tuple quot -- )
  67     random-generator swap with-variable ; inline
  68
  69 : with-system-random ( quot -- )
  70     system-random-generator get swap with-random ; inline
  71
  72 : with-secure-random ( quot -- )
  73     secure-random-generator get swap with-random ; inline
  74
  75 : uniform-random-float ( min max -- n )
  76     4 random-bytes underlying>> *uint >float
  77     4 random-bytes underlying>> *uint >float
  78     2.0 32 ^ * +
  79     [ over - 2.0 -64 ^ * ] dip
  80     * + ; inline
  81
  82 : normal-random-float ( mean sigma -- n )
  83     0.0 1.0 uniform-random-float
  84     0.0 1.0 uniform-random-float
  85     [ 2 pi * * cos ]
  86     [ 1.0 swap - log -2.0 * sqrt ]
  87     bi* * * + ;
  88
  89 {
  90     { [ os windows? ] [ "random.windows" require ] }
  91     { [ os unix? ] [ "random.unix" require ] }
  92 } cond
  93
  94 "random.mersenne-twister" require