basis/regexp/compiler/compiler.factor

   1 ! Copyright (C) 2009 Daniel Ehrenberg.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: regexp.classes kernel sequences regexp.negation
   4 quotations assocs fry math locals combinators
   5 accessors words compiler.units kernel.private strings
   6 sequences.private arrays namespaces unicode.breaks
   7 regexp.transition-tables combinators.short-circuit ;
   8 IN: regexp.compiler
   9
  10 GENERIC: question>quot ( question -- quot )
  11
  12 SYMBOL: shortest?
  13 SYMBOL: backwards?
  14
  15 <PRIVATE
  16
  17 M: t question>quot drop [ 2drop t ] ;
  18 M: f question>quot drop [ 2drop f ] ;
  19
  20 M: beginning-of-input question>quot
  21     drop [ drop zero? ] ;
  22
  23 M: end-of-input question>quot
  24     drop [ length = ] ;
  25
  26 M: end-of-file question>quot
  27     drop [
  28         {
  29             [ length swap - 2 <= ]
  30             [ swap tail { "\n" "\r\n" "\r" "" } member? ]
  31         } 2&&
  32     ] ;
  33
  34 M: $ question>quot
  35     drop [ { [ length = ] [ ?nth "\r\n" member? ] } 2|| ] ;
  36
  37 M: ^ question>quot
  38     drop [ { [ drop zero? ] [ [ 1- ] dip ?nth "\r\n" member? ] } 2|| ] ;
  39
  40 M: $unix question>quot
  41     drop [ { [ length = ] [ ?nth CHAR: \n = ] } 2|| ] ;
  42
  43 M: ^unix question>quot
  44     drop [ { [ drop zero? ] [ [ 1- ] dip ?nth CHAR: \n = ] } 2|| ] ;
  45
  46 M: word-break question>quot
  47     drop [ word-break-at? ] ;
  48
  49 : (execution-quot) ( next-state -- quot )
  50     ! The conditions here are for lookaround and anchors, etc
  51     dup condition? [
  52         [ question>> question>quot ] [ yes>> ] [ no>> ] tri
  53         [ (execution-quot) ] bi@
  54         '[ 2dup @ _ _ if ]
  55     ] [ '[ _ execute ] ] if ;
  56
  57 : execution-quot ( next-state -- quot )
  58     dup sequence? [ first ] when
  59     (execution-quot) ;
  60
  61 TUPLE: box contents ;
  62 C: <box> box
  63
  64 : condition>quot ( condition -- quot )
  65     ! Conditions here are for different classes
  66     dup condition? [
  67         [ question>> ] [ yes>> ] [ no>> ] tri
  68         [ condition>quot ] bi@
  69         '[ dup _ class-member? _ _ if ]
  70     ] [
  71         contents>>
  72         [ [ 3drop ] ] [ execution-quot '[ drop @ ] ] if-empty
  73     ] if ;
  74
  75 : non-literals>dispatch ( literals non-literals  -- quot )
  76     [ swap ] assoc-map ! we want state => predicate, and get the opposite as input
  77     swap keys f assoc-answers
  78     table>condition [ <box> ] condition-map condition>quot ;
  79
  80 : literals>cases ( literal-transitions -- case-body )
  81     [ execution-quot ] assoc-map ;
  82
  83 : split-literals ( transitions -- case default )
  84     { } assoc-like [ first integer? ] partition
  85     [ [ literals>cases ] keep ] dip non-literals>dispatch ;
  86
  87 :: step ( last-match index str quot final? direction -- last-index/f )
  88     final? index last-match ?
  89     index str bounds-check? [
  90         index direction + str
  91         index str nth-unsafe
  92         quot call
  93     ] when ; inline
  94
  95 : direction ( -- n )
  96     backwards? get -1 1 ? ;
  97
  98 : transitions>quot ( transitions final-state? -- quot )
  99     dup shortest? get and [ 2drop [ drop nip ] ] [
 100         [ split-literals swap case>quot ] dip direction
 101         '[ { array-capacity string } declare _ _ _ step ]
 102     ] if ;
 103
 104 : word>quot ( word dfa -- quot )
 105     [ transitions>> at ]
 106     [ final-states>> key? ] 2bi
 107     transitions>quot ;
 108
 109 : states>code ( words dfa -- )
 110     '[
 111         dup _ word>quot
 112         (( last-match index string -- ? ))
 113         define-declared
 114     ] each ;
 115
 116 : states>words ( dfa -- words dfa )
 117     dup transitions>> keys [ gensym ] H{ } map>assoc
 118     [ transitions-at ]
 119     [ values ]
 120     bi swap ;
 121
 122 : dfa>main-word ( dfa -- word )
 123     states>words [ states>code ] keep start-state>> ;
 124
 125 PRIVATE>
 126
 127 : dfa>word ( dfa -- quot )
 128     dfa>main-word execution-quot '[ drop [ f ] 2dip @ ]
 129     (( start-index string regexp -- i/f )) define-temp ;
 130
 131 : dfa>shortest-word ( dfa -- word )
 132     t shortest? [ dfa>word ] with-variable ;
 133
 134 : dfa>reverse-word ( dfa -- word )
 135     t backwards? [ dfa>word ] with-variable ;
 136
 137 : dfa>reverse-shortest-word ( dfa -- word )
 138     t backwards? [ dfa>shortest-word ] with-variable ;