basis/specialized-arrays/functor/functor.factor

   1 ! Copyright (C) 2008 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: functors sequences sequences.private prettyprint.custom
   4 kernel words classes math parser alien.c-types byte-arrays
   5 accessors summary ;
   6 IN: specialized-arrays.functor
   7
   8 ERROR: bad-byte-array-length byte-array type ;
   9
  10 M: bad-byte-array-length summary
  11     drop "Byte array length doesn't divide type width" ;
  12
  13 FUNCTOR: define-array ( T -- )
  14
  15 A            DEFINES ${T}-array
  16 <A>          DEFINES <${A}>
  17 >A           DEFINES >${A}
  18 byte-array>A DEFINES byte-array>${A}
  19 A{           DEFINES ${A}{
  20
  21 NTH          [ T dup c-getter array-accessor ]
  22 SET-NTH      [ T dup c-setter array-accessor ]
  23
  24 WHERE
  25
  26 TUPLE: A
  27 { length array-capacity read-only }
  28 { underlying byte-array read-only } ;
  29
  30 : <A> ( n -- specialized-array ) dup T <c-array> A boa ; inline
  31
  32 : byte-array>A ( byte-array -- specialized-array )
  33     dup length T heap-size /mod 0 = [ drop T bad-byte-array-length ] unless
  34     swap A boa ; inline
  35
  36 M: A clone [ length>> ] [ underlying>> clone ] bi A boa ;
  37
  38 M: A length length>> ;
  39
  40 M: A nth-unsafe underlying>> NTH call ;
  41
  42 M: A set-nth-unsafe underlying>> SET-NTH call ;
  43
  44 : >A ( seq -- specialized-array ) A new clone-like ; inline
  45
  46 M: A like drop dup A instance? [ >A execute ] unless ;
  47
  48 M: A new-sequence drop <A> execute ;
  49
  50 M: A equal? over A instance? [ sequence= ] [ 2drop f ] if ;
  51
  52 M: A resize
  53     [ drop ] [
  54         [ T heap-size * ] [ underlying>> ] bi*
  55         resize-byte-array
  56     ] 2bi
  57     A boa ;
  58
  59 M: A byte-length underlying>> length ;
  60
  61 M: A pprint-delims drop A{ \ } ;
  62
  63 M: A >pprint-sequence ;
  64
  65 M: A pprint* pprint-object ;
  66
  67 : A{ \ } [ >A execute ] parse-literal ; parsing
  68
  69 INSTANCE: A sequence
  70
  71 ;FUNCTOR