basis/regexp/classes/classes.factor

   1 ! Copyright (C) 2008, 2009 Doug Coleman, Daniel Ehrenberg.
   2 ! See https://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays assocs classes combinators
   4 combinators.short-circuit combinators.smart kernel math
   5 math.order sequences sets unicode unicode.data ;
   6 FROM: ascii => ascii? ;
   7 IN: regexp.classes
   8
   9 SINGLETONS: dot letter-class LETTER-class Letter-class digit-class
  10 alpha-class non-newline-blank-class
  11 ascii-class punctuation-class java-printable-class blank-class
  12 control-character-class hex-digit-class java-blank-class c-identifier-class
  13 unmatchable-class terminator-class word-boundary-class ;
  14
  15 SINGLETONS: beginning-of-input ^crlf end-of-input $crlf end-of-file
  16 ^unix $unix word-break ;
  17
  18 TUPLE: range-class { from read-only } { to read-only } ;
  19 C: <range-class> range-class
  20
  21 TUPLE: primitive-class { class read-only } ;
  22 C: <primitive-class> primitive-class
  23
  24 TUPLE: category-class { category read-only } ;
  25 C: <category-class> category-class
  26
  27 TUPLE: category-range-class { category read-only } ;
  28 C: <category-range-class> category-range-class
  29
  30 TUPLE: script-class { script read-only } ;
  31 C: <script-class> script-class
  32
  33 GENERIC: class-member? ( obj class -- ? )
  34
  35 M: t class-member? 2drop t ; inline
  36
  37 M: integer class-member? = ; inline
  38
  39 M: range-class class-member?
  40     [ from>> ] [ to>> ] bi between? ; inline
  41
  42 M: letter-class class-member?
  43     drop letter? ; inline
  44
  45 M: LETTER-class class-member?
  46     drop LETTER? ; inline
  47
  48 M: Letter-class class-member?
  49     drop Letter? ; inline
  50
  51 M: ascii-class class-member?
  52     drop ascii? ; inline
  53
  54 M: digit-class class-member?
  55     drop digit? ; inline
  56
  57 : c-identifier-char? ( ch -- ? )
  58     { [ alpha? ] [ CHAR: _ = ] } 1|| ;
  59
  60 M: c-identifier-class class-member?
  61     drop c-identifier-char? ; inline
  62
  63 M: alpha-class class-member?
  64     drop alpha? ; inline
  65
  66 : punct? ( ch -- ? )
  67     "!\"#$%&'()*+,-./:;<=>?@[\\]^_`{|}~" member? ;
  68
  69 M: punctuation-class class-member?
  70     drop punct? ; inline
  71
  72 : java-printable? ( ch -- ? )
  73     { [ alpha? ] [ punct? ] } 1|| ;
  74
  75 M: java-printable-class class-member?
  76     drop java-printable? ; inline
  77
  78 M: non-newline-blank-class class-member?
  79     drop { [ blank? ] [ CHAR: \n = not ] } 1&& ; inline
  80
  81 M: control-character-class class-member?
  82     drop control? ; inline
  83
  84 : hex-digit? ( ch -- ? )
  85     {
  86         [ CHAR: A CHAR: F between? ]
  87         [ CHAR: a CHAR: f between? ]
  88         [ CHAR: 0 CHAR: 9 between? ]
  89     } 1|| ;
  90
  91 M: hex-digit-class class-member?
  92     drop hex-digit? ; inline
  93
  94 : java-blank? ( ch -- ? )
  95     {
  96         CHAR: \s CHAR: \t CHAR: \n
  97         CHAR: \v CHAR: \a CHAR: \r
  98     } member? ;
  99
 100 M: java-blank-class class-member?
 101     drop java-blank? ; inline
 102
 103 M: unmatchable-class class-member?
 104     2drop f ; inline
 105
 106 M: terminator-class class-member?
 107     drop "\r\n\u000085\u002029\u002028" member? ; inline
 108
 109 M: f class-member? 2drop f ; inline
 110
 111 M: script-class class-member?
 112     [ script-of ] [ script>> ] bi* = ; inline
 113
 114 M: category-class class-member?
 115     [ category ] [ category>> ] bi* = ; inline
 116
 117 M: category-range-class class-member? inline
 118     [ category first ] [ category>> ] bi* = ; inline
 119
 120 TUPLE: not-class { class read-only } ;
 121
 122 PREDICATE: not-integer < not-class class>> integer? ;
 123
 124 UNION: simple-class
 125     primitive-class range-class dot ;
 126 PREDICATE: not-simple < not-class class>> simple-class? ;
 127
 128 M: not-class class-member?
 129     class>> class-member? not ; inline
 130
 131 TUPLE: or-class { seq read-only } ;
 132
 133 M: or-class class-member?
 134     seq>> [ class-member? ] with any? ; inline
 135
 136 TUPLE: and-class { seq read-only } ;
 137
 138 M: and-class class-member?
 139     seq>> [ class-member? ] with all? ; inline
 140
 141 DEFER: (substitute)
 142
 143 : flatten ( seq class -- newseq )
 144     '[ dup _ instance? [ seq>> ] [ 1array ] if ] map concat ; inline
 145
 146 :: sequence>instance ( seq empty class -- instance )
 147     seq length {
 148         { 0 [ empty ] }
 149         { 1 [ seq first ] }
 150         [ drop seq { } like class boa ]
 151     } case ; inline
 152
 153 TUPLE: class-partition integers not-integers simples not-simples and or other ;
 154
 155 : partition-classes ( seq -- class-partition )
 156     members
 157     [ integer? ] partition
 158     [ not-integer? ] partition
 159     [ simple-class? ] partition
 160     [ not-simple? ] partition
 161     [ and-class? ] partition
 162     [ or-class? ] partition
 163     class-partition boa ;
 164
 165 : class-partition>sequence ( class-partition -- seq )
 166     {
 167         [ integers>> ]
 168         [ not-integers>> ]
 169         [ simples>> ]
 170         [ not-simples>> ]
 171         [ and>> ]
 172         [ or>> ]
 173         [ other>> ]
 174     } cleave>array concat ;
 175
 176 : repartition ( partition -- partition' )
 177     ! This could be made more efficient; only and and or are effected
 178     class-partition>sequence partition-classes ;
 179
 180 : filter-not-integers ( partition -- partition' )
 181     dup
 182     [ simples>> ] [ not-simples>> ] [ or>> ] tri
 183     3append and-class boa
 184     '[ [ class>> _ class-member? ] filter ] change-not-integers ;
 185
 186 : answer-ors ( partition -- partition' )
 187     dup [ not-integers>> ] [ not-simples>> ] [ simples>> ] tri 3append
 188     '[ [ _ [ t (substitute) ] each ] map ] change-or ;
 189
 190 : contradiction? ( partition -- ? )
 191     {
 192         [ [ simples>> ] [ not-simples>> ] bi intersects? ]
 193         [ other>> f swap member? ]
 194     } 1|| ;
 195
 196 : make-and-class ( partition -- and-class )
 197     answer-ors repartition
 198     [ t swap remove ] change-other
 199     dup contradiction?
 200     [ drop f ]
 201     [ filter-not-integers class-partition>sequence members t and-class sequence>instance ] if ;
 202
 203 : <and-class> ( seq -- class )
 204     dup and-class flatten partition-classes
 205     dup integers>> length {
 206         { 0 [ nip make-and-class ] }
 207         { 1 [ integers>> first [ '[ _ swap class-member? ] all? ] keep and ] }
 208         [ 3drop f ]
 209     } case ;
 210
 211 : filter-integers ( partition -- partition' )
 212     dup
 213     [ simples>> ] [ not-simples>> ] [ and>> ] tri
 214     3append or-class boa
 215     '[ [ _ class-member? ] reject ] change-integers ;
 216
 217 : answer-ands ( partition -- partition' )
 218     dup [ integers>> ] [ not-simples>> ] [ simples>> ] tri 3append
 219     '[ [ _ [ f (substitute) ] each ] map ] change-and ;
 220
 221 : tautology? ( partition -- ? )
 222     {
 223         [ [ simples>> ] [ not-simples>> ] bi intersects? ]
 224         [ other>> t swap member? ]
 225     } 1|| ;
 226
 227 : make-or-class ( partition -- and-class )
 228     answer-ands repartition
 229     [ f swap remove ] change-other
 230     dup tautology?
 231     [ drop t ]
 232     [ filter-integers class-partition>sequence members f or-class sequence>instance ] if ;
 233
 234 : <or-class> ( seq -- class )
 235     dup or-class flatten partition-classes
 236     dup not-integers>> length {
 237         { 0 [ nip make-or-class ] }
 238         { 1 [
 239             not-integers>> first
 240             [ class>> '[ _ swap class-member? ] any? ] keep or
 241         ] }
 242         [ 3drop t ]
 243     } case ;
 244
 245 GENERIC: <not-class> ( class -- inverse )
 246
 247 M: object <not-class>
 248     not-class boa ;
 249
 250 M: not-class <not-class>
 251     class>> ;
 252
 253 M: and-class <not-class>
 254     seq>> [ <not-class> ] map <or-class> ;
 255
 256 M: or-class <not-class>
 257     seq>> [ <not-class> ] map <and-class> ;
 258
 259 M: t <not-class> drop f ;
 260 M: f <not-class> drop t ;
 261
 262 : <minus-class> ( a b -- a-b )
 263     <not-class> 2array <and-class> ;
 264
 265 : <sym-diff-class> ( a b -- a~b )
 266     2array [ <or-class> ] [ <and-class> ] bi <minus-class> ;
 267
 268 M: primitive-class class-member?
 269     class>> class-member? ; inline
 270
 271 TUPLE: condition question yes no ;
 272 C: <condition> condition
 273
 274 GENERIC#: answer 2 ( class from to -- new-class )
 275
 276 M:: object answer ( class from to -- new-class )
 277     class from = to class ? ;
 278
 279 : replace-compound ( class from to -- seq )
 280     [ seq>> ] 2dip '[ _ _ answer ] map ;
 281
 282 M: and-class answer
 283     replace-compound <and-class> ;
 284
 285 M: or-class answer
 286     replace-compound <or-class> ;
 287
 288 M: not-class answer
 289     [ class>> ] 2dip answer <not-class> ;
 290
 291 GENERIC#: (substitute) 1 ( class from to -- new-class )
 292 M: object (substitute) answer ;
 293 M: not-class (substitute) [ <not-class> ] bi@ answer ;
 294
 295 : assoc-answer ( table question answer -- new-table )
 296     '[ _ _ (substitute) ] assoc-map sift-values ;
 297
 298 : assoc-answers ( table questions answer -- new-table )
 299     '[ _ assoc-answer ] each ;
 300
 301 DEFER: make-condition
 302
 303 : (make-condition) ( table questions question -- condition )
 304     [ 2nip ]
 305     [ swap [ t assoc-answer ] dip make-condition ]
 306     [ swap [ f assoc-answer ] dip make-condition ] 3tri
 307     2dup = [ 2nip ] [ <condition> ] if ;
 308
 309 : make-condition ( table questions -- condition )
 310     [ keys ] [ unclip (make-condition) ] if-empty ;
 311
 312 GENERIC: class>questions ( class -- questions )
 313 : compound-questions ( class -- questions ) seq>> [ class>questions ] gather ;
 314 M: or-class class>questions compound-questions ;
 315 M: and-class class>questions compound-questions ;
 316 M: not-class class>questions class>> class>questions ;
 317 M: object class>questions 1array ;
 318
 319 : table>questions ( table -- questions )
 320     values [ class>questions ] gather >array t swap remove ;
 321
 322 : table>condition ( table -- condition )
 323     ! input table is state => class
 324     >alist dup table>questions make-condition ;
 325
 326 : condition-map ( condition quot: ( obj -- obj' ) -- new-condition )
 327     over condition? [
 328         [ [ question>> ] [ yes>> ] [ no>> ] tri ] dip
 329         '[ _ condition-map ] bi@ <condition>
 330     ] [ call ] if ; inline recursive
 331
 332 : condition-states ( condition -- states )
 333     dup condition? [
 334         [ yes>> ] [ no>> ] bi
 335         [ condition-states ] bi@ union
 336     ] [ 1array ] if ;
 337
 338 : condition-at ( condition assoc -- new-condition )
 339     '[ _ at ] condition-map ;