basis/specialized-arrays/specialized-arrays.factor

   1 ! Copyright (C) 2008, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors alien alien.c-types assocs byte-arrays classes
   4 compiler.units functors io kernel lexer libc math
   5 math.vectors.specialization namespaces parser
   6 prettyprint.custom sequences sequences.private strings summary
   7 vocabs vocabs.loader vocabs.parser words ;
   8 IN: specialized-arrays
   9
  10 MIXIN: specialized-array
  11
  12 INSTANCE: specialized-array sequence
  13
  14 GENERIC: direct-array-syntax ( obj -- word )
  15
  16 ERROR: bad-byte-array-length byte-array type ;
  17
  18 M: bad-byte-array-length summary
  19     drop "Byte array length doesn't divide type width" ;
  20
  21 : (underlying) ( n c-type -- array )
  22     heap-size * (byte-array) ; inline
  23
  24 : <underlying> ( n type -- array )
  25     heap-size * <byte-array> ; inline
  26
  27 <PRIVATE
  28
  29 FUNCTOR: define-array ( T -- )
  30
  31 A            DEFINES-CLASS ${T}-array
  32 S            DEFINES-CLASS ${T}-sequence
  33 <A>          DEFINES <${A}>
  34 (A)          DEFINES (${A})
  35 <direct-A>   DEFINES <direct-${A}>
  36 malloc-A     DEFINES malloc-${A}
  37 >A           DEFINES >${A}
  38 byte-array>A DEFINES byte-array>${A}
  39
  40 A{           DEFINES ${A}{
  41 A@           DEFINES ${A}@
  42
  43 NTH          [ T dup c-type-getter-boxer array-accessor ]
  44 SET-NTH      [ T dup c-setter array-accessor ]
  45
  46 WHERE
  47
  48 MIXIN: S
  49
  50 TUPLE: A
  51 { underlying c-ptr read-only }
  52 { length array-capacity read-only } ;
  53
  54 : <direct-A> ( alien len -- specialized-array ) A boa ; inline
  55
  56 : <A> ( n -- specialized-array ) [ T <underlying> ] keep <direct-A> ; inline
  57
  58 : (A) ( n -- specialized-array ) [ T (underlying) ] keep <direct-A> ; inline
  59
  60 : malloc-A ( len -- specialized-array ) [ T heap-size calloc ] keep <direct-A> ; inline
  61
  62 : byte-array>A ( byte-array -- specialized-array )
  63     dup length T heap-size /mod 0 = [ drop T bad-byte-array-length ] unless
  64     <direct-A> ; inline
  65
  66 M: A clone [ underlying>> clone ] [ length>> ] bi <direct-A> ; inline
  67
  68 M: A length length>> ; inline
  69
  70 M: A nth-unsafe underlying>> NTH call ; inline
  71
  72 M: A set-nth-unsafe underlying>> SET-NTH call ; inline
  73
  74 : >A ( seq -- specialized-array ) A new clone-like ;
  75
  76 M: A like drop dup A instance? [ >A ] unless ; inline
  77
  78 M: A new-sequence drop (A) ; inline
  79
  80 M: A equal? over A instance? [ sequence= ] [ 2drop f ] if ;
  81
  82 M: A resize
  83     [
  84         [ T heap-size * ] [ underlying>> ] bi*
  85         resize-byte-array
  86     ] [ drop ] 2bi
  87     <direct-A> ; inline
  88
  89 M: A byte-length underlying>> length ; inline
  90 M: A pprint-delims drop \ A{ \ } ;
  91 M: A >pprint-sequence ;
  92
  93 SYNTAX: A{ \ } [ >A ] parse-literal ;
  94 SYNTAX: A@ scan-object scan-object <direct-A> parsed ;
  95
  96 INSTANCE: A specialized-array
  97
  98 A T c-type-boxed-class f specialize-vector-words
  99
 100 ;FUNCTOR
 101
 102 : underlying-type ( c-type -- c-type' )
 103     dup c-types get at string? [
 104         c-types get at underlying-type
 105     ] when ;
 106
 107 : specialized-array-vocab ( c-type -- vocab )
 108     "specialized-arrays.instances." prepend ;
 109
 110 : defining-array-message ( type -- )
 111     "quiet" get [ drop ] [
 112         "Generating specialized " " arrays..." surround print
 113     ] if ;
 114
 115 PRIVATE>
 116
 117 : define-array-vocab ( type  -- vocab )
 118     underlying-type
 119     dup specialized-array-vocab vocab
 120     [ ] [
 121         [ defining-array-message ]
 122         [
 123             [
 124                 dup specialized-array-vocab
 125                 [ define-array ] with-current-vocab
 126             ] with-compilation-unit
 127         ]
 128         [ specialized-array-vocab ]
 129         tri
 130     ] ?if ;
 131
 132 M: string require-c-array define-array-vocab drop ;
 133
 134 ERROR: specialized-array-vocab-not-loaded c-type ;
 135
 136 M: string c-array-constructor
 137     underlying-type
 138     dup [ "<" "-array>" surround ] [ specialized-array-vocab ] bi lookup
 139     [ ] [ specialized-array-vocab-not-loaded ] ?if ; foldable
 140
 141 M: string c-(array)-constructor
 142     underlying-type
 143     dup [ "(" "-array)" surround ] [ specialized-array-vocab ] bi lookup
 144     [ ] [ specialized-array-vocab-not-loaded ] ?if ; foldable
 145
 146 M: string c-direct-array-constructor
 147     underlying-type
 148     dup [ "<direct-" "-array>" surround ] [ specialized-array-vocab ] bi lookup
 149     [ ] [ specialized-array-vocab-not-loaded ] ?if ; foldable
 150
 151 SYNTAX: SPECIALIZED-ARRAY:
 152     scan define-array-vocab use-vocab ;
 153
 154 "prettyprint" vocab [
 155     "specialized-arrays.prettyprint" require
 156 ] when