basis/specialized-arrays/functor/functor.factor

   1 ! Copyright (C) 2008 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: functors sequences sequences.private prettyprint.custom
   4 kernel words classes math math.vectors.specialization parser
   5 alien.c-types byte-arrays accessors summary ;
   6 IN: specialized-arrays.functor
   7
   8 ERROR: bad-byte-array-length byte-array type ;
   9
  10 M: bad-byte-array-length summary
  11     drop "Byte array length doesn't divide type width" ;
  12
  13 : (underlying) ( n c-type -- array )
  14     heap-size * (byte-array) ; inline
  15
  16 : <underlying> ( n type -- array )
  17     heap-size * <byte-array> ; inline
  18
  19 FUNCTOR: define-array ( T -- )
  20
  21 A            DEFINES-CLASS ${T}-array
  22 S            DEFINES-CLASS ${T}-sequence
  23 <A>          DEFINES <${A}>
  24 (A)          DEFINES (${A})
  25 >A           DEFINES >${A}
  26 byte-array>A DEFINES byte-array>${A}
  27 A{           DEFINES ${A}{
  28
  29 NTH          [ T dup c-type-getter-boxer array-accessor ]
  30 SET-NTH      [ T dup c-setter array-accessor ]
  31
  32 WHERE
  33
  34 MIXIN: S
  35
  36 TUPLE: A
  37 { length array-capacity read-only }
  38 { underlying byte-array read-only } ;
  39
  40 : <A> ( n -- specialized-array ) dup T <underlying> A boa ; inline
  41
  42 : (A) ( n -- specialized-array ) dup T (underlying) A boa ; inline
  43
  44 : byte-array>A ( byte-array -- specialized-array )
  45     dup length T heap-size /mod 0 = [ drop T bad-byte-array-length ] unless
  46     swap A boa ; inline
  47
  48 M: A clone [ length>> ] [ underlying>> clone ] bi A boa ; inline
  49
  50 M: A length length>> ; inline
  51
  52 M: A nth-unsafe underlying>> NTH call ; inline
  53
  54 M: A set-nth-unsafe underlying>> SET-NTH call ; inline
  55
  56 : >A ( seq -- specialized-array ) A new clone-like ;
  57
  58 M: A like drop dup A instance? [ >A ] unless ; inline
  59
  60 M: A new-sequence drop (A) ; inline
  61
  62 M: A equal? over A instance? [ sequence= ] [ 2drop f ] if ;
  63
  64 M: A resize
  65     [ drop ] [
  66         [ T heap-size * ] [ underlying>> ] bi*
  67         resize-byte-array
  68     ] 2bi
  69     A boa ; inline
  70
  71 M: A byte-length underlying>> length ; inline
  72
  73 M: A pprint-delims drop \ A{ \ } ;
  74
  75 M: A >pprint-sequence ;
  76
  77 M: A pprint* pprint-object ;
  78
  79 SYNTAX: A{ \ } [ >A ] parse-literal ;
  80
  81 INSTANCE: A sequence
  82 INSTANCE: A S
  83
  84 A T c-type-boxed-class f specialize-vector-words
  85
  86 T c-type
  87     \ A >>array-class
  88     \ <A> >>array-constructor
  89     \ (A) >>(array)-constructor
  90     \ S >>sequence-mixin-class
  91     drop
  92
  93 ;FUNCTOR