basis/specialized-arrays/functor/functor.factor

   1 ! Copyright (C) 2008, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: functors sequences sequences.private prettyprint.custom
   4 kernel words classes math math.vectors.specialization parser
   5 alien.c-types byte-arrays accessors summary alien specialized-arrays ;
   6 IN: specialized-arrays.functor
   7
   8 ERROR: bad-byte-array-length byte-array type ;
   9
  10 M: bad-byte-array-length summary
  11     drop "Byte array length doesn't divide type width" ;
  12
  13 : (underlying) ( n c-type -- array )
  14     heap-size * (byte-array) ; inline
  15
  16 : <underlying> ( n type -- array )
  17     heap-size * <byte-array> ; inline
  18
  19 FUNCTOR: define-array ( T -- )
  20
  21 A            DEFINES-CLASS ${T}-array
  22 S            DEFINES-CLASS ${T}-sequence
  23 <A>          DEFINES <${A}>
  24 (A)          DEFINES (${A})
  25 <direct-A>   DEFINES <direct-${A}>
  26 >A           DEFINES >${A}
  27 byte-array>A DEFINES byte-array>${A}
  28
  29 A{           DEFINES ${A}{
  30 A@           DEFINES ${A}@
  31
  32 NTH          [ T dup c-type-getter-boxer array-accessor ]
  33 SET-NTH      [ T dup c-setter array-accessor ]
  34
  35 WHERE
  36
  37 MIXIN: S
  38
  39 TUPLE: A
  40 { underlying c-ptr read-only }
  41 { length array-capacity read-only } ;
  42
  43 : <direct-A> ( alien len -- specialized-array ) A boa ; inline
  44
  45 : <A> ( n -- specialized-array ) [ T <underlying> ] keep <direct-A> ; inline
  46
  47 : (A) ( n -- specialized-array ) [ T (underlying) ] keep <direct-A> ; inline
  48
  49 : byte-array>A ( byte-array -- specialized-array )
  50     dup length T heap-size /mod 0 = [ drop T bad-byte-array-length ] unless
  51     <direct-A> ; inline
  52
  53 M: A clone [ underlying>> clone ] [ length>> ] bi <direct-A> ; inline
  54
  55 M: A length length>> ; inline
  56
  57 M: A nth-unsafe underlying>> NTH call ; inline
  58
  59 M: A set-nth-unsafe underlying>> SET-NTH call ; inline
  60
  61 : >A ( seq -- specialized-array ) A new clone-like ;
  62
  63 M: A like drop dup A instance? [ >A ] unless ; inline
  64
  65 M: A new-sequence drop (A) ; inline
  66
  67 M: A equal? over A instance? [ sequence= ] [ 2drop f ] if ;
  68
  69 M: A resize
  70     [
  71         [ T heap-size * ] [ underlying>> ] bi*
  72         resize-byte-array
  73     ] [ drop ] 2bi
  74     <direct-A> ; inline
  75
  76 M: A byte-length underlying>> length ; inline
  77 M: A pprint-delims drop \ A{ \ } ;
  78 M: A >pprint-sequence ;
  79
  80 SYNTAX: A{ \ } [ >A ] parse-literal ;
  81 SYNTAX: A@ scan-object scan-object <direct-A> parsed ;
  82
  83 INSTANCE: A specialized-array
  84
  85 A T c-type-boxed-class f specialize-vector-words
  86
  87 T c-type
  88     \ A >>array-class
  89     \ <A> >>array-constructor
  90     \ (A) >>(array)-constructor
  91     \ <direct-A> >>direct-array-constructor
  92     drop
  93
  94 ;FUNCTOR