basis/random/random.factor

   1 ! Copyright (C) 2008 Doug Coleman.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors alien.c-types alien.data arrays assocs
   4 byte-arrays byte-vectors combinators combinators.short-circuit
   5 fry io.backend io.binary kernel locals math math.bitwise
   6 math.constants math.functions math.order math.ranges namespaces
   7 sequences sequences.private sets summary system vocabs hints
   8 typed ;
   9 IN: random
  10
  11 SYMBOL: system-random-generator
  12 SYMBOL: secure-random-generator
  13 SYMBOL: random-generator
  14
  15 GENERIC# seed-random 1 ( tuple seed -- tuple' )
  16 GENERIC: random-32* ( tuple -- r )
  17 GENERIC: random-bytes* ( n tuple -- byte-array )
  18
  19 M: object random-bytes* ( n tuple -- byte-array )
  20     [ [ <byte-vector> ] keep 4 /mod ] dip
  21     [ pick '[ _ random-32* int <ref> _ push-all ] times ]
  22     [
  23         over zero?
  24         [ 2drop ] [ random-32* int <ref> swap head append! ] if
  25     ] bi-curry bi* B{ } like ;
  26
  27 HINTS: M\ object random-bytes* { fixnum object } ;
  28
  29 M: object random-32* ( tuple -- r ) 4 swap random-bytes* be> ;
  30
  31 ERROR: no-random-number-generator ;
  32
  33 M: no-random-number-generator summary
  34     drop "Random number generator is not defined." ;
  35
  36 M: f random-bytes* ( n obj -- * ) no-random-number-generator ;
  37
  38 M: f random-32* ( obj -- * ) no-random-number-generator ;
  39
  40 : random-32 ( -- n ) random-generator get random-32* ;
  41
  42 TYPED: random-bytes ( n: fixnum -- byte-array: byte-array )
  43     random-generator get random-bytes* ; inline
  44
  45 <PRIVATE
  46
  47 : (random-integer) ( bits -- n required-bits )
  48     [ random-32 32 ] dip 32 - [ dup 0 > ] [
  49         [ 32 shift random-32 + ] [ 32 + ] [ 32 - ] tri*
  50     ] while drop ;
  51
  52 : random-integer ( n -- n' )
  53     dup next-power-of-2 log2 (random-integer)
  54     [ * ] [ 2^ /i ] bi* ;
  55
  56 PRIVATE>
  57
  58 : random-bits ( numbits -- r ) 2^ random-integer ;
  59
  60 : random-bits* ( numbits -- n )
  61     1 - [ random-bits ] keep set-bit ;
  62
  63 GENERIC: random ( obj -- elt )
  64
  65 M: integer random [ f ] [ random-integer ] if-zero ;
  66
  67 M: sequence random
  68     [ f ] [
  69         [ length random-integer ] keep nth
  70     ] if-empty ;
  71
  72 : randomize-n-last ( seq n -- seq )
  73     [ dup length dup ] dip - 1 max '[ dup _ > ]
  74     [ [ random ] [ 1 - ] bi [ pick exchange-unsafe ] keep ]
  75     while drop ;
  76
  77 : randomize ( seq -- randomized )
  78     dup length randomize-n-last ;
  79
  80 ERROR: too-many-samples seq n ;
  81
  82 : sample ( seq n -- seq' )
  83     2dup [ length ] dip < [ too-many-samples ] when
  84     [ [ length iota >array ] dip [ randomize-n-last ] keep tail-slice* ]
  85     [ drop ] 2bi nths ;
  86
  87 : delete-random ( seq -- elt )
  88     [ length random-integer ] keep [ nth ] 2keep remove-nth! drop ;
  89
  90 : with-random ( tuple quot -- )
  91     random-generator swap with-variable ; inline
  92
  93 : with-system-random ( quot -- )
  94     system-random-generator get swap with-random ; inline
  95
  96 : with-secure-random ( quot -- )
  97     secure-random-generator get swap with-random ; inline
  98
  99 : uniform-random-float ( min max -- n )
 100     4 random-bytes uint deref >float
 101     4 random-bytes uint deref >float
 102     2.0 32 ^ * +
 103     [ over - 2.0 -64 ^ * ] dip
 104     * + ; inline
 105
 106 : random-unit ( -- n )
 107     0.0 1.0 uniform-random-float ; inline
 108
 109 : (cos-random-float) ( -- n )
 110     0. 2pi uniform-random-float cos ;
 111
 112 : (log-sqrt-random-float) ( -- n )
 113     random-unit log -2. * sqrt ;
 114
 115 : normal-random-float ( mean sigma -- n )
 116     (cos-random-float) (log-sqrt-random-float) * * + ;
 117
 118 : lognormal-random-float ( mean sigma -- n )
 119     normal-random-float exp ;
 120
 121 : exponential-random-float ( lambda -- n )
 122     random-unit log neg swap / ;
 123
 124 : weibull-random-float ( alpha beta -- n )
 125     [
 126         [ random-unit log neg ] dip
 127         1. swap / ^
 128     ] dip * ;
 129
 130 : pareto-random-float ( k alpha -- n )
 131     [ random-unit ] dip recip ^ /f ;
 132
 133 :: (gamma-random-float>1) ( alpha beta -- n )
 134     ! Uses R.C.H. Cheng, "The generation of Gamma
 135     ! variables with non-integral shape parameters",
 136     ! Applied Statistics, (1977), 26, No. 1, p71-74
 137     2. alpha * 1 - sqrt :> ainv
 138     alpha 4. log -      :> bbb
 139     alpha ainv +        :> ccc
 140
 141     0 :> r! 0 :> z! 0 :> result! ! initialize locals
 142     [
 143         r {
 144             [ 1. 4.5 log + + z 4.5 * - 0 >= ]
 145             [ z log >= ]
 146         } 1|| not
 147     ] [
 148         random-unit :> u1
 149         random-unit :> u2
 150
 151         u1 1. u1 - / log ainv / :> v
 152         alpha v exp *           :> x
 153         u1 sq u2 *              z!
 154         bbb ccc v * + x -       r!
 155
 156         x beta *                result!
 157     ] do while result ;
 158
 159 : (gamma-random-float=1) ( alpha beta -- n )
 160     nip random-unit log neg * ;
 161
 162 :: (gamma-random-float<1) ( alpha beta -- n )
 163     ! Uses ALGORITHM GS of Statistical Computing - Kennedy & Gentle
 164     alpha e + e / :> b
 165
 166     0 :> x! 0 :> p! ! initialize locals
 167     [
 168         p 1.0 > [
 169             random-unit x alpha 1 - ^ >
 170         ] [
 171             random-unit x neg exp >
 172         ] if
 173     ] [
 174         random-unit b * p!
 175         p 1.0 <= [
 176             p 1. alpha / ^
 177         ] [
 178             b p - alpha / log neg
 179         ] if x!
 180     ] do while x beta * ;
 181
 182 : gamma-random-float ( alpha beta -- n )
 183     {
 184         { [ over 1 > ] [ (gamma-random-float>1) ] }
 185         { [ over 1 = ] [ (gamma-random-float=1) ] }
 186         [ (gamma-random-float<1) ]
 187     } cond ;
 188
 189 : beta-random-float ( alpha beta -- n )
 190     [ 1. gamma-random-float ] dip over zero?
 191     [ 2drop 0 ] [ 1. gamma-random-float dupd + / ] if ;
 192
 193 :: von-mises-random-float ( mu kappa -- n )
 194     ! Based upon an algorithm published in: Fisher, N.I.,
 195     ! "Statistical Analysis of Circular Data", Cambridge
 196     ! University Press, 1993.
 197     kappa 1e-6 <= [
 198         2pi random-unit *
 199     ] [
 200         4. kappa sq * 1. + sqrt 1. + :> a
 201         a 2. a * sqrt - 2. kappa * / :> b
 202         b sq 1. + 2. b * /           :> r
 203
 204         0 :> c! 0 :> _f! ! initialize locals
 205         [
 206             random-unit {
 207                 [ 2. c - c * < ] [ 1. c - exp c * <= ]
 208             } 1|| not
 209         ] [
 210             random-unit pi * cos :> z
 211             r z * 1. + r z + /   _f!
 212             r _f - kappa *       c!
 213         ] do while
 214
 215         mu 2pi mod _f cos random-unit 0.5 > [ + ] [ - ] if
 216     ] if ;
 217
 218 :: (triangular-random-float) ( low high mode -- n )
 219     mode low - high low - / :> c!
 220     random-unit :> u!
 221     high low
 222     u c > [ 1. u - u! 1. c - c! swap ] when
 223     [ - u c * sqrt * ] keep + ;
 224
 225 : triangular-random-float ( low high -- n )
 226     2dup + 2 /f (triangular-random-float) ;
 227
 228 : laplace-random-float ( mean scale -- n )
 229     random-unit dup 0.5 <
 230     [ 2 * log ] [ 1 swap - 2 * log neg ] if * + ;
 231
 232 : cauchy-random-float ( median scale -- n )
 233     random-unit 0.5 - pi * tan * + ;
 234
 235 : chi-square-random-float ( dof -- n )
 236     [ 0.5 ] dip 2 * gamma-random-float ;
 237
 238 : student-t-random-float ( dof -- n )
 239     [ 0 1 normal-random-float ] dip
 240     [ chi-square-random-float ] [ / ] bi sqrt / ;
 241
 242 : inv-gamma-random-float ( shape scale -- n )
 243     recip gamma-random-float recip ;
 244
 245 : rayleigh-random-float ( mode -- n )
 246     random-unit log -2 * sqrt * ;
 247
 248 : gumbel-random-float ( loc scale -- n )
 249     random-unit log neg log * - ;
 250
 251 : logistic-random-float ( loc scale -- n )
 252     random-unit dup 1 swap - / log * + ;
 253
 254 : power-random-float ( alpha -- n )
 255     [ random-unit log exp 1 swap - ] dip recip ^ ;
 256
 257 {
 258     { [ os windows? ] [ "random.windows" require ] }
 259     { [ os unix? ] [ "random.unix" require ] }
 260 } cond
 261
 262 "random.mersenne-twister" require