basis/specialized-arrays/specialized-arrays.factor

   1 ! Copyright (C) 2008, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors alien alien.c-types alien.parser assocs
   4 byte-arrays classes compiler.units functors kernel lexer libc math
   5 math.vectors.specialization namespaces parser prettyprint.custom
   6 sequences sequences.private strings summary vocabs vocabs.loader
   7 vocabs.parser words fry combinators ;
   8 IN: specialized-arrays
   9
  10 MIXIN: specialized-array
  11
  12 INSTANCE: specialized-array sequence
  13
  14 GENERIC: direct-array-syntax ( obj -- word )
  15
  16 ERROR: bad-byte-array-length byte-array type ;
  17
  18 M: bad-byte-array-length summary
  19     drop "Byte array length doesn't divide type width" ;
  20
  21 : (underlying) ( n c-type -- array )
  22     heap-size * (byte-array) ; inline
  23
  24 : <underlying> ( n type -- array )
  25     heap-size * <byte-array> ; inline
  26
  27 <PRIVATE
  28
  29 FUNCTOR: define-array ( T -- )
  30
  31 A            DEFINES-CLASS ${T}-array
  32 S            DEFINES-CLASS ${T}-sequence
  33 <A>          DEFINES <${A}>
  34 (A)          DEFINES (${A})
  35 <direct-A>   DEFINES <direct-${A}>
  36 malloc-A     DEFINES malloc-${A}
  37 >A           DEFINES >${A}
  38 byte-array>A DEFINES byte-array>${A}
  39
  40 A{           DEFINES ${A}{
  41 A@           DEFINES ${A}@
  42
  43 NTH          [ T dup c-type-getter-boxer array-accessor ]
  44 SET-NTH      [ T dup c-setter array-accessor ]
  45
  46 WHERE
  47
  48 MIXIN: S
  49
  50 TUPLE: A
  51 { underlying c-ptr read-only }
  52 { length array-capacity read-only } ;
  53
  54 : <direct-A> ( alien len -- specialized-array ) A boa ; inline
  55
  56 : <A> ( n -- specialized-array ) [ T <underlying> ] keep <direct-A> ; inline
  57
  58 : (A) ( n -- specialized-array ) [ T (underlying) ] keep <direct-A> ; inline
  59
  60 : malloc-A ( len -- specialized-array ) [ T heap-size calloc ] keep <direct-A> ; inline
  61
  62 : byte-array>A ( byte-array -- specialized-array )
  63     dup length T heap-size /mod 0 = [ drop T bad-byte-array-length ] unless
  64     <direct-A> ; inline
  65
  66 M: A clone [ underlying>> clone ] [ length>> ] bi <direct-A> ; inline
  67
  68 M: A length length>> ; inline
  69
  70 M: A nth-unsafe underlying>> NTH call ; inline
  71
  72 M: A set-nth-unsafe underlying>> SET-NTH call ; inline
  73
  74 : >A ( seq -- specialized-array ) A new clone-like ;
  75
  76 M: A like drop dup A instance? [ >A ] unless ; inline
  77
  78 M: A new-sequence drop (A) ; inline
  79
  80 M: A equal? over A instance? [ sequence= ] [ 2drop f ] if ;
  81
  82 M: A resize
  83     [
  84         [ T heap-size * ] [ underlying>> ] bi*
  85         resize-byte-array
  86     ] [ drop ] 2bi
  87     <direct-A> ; inline
  88
  89 M: A byte-length length T heap-size * ; inline
  90
  91 M: A direct-array-syntax drop \ A@ ;
  92
  93 M: A pprint-delims drop \ A{ \ } ;
  94
  95 M: A >pprint-sequence ;
  96
  97 SYNTAX: A{ \ } [ >A ] parse-literal ;
  98 SYNTAX: A@ scan-object scan-object <direct-A> parsed ;
  99
 100 INSTANCE: A specialized-array
 101
 102 A T c-type-boxed-class f specialize-vector-words
 103
 104 ;FUNCTOR
 105
 106 GENERIC: (underlying-type) ( c-type -- c-type' )
 107
 108 M: string (underlying-type) c-types get at ;
 109 M: word (underlying-type) "c-type" word-prop ;
 110
 111 : underlying-type ( c-type -- c-type' )
 112     dup (underlying-type) {
 113         { [ dup not ] [ drop no-c-type ] }
 114         { [ dup c-type-name? ] [ nip underlying-type ] }
 115         [ drop ]
 116     } cond ;
 117
 118 : underlying-type-name ( c-type -- name )
 119     underlying-type dup word? [ name>> ] when ;
 120
 121 : specialized-array-vocab ( c-type -- vocab )
 122     "specialized-arrays.instances." prepend ;
 123
 124 PRIVATE>
 125
 126 : generate-vocab ( vocab-name quot -- vocab )
 127     [ dup vocab [ ] ] dip '[
 128         [
 129             [
 130                  _ with-current-vocab
 131             ] with-compilation-unit
 132         ] keep
 133     ] ?if ; inline
 134
 135 : define-array-vocab ( type -- vocab )
 136     underlying-type-name
 137     [ specialized-array-vocab ] [ '[ _ define-array ] ] bi
 138     generate-vocab ;
 139
 140 M: c-type-name require-c-array define-array-vocab drop ;
 141
 142 ERROR: specialized-array-vocab-not-loaded c-type ;
 143
 144 M: c-type-name c-array-constructor
 145     underlying-type-name
 146     dup [ "<" "-array>" surround ] [ specialized-array-vocab ] bi lookup
 147     [ ] [ specialized-array-vocab-not-loaded ] ?if ; foldable
 148
 149 M: c-type-name c-(array)-constructor
 150     underlying-type-name
 151     dup [ "(" "-array)" surround ] [ specialized-array-vocab ] bi lookup
 152     [ ] [ specialized-array-vocab-not-loaded ] ?if ; foldable
 153
 154 M: c-type-name c-direct-array-constructor
 155     underlying-type-name
 156     dup [ "<direct-" "-array>" surround ] [ specialized-array-vocab ] bi lookup
 157     [ ] [ specialized-array-vocab-not-loaded ] ?if ; foldable
 158
 159 SYNTAX: SPECIALIZED-ARRAY:
 160     scan-c-type define-array-vocab use-vocab ;
 161
 162 "prettyprint" vocab [
 163     "specialized-arrays.prettyprint" require
 164 ] when