basis/specialized-arrays/functor/functor.factor

   1 ! Copyright (C) 2008 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: functors sequences sequences.private prettyprint.custom
   4 kernel words classes math math.vectors.specialization parser
   5 alien.c-types byte-arrays accessors summary ;
   6 IN: specialized-arrays.functor
   7
   8 ERROR: bad-byte-array-length byte-array type ;
   9
  10 M: bad-byte-array-length summary
  11     drop "Byte array length doesn't divide type width" ;
  12
  13 : (c-array) ( n c-type -- array )
  14     heap-size * (byte-array) ; inline
  15
  16 FUNCTOR: define-array ( T -- )
  17
  18 A            DEFINES-CLASS ${T}-array
  19 <A>          DEFINES <${A}>
  20 (A)          DEFINES (${A})
  21 >A           DEFINES >${A}
  22 byte-array>A DEFINES byte-array>${A}
  23 A{           DEFINES ${A}{
  24
  25 NTH          [ T dup c-type-getter-boxer array-accessor ]
  26 SET-NTH      [ T dup c-setter array-accessor ]
  27
  28 WHERE
  29
  30 TUPLE: A
  31 { length array-capacity read-only }
  32 { underlying byte-array read-only } ;
  33
  34 : <A> ( n -- specialized-array ) dup T <c-array> A boa ; inline
  35
  36 : (A) ( n -- specialized-array ) dup T (c-array) A boa ; inline
  37
  38 : byte-array>A ( byte-array -- specialized-array )
  39     dup length T heap-size /mod 0 = [ drop T bad-byte-array-length ] unless
  40     swap A boa ; inline
  41
  42 M: A clone [ length>> ] [ underlying>> clone ] bi A boa ; inline
  43
  44 M: A length length>> ; inline
  45
  46 M: A nth-unsafe underlying>> NTH call ; inline
  47
  48 M: A set-nth-unsafe underlying>> SET-NTH call ; inline
  49
  50 : >A ( seq -- specialized-array ) A new clone-like ;
  51
  52 M: A like drop dup A instance? [ >A ] unless ; inline
  53
  54 M: A new-sequence drop (A) ; inline
  55
  56 M: A equal? over A instance? [ sequence= ] [ 2drop f ] if ;
  57
  58 M: A resize
  59     [ drop ] [
  60         [ T heap-size * ] [ underlying>> ] bi*
  61         resize-byte-array
  62     ] 2bi
  63     A boa ; inline
  64
  65 M: A byte-length underlying>> length ; inline
  66
  67 M: A pprint-delims drop \ A{ \ } ;
  68
  69 M: A >pprint-sequence ;
  70
  71 M: A pprint* pprint-object ;
  72
  73 SYNTAX: A{ \ } [ >A ] parse-literal ;
  74
  75 INSTANCE: A sequence
  76
  77 A T c-type-boxed-class specialize-vector-words
  78
  79 ;FUNCTOR