basis/regexp/classes/classes.factor

   1 ! Copyright (C) 2008, 2009 Doug Coleman, Daniel Ehrenberg.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel math math.order words combinators locals
   4 unicode.categories combinators.short-circuit sequences
   5 fry macros arrays assocs sets classes mirrors unicode.script
   6 unicode.data ;
   7 FROM: ascii => ascii? ;
   8 FROM: sets => members ;
   9 IN: regexp.classes
  10
  11 SINGLETONS: dot letter-class LETTER-class Letter-class digit-class
  12 alpha-class non-newline-blank-class
  13 ascii-class punctuation-class java-printable-class blank-class
  14 control-character-class hex-digit-class java-blank-class c-identifier-class
  15 unmatchable-class terminator-class word-boundary-class ;
  16
  17 SINGLETONS: beginning-of-input ^ end-of-input $ end-of-file
  18 ^unix $unix word-break ;
  19
  20 TUPLE: range-class from to ;
  21 C: <range-class> range-class
  22
  23 TUPLE: primitive-class class ;
  24 C: <primitive-class> primitive-class
  25
  26 TUPLE: category-class category ;
  27 C: <category-class> category-class
  28
  29 TUPLE: category-range-class category ;
  30 C: <category-range-class> category-range-class
  31
  32 TUPLE: script-class script ;
  33 C: <script-class> script-class
  34
  35 GENERIC: class-member? ( obj class -- ? )
  36
  37 M: t class-member? ( obj class -- ? ) 2drop t ;
  38
  39 M: integer class-member? ( obj class -- ? ) = ;
  40
  41 M: range-class class-member? ( obj class -- ? )
  42     [ from>> ] [ to>> ] bi between? ;
  43
  44 M: letter-class class-member? ( obj class -- ? )
  45     drop letter? ;
  46
  47 M: LETTER-class class-member? ( obj class -- ? )
  48     drop LETTER? ;
  49
  50 M: Letter-class class-member? ( obj class -- ? )
  51     drop Letter? ;
  52
  53 M: ascii-class class-member? ( obj class -- ? )
  54     drop ascii? ;
  55
  56 M: digit-class class-member? ( obj class -- ? )
  57     drop digit? ;
  58
  59 : c-identifier-char? ( ch -- ? )
  60     { [ alpha? ] [ CHAR: _ = ] } 1|| ;
  61
  62 M: c-identifier-class class-member? ( obj class -- ? )
  63     drop c-identifier-char? ;
  64
  65 M: alpha-class class-member? ( obj class -- ? )
  66     drop alpha? ;
  67
  68 : punct? ( ch -- ? )
  69     "!\"#$%&'()*+,-./:;<=>?@[\\]^_`{|}~" member? ;
  70
  71 M: punctuation-class class-member? ( obj class -- ? )
  72     drop punct? ;
  73
  74 : java-printable? ( ch -- ? )
  75     { [ alpha? ] [ punct? ] } 1|| ;
  76
  77 M: java-printable-class class-member? ( obj class -- ? )
  78     drop java-printable? ;
  79
  80 M: non-newline-blank-class class-member? ( obj class -- ? )
  81     drop { [ blank? ] [ CHAR: \n = not ] } 1&& ;
  82
  83 M: control-character-class class-member? ( obj class -- ? )
  84     drop control? ;
  85
  86 : hex-digit? ( ch -- ? )
  87     {
  88         [ CHAR: A CHAR: F between? ]
  89         [ CHAR: a CHAR: f between? ]
  90         [ CHAR: 0 CHAR: 9 between? ]
  91     } 1|| ;
  92
  93 M: hex-digit-class class-member? ( obj class -- ? )
  94     drop hex-digit? ;
  95
  96 : java-blank? ( ch -- ? )
  97     {
  98         CHAR: \s CHAR: \t CHAR: \n
  99         HEX: b HEX: 7 CHAR: \r
 100     } member? ;
 101
 102 M: java-blank-class class-member? ( obj class -- ? )
 103     drop java-blank? ;
 104
 105 M: unmatchable-class class-member? ( obj class -- ? )
 106     2drop f ;
 107
 108 M: terminator-class class-member? ( obj class -- ? )
 109     drop "\r\n\u000085\u002029\u002028" member? ;
 110
 111 M: f class-member? 2drop f ;
 112
 113 : same? ( obj1 obj2 quot1: ( obj1 -- val1 ) quot2: ( obj2 -- val2 ) -- ? )
 114     bi* = ; inline
 115
 116 M: script-class class-member?
 117     [ script-of ] [ script>> ] same? ;
 118
 119 M: category-class class-member?
 120     [ category ] [ category>> ] same? ;
 121
 122 M: category-range-class class-member?
 123     [ category first ] [ category>> ] same? ;
 124
 125 TUPLE: not-class class ;
 126
 127 PREDICATE: not-integer < not-class class>> integer? ;
 128
 129 UNION: simple-class
 130     primitive-class range-class dot ;
 131 PREDICATE: not-simple < not-class class>> simple-class? ;
 132
 133 M: not-class class-member?
 134     class>> class-member? not ;
 135
 136 TUPLE: or-class seq ;
 137
 138 M: or-class class-member?
 139     seq>> [ class-member? ] with any? ;
 140
 141 TUPLE: and-class seq ;
 142
 143 M: and-class class-member?
 144     seq>> [ class-member? ] with all? ;
 145
 146 DEFER: substitute
 147
 148 : flatten ( seq class -- newseq )
 149     '[ dup _ instance? [ seq>> ] [ 1array ] if ] map concat ; inline
 150
 151 :: seq>instance ( seq empty class -- instance )
 152     seq length {
 153         { 0 [ empty ] }
 154         { 1 [ seq first ] }
 155         [ drop class new seq { } like >>seq ]
 156     } case ; inline
 157
 158 TUPLE: class-partition integers not-integers simples not-simples and or other ;
 159
 160 : partition-classes ( seq -- class-partition )
 161     members
 162     [ integer? ] partition
 163     [ not-integer? ] partition
 164     [ simple-class? ] partition
 165     [ not-simple? ] partition
 166     [ and-class? ] partition
 167     [ or-class? ] partition
 168     class-partition boa ;
 169
 170 : class-partition>seq ( class-partition -- seq )
 171     make-mirror values concat ;
 172
 173 : repartition ( partition -- partition' )
 174     ! This could be made more efficient; only and and or are effected
 175     class-partition>seq partition-classes ;
 176
 177 : filter-not-integers ( partition -- partition' )
 178     dup
 179     [ simples>> ] [ not-simples>> ] [ or>> ] tri
 180     3append and-class boa
 181     '[ [ class>> _ class-member? ] filter ] change-not-integers ;
 182
 183 : answer-ors ( partition -- partition' )
 184     dup [ not-integers>> ] [ not-simples>> ] [ simples>> ] tri 3append
 185     '[ [ _ [ t substitute ] each ] map ] change-or ;
 186
 187 : contradiction? ( partition -- ? )
 188     {
 189         [ [ simples>> ] [ not-simples>> ] bi intersects? ]
 190         [ other>> f swap member? ]
 191     } 1|| ;
 192
 193 : make-and-class ( partition -- and-class )
 194     answer-ors repartition
 195     [ t swap remove ] change-other
 196     dup contradiction?
 197     [ drop f ]
 198     [ filter-not-integers class-partition>seq members t and-class seq>instance ] if ;
 199
 200 : <and-class> ( seq -- class )
 201     dup and-class flatten partition-classes
 202     dup integers>> length {
 203         { 0 [ nip make-and-class ] }
 204         { 1 [ integers>> first [ '[ _ swap class-member? ] all? ] keep and ] }
 205         [ 3drop f ]
 206     } case ;
 207
 208 : filter-integers ( partition -- partition' )
 209     dup
 210     [ simples>> ] [ not-simples>> ] [ and>> ] tri
 211     3append or-class boa
 212     '[ [ _ class-member? not ] filter ] change-integers ;
 213
 214 : answer-ands ( partition -- partition' )
 215     dup [ integers>> ] [ not-simples>> ] [ simples>> ] tri 3append
 216     '[ [ _ [ f substitute ] each ] map ] change-and ;
 217
 218 : tautology? ( partition -- ? )
 219     {
 220         [ [ simples>> ] [ not-simples>> ] bi intersects? ]
 221         [ other>> t swap member? ]
 222     } 1|| ;
 223
 224 : make-or-class ( partition -- and-class )
 225     answer-ands repartition
 226     [ f swap remove ] change-other
 227     dup tautology?
 228     [ drop t ]
 229     [ filter-integers class-partition>seq members f or-class seq>instance ] if ;
 230
 231 : <or-class> ( seq -- class )
 232     dup or-class flatten partition-classes
 233     dup not-integers>> length {
 234         { 0 [ nip make-or-class ] }
 235         { 1 [
 236             not-integers>> first
 237             [ class>> '[ _ swap class-member? ] any? ] keep or
 238         ] }
 239         [ 3drop t ]
 240     } case ;
 241
 242 GENERIC: <not-class> ( class -- inverse )
 243
 244 M: object <not-class>
 245     not-class boa ;
 246
 247 M: not-class <not-class>
 248     class>> ;
 249
 250 M: and-class <not-class>
 251     seq>> [ <not-class> ] map <or-class> ;
 252
 253 M: or-class <not-class>
 254     seq>> [ <not-class> ] map <and-class> ;
 255
 256 M: t <not-class> drop f ;
 257 M: f <not-class> drop t ;
 258
 259 : <minus-class> ( a b -- a-b )
 260     <not-class> 2array <and-class> ;
 261
 262 : <sym-diff-class> ( a b -- a~b )
 263     2array [ <or-class> ] [ <and-class> ] bi <minus-class> ;
 264
 265 M: primitive-class class-member?
 266     class>> class-member? ;
 267
 268 TUPLE: condition question yes no ;
 269 C: <condition> condition
 270
 271 GENERIC# answer 2 ( class from to -- new-class )
 272
 273 M:: object answer ( class from to -- new-class )
 274     class from = to class ? ;
 275
 276 : replace-compound ( class from to -- seq )
 277     [ seq>> ] 2dip '[ _ _ answer ] map ;
 278
 279 M: and-class answer
 280     replace-compound <and-class> ;
 281
 282 M: or-class answer
 283     replace-compound <or-class> ;
 284
 285 M: not-class answer
 286     [ class>> ] 2dip answer <not-class> ;
 287
 288 GENERIC# substitute 1 ( class from to -- new-class )
 289 M: object substitute answer ;
 290 M: not-class substitute [ <not-class> ] bi@ answer ;
 291
 292 : assoc-answer ( table question answer -- new-table )
 293     '[ _ _ substitute ] assoc-map
 294     [ nip ] assoc-filter ;
 295
 296 : assoc-answers ( table questions answer -- new-table )
 297     '[ _ assoc-answer ] each ;
 298
 299 DEFER: make-condition
 300
 301 : (make-condition) ( table questions question -- condition )
 302     [ 2nip ]
 303     [ swap [ t assoc-answer ] dip make-condition ]
 304     [ swap [ f assoc-answer ] dip make-condition ] 3tri
 305     2dup = [ 2nip ] [ <condition> ] if ;
 306
 307 : make-condition ( table questions -- condition )
 308     [ keys ] [ unclip (make-condition) ] if-empty ;
 309
 310 GENERIC: class>questions ( class -- questions )
 311 : compound-questions ( class -- questions ) seq>> [ class>questions ] gather ;
 312 M: or-class class>questions compound-questions ;
 313 M: and-class class>questions compound-questions ;
 314 M: not-class class>questions class>> class>questions ;
 315 M: object class>questions 1array ;
 316
 317 : table>questions ( table -- questions )
 318     values [ class>questions ] gather >array t swap remove ;
 319
 320 : table>condition ( table -- condition )
 321     ! input table is state => class
 322     >alist dup table>questions make-condition ;
 323
 324 : condition-map ( condition quot: ( obj -- obj' ) -- new-condition )
 325     over condition? [
 326         [ [ question>> ] [ yes>> ] [ no>> ] tri ] dip
 327         '[ _ condition-map ] bi@ <condition>
 328     ] [ call ] if ; inline recursive
 329
 330 : condition-states ( condition -- states )
 331     dup condition? [
 332         [ yes>> ] [ no>> ] bi
 333         [ condition-states ] bi@ union
 334     ] [ 1array ] if ;
 335
 336 : condition-at ( condition assoc -- new-condition )
 337     '[ _ at ] condition-map ;