basis/regexp/classes/classes.factor

   1 ! Copyright (C) 2008, 2009 Doug Coleman, Daniel Ehrenberg.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel math math.order words combinators
   4 combinators.smart combinators.short-circuit locals
   5 unicode.categories sequences fry macros arrays assocs sets
   6 classes unicode.script unicode.data ;
   7 FROM: ascii => ascii? ;
   8 FROM: sets => members ;
   9 IN: regexp.classes
  10
  11 SINGLETONS: dot letter-class LETTER-class Letter-class digit-class
  12 alpha-class non-newline-blank-class
  13 ascii-class punctuation-class java-printable-class blank-class
  14 control-character-class hex-digit-class java-blank-class c-identifier-class
  15 unmatchable-class terminator-class word-boundary-class ;
  16
  17 SINGLETONS: beginning-of-input ^ end-of-input $ end-of-file
  18 ^unix $unix word-break ;
  19
  20 TUPLE: range-class from to ;
  21 C: <range-class> range-class
  22
  23 TUPLE: primitive-class class ;
  24 C: <primitive-class> primitive-class
  25
  26 TUPLE: category-class category ;
  27 C: <category-class> category-class
  28
  29 TUPLE: category-range-class category ;
  30 C: <category-range-class> category-range-class
  31
  32 TUPLE: script-class script ;
  33 C: <script-class> script-class
  34
  35 GENERIC: class-member? ( obj class -- ? )
  36
  37 M: t class-member? ( obj class -- ? ) 2drop t ;
  38
  39 M: integer class-member? ( obj class -- ? ) = ;
  40
  41 M: range-class class-member? ( obj class -- ? )
  42     [ from>> ] [ to>> ] bi between? ;
  43
  44 M: letter-class class-member? ( obj class -- ? )
  45     drop letter? ;
  46
  47 M: LETTER-class class-member? ( obj class -- ? )
  48     drop LETTER? ;
  49
  50 M: Letter-class class-member? ( obj class -- ? )
  51     drop Letter? ;
  52
  53 M: ascii-class class-member? ( obj class -- ? )
  54     drop ascii? ;
  55
  56 M: digit-class class-member? ( obj class -- ? )
  57     drop digit? ;
  58
  59 : c-identifier-char? ( ch -- ? )
  60     { [ alpha? ] [ CHAR: _ = ] } 1|| ;
  61
  62 M: c-identifier-class class-member? ( obj class -- ? )
  63     drop c-identifier-char? ;
  64
  65 M: alpha-class class-member? ( obj class -- ? )
  66     drop alpha? ;
  67
  68 : punct? ( ch -- ? )
  69     "!\"#$%&'()*+,-./:;<=>?@[\\]^_`{|}~" member? ;
  70
  71 M: punctuation-class class-member? ( obj class -- ? )
  72     drop punct? ;
  73
  74 : java-printable? ( ch -- ? )
  75     { [ alpha? ] [ punct? ] } 1|| ;
  76
  77 M: java-printable-class class-member? ( obj class -- ? )
  78     drop java-printable? ;
  79
  80 M: non-newline-blank-class class-member? ( obj class -- ? )
  81     drop { [ blank? ] [ CHAR: \n = not ] } 1&& ;
  82
  83 M: control-character-class class-member? ( obj class -- ? )
  84     drop control? ;
  85
  86 : hex-digit? ( ch -- ? )
  87     {
  88         [ CHAR: A CHAR: F between? ]
  89         [ CHAR: a CHAR: f between? ]
  90         [ CHAR: 0 CHAR: 9 between? ]
  91     } 1|| ;
  92
  93 M: hex-digit-class class-member? ( obj class -- ? )
  94     drop hex-digit? ;
  95
  96 : java-blank? ( ch -- ? )
  97     {
  98         CHAR: \s CHAR: \t CHAR: \n
  99         0xb 0x7 CHAR: \r
 100     } member? ;
 101
 102 M: java-blank-class class-member? ( obj class -- ? )
 103     drop java-blank? ;
 104
 105 M: unmatchable-class class-member? ( obj class -- ? )
 106     2drop f ;
 107
 108 M: terminator-class class-member? ( obj class -- ? )
 109     drop "\r\n\u000085\u002029\u002028" member? ;
 110
 111 M: f class-member? 2drop f ;
 112
 113 : same? ( obj1 obj2 quot1: ( obj1 -- val1 ) quot2: ( obj2 -- val2 ) -- ? )
 114     bi* = ; inline
 115
 116 M: script-class class-member?
 117     [ script-of ] [ script>> ] same? ;
 118
 119 M: category-class class-member?
 120     [ category ] [ category>> ] same? ;
 121
 122 M: category-range-class class-member?
 123     [ category first ] [ category>> ] same? ;
 124
 125 TUPLE: not-class class ;
 126
 127 PREDICATE: not-integer < not-class class>> integer? ;
 128
 129 UNION: simple-class
 130     primitive-class range-class dot ;
 131 PREDICATE: not-simple < not-class class>> simple-class? ;
 132
 133 M: not-class class-member?
 134     class>> class-member? not ;
 135
 136 TUPLE: or-class seq ;
 137
 138 M: or-class class-member?
 139     seq>> [ class-member? ] with any? ;
 140
 141 TUPLE: and-class seq ;
 142
 143 M: and-class class-member?
 144     seq>> [ class-member? ] with all? ;
 145
 146 DEFER: substitute
 147
 148 : flatten ( seq class -- newseq )
 149     '[ dup _ instance? [ seq>> ] [ 1array ] if ] map concat ; inline
 150
 151 :: seq>instance ( seq empty class -- instance )
 152     seq length {
 153         { 0 [ empty ] }
 154         { 1 [ seq first ] }
 155         [ drop class new seq { } like >>seq ]
 156     } case ; inline
 157
 158 TUPLE: class-partition integers not-integers simples not-simples and or other ;
 159
 160 : partition-classes ( seq -- class-partition )
 161     members
 162     [ integer? ] partition
 163     [ not-integer? ] partition
 164     [ simple-class? ] partition
 165     [ not-simple? ] partition
 166     [ and-class? ] partition
 167     [ or-class? ] partition
 168     class-partition boa ;
 169
 170 : class-partition>seq ( class-partition -- seq )
 171     [
 172         {
 173             [ integers>> ]
 174             [ not-integers>> ]
 175             [ simples>> ]
 176             [ not-simples>> ]
 177             [ and>> ]
 178             [ or>> ]
 179             [ other>> ]
 180         } cleave
 181     ] output>array concat ;
 182
 183 : repartition ( partition -- partition' )
 184     ! This could be made more efficient; only and and or are effected
 185     class-partition>seq partition-classes ;
 186
 187 : filter-not-integers ( partition -- partition' )
 188     dup
 189     [ simples>> ] [ not-simples>> ] [ or>> ] tri
 190     3append and-class boa
 191     '[ [ class>> _ class-member? ] filter ] change-not-integers ;
 192
 193 : answer-ors ( partition -- partition' )
 194     dup [ not-integers>> ] [ not-simples>> ] [ simples>> ] tri 3append
 195     '[ [ _ [ t substitute ] each ] map ] change-or ;
 196
 197 : contradiction? ( partition -- ? )
 198     {
 199         [ [ simples>> ] [ not-simples>> ] bi intersects? ]
 200         [ other>> f swap member? ]
 201     } 1|| ;
 202
 203 : make-and-class ( partition -- and-class )
 204     answer-ors repartition
 205     [ t swap remove ] change-other
 206     dup contradiction?
 207     [ drop f ]
 208     [ filter-not-integers class-partition>seq members t and-class seq>instance ] if ;
 209
 210 : <and-class> ( seq -- class )
 211     dup and-class flatten partition-classes
 212     dup integers>> length {
 213         { 0 [ nip make-and-class ] }
 214         { 1 [ integers>> first [ '[ _ swap class-member? ] all? ] keep and ] }
 215         [ 3drop f ]
 216     } case ;
 217
 218 : filter-integers ( partition -- partition' )
 219     dup
 220     [ simples>> ] [ not-simples>> ] [ and>> ] tri
 221     3append or-class boa
 222     '[ [ _ class-member? not ] filter ] change-integers ;
 223
 224 : answer-ands ( partition -- partition' )
 225     dup [ integers>> ] [ not-simples>> ] [ simples>> ] tri 3append
 226     '[ [ _ [ f substitute ] each ] map ] change-and ;
 227
 228 : tautology? ( partition -- ? )
 229     {
 230         [ [ simples>> ] [ not-simples>> ] bi intersects? ]
 231         [ other>> t swap member? ]
 232     } 1|| ;
 233
 234 : make-or-class ( partition -- and-class )
 235     answer-ands repartition
 236     [ f swap remove ] change-other
 237     dup tautology?
 238     [ drop t ]
 239     [ filter-integers class-partition>seq members f or-class seq>instance ] if ;
 240
 241 : <or-class> ( seq -- class )
 242     dup or-class flatten partition-classes
 243     dup not-integers>> length {
 244         { 0 [ nip make-or-class ] }
 245         { 1 [
 246             not-integers>> first
 247             [ class>> '[ _ swap class-member? ] any? ] keep or
 248         ] }
 249         [ 3drop t ]
 250     } case ;
 251
 252 GENERIC: <not-class> ( class -- inverse )
 253
 254 M: object <not-class>
 255     not-class boa ;
 256
 257 M: not-class <not-class>
 258     class>> ;
 259
 260 M: and-class <not-class>
 261     seq>> [ <not-class> ] map <or-class> ;
 262
 263 M: or-class <not-class>
 264     seq>> [ <not-class> ] map <and-class> ;
 265
 266 M: t <not-class> drop f ;
 267 M: f <not-class> drop t ;
 268
 269 : <minus-class> ( a b -- a-b )
 270     <not-class> 2array <and-class> ;
 271
 272 : <sym-diff-class> ( a b -- a~b )
 273     2array [ <or-class> ] [ <and-class> ] bi <minus-class> ;
 274
 275 M: primitive-class class-member?
 276     class>> class-member? ;
 277
 278 TUPLE: condition question yes no ;
 279 C: <condition> condition
 280
 281 GENERIC# answer 2 ( class from to -- new-class )
 282
 283 M:: object answer ( class from to -- new-class )
 284     class from = to class ? ;
 285
 286 : replace-compound ( class from to -- seq )
 287     [ seq>> ] 2dip '[ _ _ answer ] map ;
 288
 289 M: and-class answer
 290     replace-compound <and-class> ;
 291
 292 M: or-class answer
 293     replace-compound <or-class> ;
 294
 295 M: not-class answer
 296     [ class>> ] 2dip answer <not-class> ;
 297
 298 GENERIC# substitute 1 ( class from to -- new-class )
 299 M: object substitute answer ;
 300 M: not-class substitute [ <not-class> ] bi@ answer ;
 301
 302 : assoc-answer ( table question answer -- new-table )
 303     '[ _ _ substitute ] assoc-map
 304     [ nip ] assoc-filter ;
 305
 306 : assoc-answers ( table questions answer -- new-table )
 307     '[ _ assoc-answer ] each ;
 308
 309 DEFER: make-condition
 310
 311 : (make-condition) ( table questions question -- condition )
 312     [ 2nip ]
 313     [ swap [ t assoc-answer ] dip make-condition ]
 314     [ swap [ f assoc-answer ] dip make-condition ] 3tri
 315     2dup = [ 2nip ] [ <condition> ] if ;
 316
 317 : make-condition ( table questions -- condition )
 318     [ keys ] [ unclip (make-condition) ] if-empty ;
 319
 320 GENERIC: class>questions ( class -- questions )
 321 : compound-questions ( class -- questions ) seq>> [ class>questions ] gather ;
 322 M: or-class class>questions compound-questions ;
 323 M: and-class class>questions compound-questions ;
 324 M: not-class class>questions class>> class>questions ;
 325 M: object class>questions 1array ;
 326
 327 : table>questions ( table -- questions )
 328     values [ class>questions ] gather >array t swap remove ;
 329
 330 : table>condition ( table -- condition )
 331     ! input table is state => class
 332     >alist dup table>questions make-condition ;
 333
 334 : condition-map ( condition quot: ( obj -- obj' ) -- new-condition )
 335     over condition? [
 336         [ [ question>> ] [ yes>> ] [ no>> ] tri ] dip
 337         '[ _ condition-map ] bi@ <condition>
 338     ] [ call ] if ; inline recursive
 339
 340 : condition-states ( condition -- states )
 341     dup condition? [
 342         [ yes>> ] [ no>> ] bi
 343         [ condition-states ] bi@ union
 344     ] [ 1array ] if ;
 345
 346 : condition-at ( condition assoc -- new-condition )
 347     '[ _ at ] condition-map ;