basis/random/random.factor

   1 ! Copyright (C) 2008 Doug Coleman.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: alien.c-types kernel math namespaces sequences
   4 io.backend io.binary combinators system vocabs.loader
   5 summary math.bitwise byte-vectors fry byte-arrays ;
   6 IN: random
   7
   8 SYMBOL: system-random-generator
   9 SYMBOL: secure-random-generator
  10 SYMBOL: random-generator
  11
  12 GENERIC: seed-random ( tuple seed -- )
  13 GENERIC: random-32* ( tuple -- r )
  14 GENERIC: random-bytes* ( n tuple -- byte-array )
  15
  16 M: object random-bytes* ( n tuple -- byte-array )
  17     [ [ <byte-vector> ] keep 4 /mod ] dip tuck
  18     [ pick '[ _ random-32* 4 >le _ push-all ] times ]
  19     [
  20         over zero?
  21         [ 2drop ] [ random-32* 4 >le swap head over push-all ] if
  22     ] 2bi* ;
  23
  24 M: object random-32* ( tuple -- r ) 4 random-bytes* le> ;
  25
  26 ERROR: no-random-number-generator ;
  27
  28 M: no-random-number-generator summary
  29     drop "Random number generator is not defined." ;
  30
  31 M: f random-bytes* ( n obj -- * ) no-random-number-generator ;
  32
  33 M: f random-32* ( obj -- * ) no-random-number-generator ;
  34
  35 : random-bytes ( n -- byte-array )
  36     random-generator get random-bytes* ;
  37
  38 <PRIVATE
  39
  40 : random-integer ( n -- n' )
  41     dup log2 7 + 8 /i 1+
  42     [ random-bytes >byte-array byte-array>bignum ]
  43     [ 3 shift 2^ ] bi / * >integer ;
  44
  45 PRIVATE>
  46
  47 : random-bits ( n -- r ) 2^ random-integer ;
  48
  49 : random ( seq -- elt )
  50     [ f ] [
  51         [ length random-integer ] keep nth
  52     ] if-empty ;
  53
  54 : delete-random ( seq -- elt )
  55     [ length random-integer ] keep [ nth ] 2keep delete-nth ;
  56
  57 : with-random ( tuple quot -- )
  58     random-generator swap with-variable ; inline
  59
  60 : with-system-random ( quot -- )
  61     system-random-generator get swap with-random ; inline
  62
  63 : with-secure-random ( quot -- )
  64     secure-random-generator get swap with-random ; inline
  65
  66 USE: vocabs.loader
  67
  68 {
  69     { [ os windows? ] [ "random.windows" require ] }
  70     { [ os unix? ] [ "random.unix" require ] }
  71 } cond
  72
  73 "random.mersenne-twister" require