basis/specialized-arrays/functor/functor.factor

   1 ! Copyright (C) 2008 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: functors sequences sequences.private prettyprint.custom
   4 kernel words classes math math.vectors.specialization parser
   5 alien.c-types byte-arrays accessors summary ;
   6 IN: specialized-arrays.functor
   7
   8 ERROR: bad-byte-array-length byte-array type ;
   9
  10 M: bad-byte-array-length summary
  11     drop "Byte array length doesn't divide type width" ;
  12
  13 : (c-array) ( n c-type -- array )
  14     heap-size * (byte-array) ; inline
  15
  16 FUNCTOR: define-array ( T -- )
  17
  18 A            DEFINES-CLASS ${T}-array
  19 S            DEFINES-CLASS ${T}-sequence
  20 <A>          DEFINES <${A}>
  21 (A)          DEFINES (${A})
  22 >A           DEFINES >${A}
  23 byte-array>A DEFINES byte-array>${A}
  24 A{           DEFINES ${A}{
  25
  26 NTH          [ T dup c-type-getter-boxer array-accessor ]
  27 SET-NTH      [ T dup c-setter array-accessor ]
  28
  29 WHERE
  30
  31 MIXIN: S
  32
  33 TUPLE: A
  34 { length array-capacity read-only }
  35 { underlying byte-array read-only } ;
  36
  37 : <A> ( n -- specialized-array ) dup T <c-array> A boa ; inline
  38
  39 : (A) ( n -- specialized-array ) dup T (c-array) A boa ; inline
  40
  41 : byte-array>A ( byte-array -- specialized-array )
  42     dup length T heap-size /mod 0 = [ drop T bad-byte-array-length ] unless
  43     swap A boa ; inline
  44
  45 M: A clone [ length>> ] [ underlying>> clone ] bi A boa ; inline
  46
  47 M: A length length>> ; inline
  48
  49 M: A nth-unsafe underlying>> NTH call ; inline
  50
  51 M: A set-nth-unsafe underlying>> SET-NTH call ; inline
  52
  53 : >A ( seq -- specialized-array ) A new clone-like ;
  54
  55 M: A like drop dup A instance? [ >A ] unless ; inline
  56
  57 M: A new-sequence drop (A) ; inline
  58
  59 M: A equal? over A instance? [ sequence= ] [ 2drop f ] if ;
  60
  61 M: A resize
  62     [ drop ] [
  63         [ T heap-size * ] [ underlying>> ] bi*
  64         resize-byte-array
  65     ] 2bi
  66     A boa ; inline
  67
  68 M: A byte-length underlying>> length ; inline
  69
  70 M: A pprint-delims drop \ A{ \ } ;
  71
  72 M: A >pprint-sequence ;
  73
  74 M: A pprint* pprint-object ;
  75
  76 SYNTAX: A{ \ } [ >A ] parse-literal ;
  77
  78 INSTANCE: A sequence
  79 INSTANCE: A S
  80
  81 A T c-type-boxed-class specialize-vector-words
  82
  83 T c-type
  84     \ A >>array-class
  85     \ <A> >>array-constructor
  86     \ S >>sequence-mixin-class
  87     drop
  88
  89 ;FUNCTOR