basis/regexp/classes/classes.factor

   1 ! Copyright (C) 2008, 2009 Doug Coleman, Daniel Ehrenberg.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel math math.order words combinators locals
   4 ascii unicode.categories combinators.short-circuit sequences ;
   5 QUALIFIED-WITH: multi-methods m
   6 IN: regexp.classes
   7
   8 SINGLETONS: any-char any-char-no-nl
   9 letter-class LETTER-class Letter-class digit-class
  10 alpha-class non-newline-blank-class
  11 ascii-class punctuation-class java-printable-class blank-class
  12 control-character-class hex-digit-class java-blank-class c-identifier-class
  13 unmatchable-class terminator-class word-boundary-class ;
  14
  15 SINGLETONS: beginning-of-input ^ end-of-input $ ;
  16
  17 TUPLE: range from to ;
  18 C: <range> range
  19
  20 GENERIC: class-member? ( obj class -- ? )
  21
  22 M: t class-member? ( obj class -- ? ) 2drop t ;
  23
  24 M: integer class-member? ( obj class -- ? ) = ;
  25
  26 M: range class-member? ( obj class -- ? )
  27     [ from>> ] [ to>> ] bi between? ;
  28
  29 M: any-char class-member? ( obj class -- ? )
  30     2drop t ;
  31
  32 M: any-char-no-nl class-member? ( obj class -- ? )
  33     drop CHAR: \n = not ;
  34
  35 M: letter-class class-member? ( obj class -- ? )
  36     drop letter? ;
  37
  38 M: LETTER-class class-member? ( obj class -- ? )
  39     drop LETTER? ;
  40
  41 M: Letter-class class-member? ( obj class -- ? )
  42     drop Letter? ;
  43
  44 M: ascii-class class-member? ( obj class -- ? )
  45     drop ascii? ;
  46
  47 M: digit-class class-member? ( obj class -- ? )
  48     drop digit? ;
  49
  50 : c-identifier-char? ( ch -- ? )
  51     { [ alpha? ] [ CHAR: _ = ] } 1|| ;
  52
  53 M: c-identifier-class class-member? ( obj class -- ? )
  54     drop c-identifier-char? ;
  55
  56 M: alpha-class class-member? ( obj class -- ? )
  57     drop alpha? ;
  58
  59 : punct? ( ch -- ? )
  60     "!\"#$%&'()*+,-./:;<=>?@[\\]^_`{|}~" member? ;
  61
  62 M: punctuation-class class-member? ( obj class -- ? )
  63     drop punct? ;
  64
  65 : java-printable? ( ch -- ? )
  66     { [ alpha? ] [ punct? ] } 1|| ;
  67
  68 M: java-printable-class class-member? ( obj class -- ? )
  69     drop java-printable? ;
  70
  71 M: non-newline-blank-class class-member? ( obj class -- ? )
  72     drop { [ blank? ] [ CHAR: \n = not ] } 1&& ;
  73
  74 M: control-character-class class-member? ( obj class -- ? )
  75     drop control? ;
  76
  77 : hex-digit? ( ch -- ? )
  78     {
  79         [ CHAR: A CHAR: F between? ]
  80         [ CHAR: a CHAR: f between? ]
  81         [ CHAR: 0 CHAR: 9 between? ]
  82     } 1|| ;
  83
  84 M: hex-digit-class class-member? ( obj class -- ? )
  85     drop hex-digit? ;
  86
  87 : java-blank? ( ch -- ? )
  88     {
  89         CHAR: \s CHAR: \t CHAR: \n
  90         HEX: b HEX: 7 CHAR: \r
  91     } member? ;
  92
  93 M: java-blank-class class-member? ( obj class -- ? )
  94     drop java-blank? ;
  95
  96 M: unmatchable-class class-member? ( obj class -- ? )
  97     2drop f ;
  98
  99 M: terminator-class class-member? ( obj class -- ? )
 100     drop "\r\n\u000085\u002029\u002028" member? ;
 101
 102 M: ^ class-member? ( obj class -- ? )
 103     2drop f ;
 104
 105 M: $ class-member? ( obj class -- ? )
 106     2drop f ;
 107
 108 M: f class-member? 2drop f ;
 109
 110 TUPLE: primitive-class class ;
 111 C: <primitive-class> primitive-class
 112
 113 TUPLE: or-class seq ;
 114
 115 TUPLE: not-class class ;
 116
 117 TUPLE: and-class seq ;
 118
 119 m:GENERIC: combine-and ( class1 class2 -- combined ? )
 120
 121 : replace-if-= ( object object -- object ? )
 122     over = ;
 123
 124 m:METHOD: combine-and { object object } replace-if-= ;
 125
 126 m:METHOD: combine-and { integer integer }
 127     2dup = [ drop t ] [ 2drop f t ] if ;
 128
 129 m:METHOD: combine-and { t object }
 130     nip t ;
 131
 132 m:METHOD: combine-and { f object }
 133     drop t ;
 134
 135 m:METHOD: combine-and { not-class object }
 136     [ class>> ] dip = [ f t ] [ f f ] if ;
 137
 138 m:METHOD: combine-and { integer object }
 139     2dup class-member? [ drop t ] [ 2drop f t ] if ;
 140
 141 m:GENERIC: combine-or ( class1 class2 -- combined ? )
 142
 143 m:METHOD: combine-or { object object } replace-if-= ;
 144
 145 m:METHOD: combine-or { integer integer }
 146     2dup = [ drop t ] [ 2drop f f ] if ;
 147
 148 m:METHOD: combine-or { t object }
 149     drop t ;
 150
 151 m:METHOD: combine-or { f object }
 152     nip t ;
 153
 154 m:METHOD: combine-or { not-class object }
 155     [ class>> ] dip = [ t t ] [ f f ] if ;
 156
 157 m:METHOD: combine-or { integer object }
 158     2dup class-member? [ nip t ] [ 2drop f f ] if ;
 159
 160 : try-combine ( elt1 elt2 quot -- combined/f ? )
 161     3dup call [ [ 3drop ] dip t ] [ drop swapd call ] if ; inline
 162
 163 :: prefix-combining ( seq elt quot: ( elt1 elt2 -- combined/f ? ) -- newseq )
 164     f :> combined!
 165     seq [ elt quot try-combine swap combined! ] find drop
 166     [ seq remove-nth combined prefix ]
 167     [ seq elt prefix ] if* ; inline
 168
 169 :: combine ( seq quot: ( elt1 elt2 -- combined/f ? ) empty class -- newseq )
 170     seq { } [ quot prefix-combining ] reduce
 171     dup length {
 172         { 0 [ drop empty ] }
 173         { 1 [ first ] }
 174         [ drop class new swap >>seq ]
 175     } case ; inline
 176
 177 : <and-class> ( seq -- class )
 178     [ combine-and ] t and-class combine ;
 179
 180 M: and-class class-member?
 181     seq>> [ class-member? ] with all? ;
 182
 183 : <or-class> ( seq -- class )
 184     [ combine-or ] f or-class combine ;
 185
 186 M: or-class class-member?
 187     seq>> [ class-member? ] with any? ;
 188
 189 : <not-class> ( class -- inverse )
 190     {
 191         { t [ f ] }
 192         { f [ t ] }
 193         [ dup not-class? [ class>> ] [ not-class boa ] if ]
 194     } case ;
 195
 196 M: not-class class-member?
 197     class>> class-member? not ;
 198
 199 M: primitive-class class-member?
 200     class>> class-member? ;
 201
 202 UNION: class primitive-class not-class or-class range ;